cgit.sxemacs.org Git - gnus/blob - lisp/gnus-range.el

   1 ;;; gnus-range.el --- range and sequence functions for Gnus
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2004
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 ;;; List and range functions
  33
  34 (defsubst gnus-range-normalize (range)
  35   "Normalize RANGE.
  36 If RANGE is a single range, return (RANGE). Otherwise, return RANGE."
  37   (if (listp (cdr-safe range)) range (list range)))
  38
  39 (defun gnus-last-element (list)
  40   "Return last element of LIST."
  41   (while (cdr list)
  42     (setq list (cdr list)))
  43   (car list))
  44
  45 (defun gnus-copy-sequence (list)
  46   "Do a complete, total copy of a list."
  47   (let (out)
  48     (while (consp list)
  49       (if (consp (car list))
  50           (push (gnus-copy-sequence (pop list)) out)
  51         (push (pop list) out)))
  52     (if list
  53         (nconc (nreverse out) list)
  54       (nreverse out))))
  55
  56 (defun gnus-set-difference (list1 list2)
  57   "Return a list of elements of LIST1 that do not appear in LIST2."
  58   (let ((list1 (copy-sequence list1)))
  59     (while list2
  60       (setq list1 (delq (car list2) list1))
  61       (setq list2 (cdr list2)))
  62     list1))
  63
  64 (defun gnus-range-difference (range1 range2)
  65   "Return the range of elements in RANGE1 that do not appear in RANGE2.
  66 Both ranges must be in ascending order."
  67   (setq range1 (gnus-range-normalize range1))
  68   (setq range2 (gnus-range-normalize range2))
  69   (let* ((new-range (cons nil (copy-sequence range1)))
  70          (r new-range)
  71          (safe t))
  72     (while (cdr r)
  73       (let* ((r1 (cadr r))
  74              (r2 (car range2))
  75              (min1 (if (numberp r1) r1 (car r1)))
  76              (max1 (if (numberp r1) r1 (cdr r1)))
  77              (min2 (if (numberp r2) r2 (car r2)))
  78              (max2 (if (numberp r2) r2 (cdr r2))))
  79
  80         (cond ((> min1 max1)
  81                ;; Invalid range: may result from overlap condition (below)
  82                ;; remove Invalid range
  83                (setcdr r (cddr r)))
  84               ((and (= min1 max1)
  85                     (listp r1))
  86                ;; Inefficient representation: may result from overlap condition (below)
  87                (setcar (cdr r) min1))
  88               ((not min2)
  89                ;; All done with range2
  90                (setq r nil))
  91               ((< max1 min2)
  92                ;; No overlap: range1 preceeds range2
  93                (pop r))
  94               ((< max2 min1)
  95                ;; No overlap: range2 preceeds range1
  96                (pop range2))
  97               ((and (<= min2 min1) (<= max1 max2))
  98                ;; Complete overlap: range1 removed
  99                (setcdr r (cddr r)))
 100               (t
 101                (setcdr r (nconc (list (cons min1 (1- min2)) (cons (1+ max2) max1)) (cddr r)))))))
 102     (cdr new-range)))
 103
 104
 105
 106 ;;;###autoload
 107 (defun gnus-sorted-difference (list1 list2)
 108   "Return a list of elements of LIST1 that do not appear in LIST2.
 109 Both lists have to be sorted over <.
 110 The tail of LIST1 is not copied."
 111   (let (out)
 112     (while (and list1 list2)
 113       (cond ((= (car list1) (car list2))
 114              (setq list1 (cdr list1)
 115                    list2 (cdr list2)))
 116             ((< (car list1) (car list2))
 117              (setq out (cons (car list1) out))
 118              (setq list1 (cdr list1)))
 119             (t
 120              (setq list2 (cdr list2)))))
 121     (nconc (nreverse out) list1)))
 122
 123 ;;;###autoload
 124 (defun gnus-sorted-ndifference (list1 list2)
 125   "Return a list of elements of LIST1 that do not appear in LIST2.
 126 Both lists have to be sorted over <.
 127 LIST1 is modified."
 128   (let* ((top (cons nil list1))
 129          (prev top))
 130     (while (and list1 list2)
 131       (cond ((= (car list1) (car list2))
 132              (setcdr prev (cdr list1))
 133              (setq list1 (cdr list1)
 134                    list2 (cdr list2)))
 135             ((< (car list1) (car list2))
 136              (setq prev list1
 137                    list1 (cdr list1)))
 138             (t
 139              (setq list2 (cdr list2)))))
 140     (cdr top)))
 141
 142 ;;;###autoload
 143 (defun gnus-sorted-complement (list1 list2)
 144   "Return a list of elements that are in LIST1 or LIST2 but not both.
 145 Both lists have to be sorted over <."
 146   (let (out)
 147     (if (or (null list1) (null list2))
 148         (or list1 list2)
 149       (while (and list1 list2)
 150         (cond ((= (car list1) (car list2))
 151                (setq list1 (cdr list1)
 152                      list2 (cdr list2)))
 153               ((< (car list1) (car list2))
 154                (setq out (cons (car list1) out))
 155                (setq list1 (cdr list1)))
 156               (t
 157                (setq out (cons (car list2) out))
 158                (setq list2 (cdr list2)))))
 159       (nconc (nreverse out) (or list1 list2)))))
 160
 161 ;;;###autoload
 162 (defun gnus-intersection (list1 list2)
 163   (let ((result nil))
 164     (while list2
 165       (when (memq (car list2) list1)
 166         (setq result (cons (car list2) result)))
 167       (setq list2 (cdr list2)))
 168     result))
 169
 170 ;;;###autoload
 171 (defun gnus-sorted-intersection (list1 list2)
 172   "Return intersection of LIST1 and LIST2.
 173 LIST1 and LIST2 have to be sorted over <."
 174   (let (out)
 175     (while (and list1 list2)
 176       (cond ((= (car list1) (car list2))
 177              (setq out (cons (car list1) out)
 178                    list1 (cdr list1)
 179                    list2 (cdr list2)))
 180             ((< (car list1) (car list2))
 181              (setq list1 (cdr list1)))
 182             (t
 183              (setq list2 (cdr list2)))))
 184     (nreverse out)))
 185
 186 ;;;###autoload
 187 (defun gnus-sorted-range-intersection (range1 range2)
 188   "Return intersection of RANGE1 and RANGE2.
 189 RANGE1 and RANGE2 have to be sorted over <."
 190   (let* (out
 191          (min1 (car range1))
 192          (max1 (if (numberp min1) min1 (prog1 (cdr min1) (setq min1 (car min1)))))
 193          (min2 (car range2))
 194          (max2 (if (numberp min2) min2 (prog1 (cdr min2) (setq min2 (car min2))))))
 195     (setq range1 (cdr range1)
 196           range2 (cdr range2))
 197     (while (and min1 min2)
 198       (cond ((< max1 min2)              ; range1 preceeds range2
 199              (setq range1 (cdr range1)
 200                    min1 nil))
 201             ((< max2 min1)              ; range2 preceeds range1
 202              (setq range2 (cdr range2)
 203                    min2 nil))
 204             (t                     ; some sort of overlap is occurring
 205              (let ((min (max min1 min2))
 206                    (max (min max1 max2)))
 207                (setq out (if (= min max)
 208                              (cons min out)
 209                            (cons (cons min max) out))))
 210              (if (< max1 max2)          ; range1 ends before range2
 211                  (setq min1 nil)        ; incr range1
 212                (setq min2 nil))))       ; incr range2
 213       (unless min1
 214         (setq min1 (car range1)
 215               max1 (if (numberp min1) min1 (prog1 (cdr min1) (setq min1 (car min1))))
 216               range1 (cdr range1)))
 217       (unless min2
 218         (setq min2 (car range2)
 219               max2 (if (numberp min2) min2 (prog1 (cdr min2) (setq min2 (car min2))))
 220               range2 (cdr range2))))
 221     (nreverse out)))
 222
 223 ;;;###autoload
 224 (defalias 'gnus-set-sorted-intersection 'gnus-sorted-nintersection)
 225
 226 ;;;###autoload
 227 (defun gnus-sorted-nintersection (list1 list2)
 228   "Return intersection of LIST1 and LIST2 by modifying cdr pointers of LIST1.
 229 LIST1 and LIST2 have to be sorted over <."
 230   (let* ((top (cons nil list1))
 231          (prev top))
 232     (while (and list1 list2)
 233       (cond ((= (car list1) (car list2))
 234              (setq prev list1
 235                    list1 (cdr list1)
 236                    list2 (cdr list2)))
 237             ((< (car list1) (car list2))
 238              (setcdr prev (cdr list1))
 239              (setq list1 (cdr list1)))
 240             (t
 241              (setq list2 (cdr list2)))))
 242     (setcdr prev nil)
 243     (cdr top)))
 244
 245 ;;;###autoload
 246 (defun gnus-sorted-union (list1 list2)
 247   "Return union of LIST1 and LIST2.
 248 LIST1 and LIST2 have to be sorted over <."
 249   (let (out)
 250     (while (and list1 list2)
 251       (cond ((= (car list1) (car list2))
 252              (setq out (cons (car list1) out)
 253                    list1 (cdr list1)
 254                    list2 (cdr list2)))
 255             ((< (car list1) (car list2))
 256              (setq out (cons (car list1) out)
 257                    list1 (cdr list1)))
 258             (t
 259              (setq out (cons (car list2) out)
 260                    list2 (cdr list2)))))
 261     (while list1
 262       (setq out (cons (car list1) out)
 263             list1 (cdr list1)))
 264     (while list2
 265       (setq out (cons (car list2) out)
 266             list2 (cdr list2)))
 267     (nreverse out)))
 268
 269 ;;;###autoload
 270 (defun gnus-sorted-nunion (list1 list2)
 271   "Return union of LIST1 and LIST2 by modifying cdr pointers of LIST1.
 272 LIST1 and LIST2 have to be sorted over <."
 273   (let* ((top (cons nil list1))
 274          (prev top))
 275     (while (and list1 list2)
 276       (cond ((= (car list1) (car list2))
 277              (setq prev list1
 278                    list1 (cdr list1)
 279                    list2 (cdr list2)))
 280             ((< (car list1) (car list2))
 281              (setq prev list1
 282                    list1 (cdr list1)))
 283             (t
 284              (setcdr prev (list (car list2)))
 285              (setq prev (cdr prev)
 286                    list2 (cdr list2))
 287              (setcdr prev list1))))
 288     (while list2
 289       (setcdr prev (list (car list2)))
 290       (setq prev (cdr prev)
 291             list2 (cdr list2)))
 292     (cdr top)))
 293
 294 (defun gnus-compress-sequence (numbers &optional always-list)
 295   "Convert sorted list of numbers to a list of ranges or a single range.
 296 If ALWAYS-LIST is non-nil, this function will always release a list of
 297 ranges."
 298   (let* ((first (car numbers))
 299          (last (car numbers))
 300          result)
 301     (if (null numbers)
 302         nil
 303       (if (not (listp (cdr numbers)))
 304           numbers
 305         (while numbers
 306           (cond ((= last (car numbers)) nil) ;Omit duplicated number
 307                 ((= (1+ last) (car numbers)) ;Still in sequence
 308                  (setq last (car numbers)))
 309                 (t                      ;End of one sequence
 310                  (setq result
 311                        (cons (if (= first last) first
 312                                (cons first last))
 313                              result))
 314                  (setq first (car numbers))
 315                  (setq last  (car numbers))))
 316           (setq numbers (cdr numbers)))
 317         (if (and (not always-list) (null result))
 318             (if (= first last) (list first) (cons first last))
 319           (nreverse (cons (if (= first last) first (cons first last))
 320                           result)))))))
 321
 322 (defalias 'gnus-uncompress-sequence 'gnus-uncompress-range)
 323 (defun gnus-uncompress-range (ranges)
 324   "Expand a list of ranges into a list of numbers.
 325 RANGES is either a single range on the form `(num . num)' or a list of
 326 these ranges."
 327   (let (first last result)
 328     (cond
 329      ((null ranges)
 330       nil)
 331      ((not (listp (cdr ranges)))
 332       (setq first (car ranges))
 333       (setq last (cdr ranges))
 334       (while (<= first last)
 335         (setq result (cons first result))
 336         (setq first (1+ first)))
 337       (nreverse result))
 338      (t
 339       (while ranges
 340         (if (atom (car ranges))
 341             (when (numberp (car ranges))
 342               (setq result (cons (car ranges) result)))
 343           (setq first (caar ranges))
 344           (setq last  (cdar ranges))
 345           (while (<= first last)
 346             (setq result (cons first result))
 347             (setq first (1+ first))))
 348         (setq ranges (cdr ranges)))
 349       (nreverse result)))))
 350
 351 (defun gnus-add-to-range (ranges list)
 352   "Return a list of ranges that has all articles from both RANGES and LIST.
 353 Note: LIST has to be sorted over `<'."
 354   (if (not ranges)
 355       (gnus-compress-sequence list t)
 356     (setq list (copy-sequence list))
 357     (unless (listp (cdr ranges))
 358       (setq ranges (list ranges)))
 359     (let ((out ranges)
 360           ilist lowest highest temp)
 361       (while (and ranges list)
 362         (setq ilist list)
 363         (setq lowest (or (and (atom (car ranges)) (car ranges))
 364                          (caar ranges)))
 365         (while (and list (cdr list) (< (cadr list) lowest))
 366           (setq list (cdr list)))
 367         (when (< (car ilist) lowest)
 368           (setq temp list)
 369           (setq list (cdr list))
 370           (setcdr temp nil)
 371           (setq out (nconc (gnus-compress-sequence ilist t) out)))
 372         (setq highest (or (and (atom (car ranges)) (car ranges))
 373                           (cdar ranges)))
 374         (while (and list (<= (car list) highest))
 375           (setq list (cdr list)))
 376         (setq ranges (cdr ranges)))
 377       (when list
 378         (setq out (nconc (gnus-compress-sequence list t) out)))
 379       (setq out (sort out (lambda (r1 r2)
 380                             (< (or (and (atom r1) r1) (car r1))
 381                                (or (and (atom r2) r2) (car r2))))))
 382       (setq ranges out)
 383       (while ranges
 384         (if (atom (car ranges))
 385             (when (cdr ranges)
 386               (if (atom (cadr ranges))
 387                   (when (= (1+ (car ranges)) (cadr ranges))
 388                     (setcar ranges (cons (car ranges)
 389                                          (cadr ranges)))
 390                     (setcdr ranges (cddr ranges)))
 391                 (when (= (1+ (car ranges)) (caadr ranges))
 392                   (setcar (cadr ranges) (car ranges))
 393                   (setcar ranges (cadr ranges))
 394                   (setcdr ranges (cddr ranges)))))
 395           (when (cdr ranges)
 396             (if (atom (cadr ranges))
 397                 (when (= (1+ (cdar ranges)) (cadr ranges))
 398                   (setcdr (car ranges) (cadr ranges))
 399                   (setcdr ranges (cddr ranges)))
 400               (when (= (1+ (cdar ranges)) (caadr ranges))
 401                 (setcdr (car ranges) (cdadr ranges))
 402                 (setcdr ranges (cddr ranges))))))
 403         (setq ranges (cdr ranges)))
 404       out)))
 405
 406 (defun gnus-remove-from-range (range1 range2)
 407   "Return a range that has all articles from RANGE2 removed from RANGE1.
 408 The returned range is always a list.  RANGE2 can also be a unsorted
 409 list of articles.  RANGE1 is modified by side effects, RANGE2 is not
 410 modified."
 411   (if (or (null range1) (null range2))
 412       range1
 413     (let (out r1 r2 r1_min r1_max r2_min r2_max
 414               (range2 (gnus-copy-sequence range2)))
 415       (setq range1 (if (listp (cdr range1)) range1 (list range1))
 416             range2 (sort (if (listp (cdr range2)) range2 (list range2))
 417                          (lambda (e1 e2)
 418                            (< (if (consp e1) (car e1) e1)
 419                               (if (consp e2) (car e2) e2))))
 420             r1 (car range1)
 421             r2 (car range2)
 422             r1_min (if (consp r1) (car r1) r1)
 423             r1_max (if (consp r1) (cdr r1) r1)
 424             r2_min (if (consp r2) (car r2) r2)
 425             r2_max (if (consp r2) (cdr r2) r2))
 426       (while (and range1 range2)
 427         (cond ((< r2_max r1_min)        ; r2 < r1
 428                (pop range2)
 429                (setq r2 (car range2)
 430                      r2_min (if (consp r2) (car r2) r2)
 431                      r2_max (if (consp r2) (cdr r2) r2)))
 432               ((and (<= r2_min r1_min) (<= r1_max r2_max)) ; r2 overlap r1
 433                (pop range1)
 434                (setq r1 (car range1)
 435                      r1_min (if (consp r1) (car r1) r1)
 436                      r1_max (if (consp r1) (cdr r1) r1)))
 437               ((and (<= r2_min r1_min) (<= r2_max r1_max)) ; r2 overlap min r1
 438                (pop range2)
 439                (setq r1_min (1+ r2_max)
 440                      r2 (car range2)
 441                      r2_min (if (consp r2) (car r2) r2)
 442                      r2_max (if (consp r2) (cdr r2) r2)))
 443               ((and (<= r1_min r2_min) (<= r2_max r1_max)) ; r2 contained in r1
 444                (if (eq r1_min (1- r2_min))
 445                    (push r1_min out)
 446                  (push (cons r1_min (1- r2_min)) out))
 447                (pop range2)
 448                (if (< r2_max r1_max)    ; finished with r1?
 449                    (setq r1_min (1+ r2_max))
 450                  (pop range1)
 451                  (setq r1 (car range1)
 452                        r1_min (if (consp r1) (car r1) r1)
 453                        r1_max (if (consp r1) (cdr r1) r1)))
 454                (setq r2 (car range2)
 455                      r2_min (if (consp r2) (car r2) r2)
 456                      r2_max (if (consp r2) (cdr r2) r2)))
 457               ((and (<= r2_min r1_max) (<= r1_max r2_max)) ; r2 overlap max r1
 458                (if (eq r1_min (1- r2_min))
 459                    (push r1_min out)
 460                  (push (cons r1_min (1- r2_min)) out))
 461                (pop range1)
 462                (setq r1 (car range1)
 463                      r1_min (if (consp r1) (car r1) r1)
 464                      r1_max (if (consp r1) (cdr r1) r1)))
 465               ((< r1_max r2_min)        ; r2 > r1
 466                (pop range1)
 467                (if (eq r1_min r1_max)
 468                    (push r1_min out)
 469                  (push (cons r1_min r1_max) out))
 470                (setq r1 (car range1)
 471                      r1_min (if (consp r1) (car r1) r1)
 472                      r1_max (if (consp r1) (cdr r1) r1)))))
 473       (when r1
 474         (if (eq r1_min r1_max)
 475             (push r1_min out)
 476           (push (cons r1_min r1_max) out))
 477         (pop range1))
 478       (while range1
 479         (push (pop range1) out))
 480       (nreverse out))))
 481
 482 (defun gnus-member-of-range (number ranges)
 483   (if (not (listp (cdr ranges)))
 484       (and (>= number (car ranges))
 485            (<= number (cdr ranges)))
 486     (let ((not-stop t))
 487       (while (and ranges
 488                   (if (numberp (car ranges))
 489                       (>= number (car ranges))
 490                     (>= number (caar ranges)))
 491                   not-stop)
 492         (when (if (numberp (car ranges))
 493                   (= number (car ranges))
 494                 (and (>= number (caar ranges))
 495                      (<= number (cdar ranges))))
 496           (setq not-stop nil))
 497         (setq ranges (cdr ranges)))
 498       (not not-stop))))
 499
 500 (defun gnus-list-range-intersection (list ranges)
 501   "Return a list of numbers in LIST that are members of RANGES.
 502 LIST is a sorted list."
 503   (setq ranges (gnus-range-normalize ranges))
 504   (let (number result)
 505     (while (setq number (pop list))
 506       (while (and ranges
 507                   (if (numberp (car ranges))
 508                       (< (car ranges) number)
 509                     (< (cdar ranges) number)))
 510         (setq ranges (cdr ranges)))
 511       (when (and ranges
 512                  (if (numberp (car ranges))
 513                       (= (car ranges) number)
 514                    ;; (caar ranges) <= number <= (cdar ranges)
 515                    (>= number (caar ranges))))
 516         (push number result)))
 517     (nreverse result)))
 518
 519 (defalias 'gnus-inverse-list-range-intersection 'gnus-list-range-difference)
 520
 521 (defun gnus-list-range-difference (list ranges)
 522   "Return a list of numbers in LIST that are not members of RANGES.
 523 LIST is a sorted list."
 524   (setq ranges (gnus-range-normalize ranges))
 525   (let (number result)
 526     (while (setq number (pop list))
 527       (while (and ranges
 528                   (if (numberp (car ranges))
 529                       (< (car ranges) number)
 530                     (< (cdar ranges) number)))
 531         (setq ranges (cdr ranges)))
 532       (when (or (not ranges)
 533                 (if (numberp (car ranges))
 534                     (not (= (car ranges) number))
 535                   ;; not ((caar ranges) <= number <= (cdar ranges))
 536                   (< number (caar ranges))))
 537         (push number result)))
 538     (nreverse result)))
 539
 540 (defun gnus-range-length (range)
 541   "Return the length RANGE would have if uncompressed."
 542   (cond
 543    ((null range)
 544     0)
 545    ((not (listp (cdr range)))
 546     (- (cdr range) (car range) -1))
 547    (t
 548     (let ((sum 0))
 549       (dolist (x range sum)
 550         (setq sum
 551               (+ sum (if (consp x) (- (cdr x) (car x) -1) 1))))))))
 552
 553 (defun gnus-sublist-p (list sublist)
 554   "Test whether all elements in SUBLIST are members of LIST."
 555   (let ((sublistp t))
 556     (while sublist
 557       (unless (memq (pop sublist) list)
 558         (setq sublistp nil
 559               sublist nil)))
 560     sublistp))
 561
 562 (defun gnus-range-add (range1 range2)
 563   "Add RANGE2 to RANGE1 (nondestructively)."
 564   (unless (listp (cdr range1))
 565     (setq range1 (list range1)))
 566   (unless (listp (cdr range2))
 567     (setq range2 (list range2)))
 568   (let ((item1 (pop range1))
 569         (item2 (pop range2))
 570         range item selector)
 571     (while (or item1 item2)
 572       (setq selector
 573             (cond
 574              ((null item1) nil)
 575              ((null item2) t)
 576              ((and (numberp item1) (numberp item2)) (< item1 item2))
 577              ((numberp item1) (< item1 (car item2)))
 578              ((numberp item2) (< (car item1) item2))
 579              (t (< (car item1) (car item2)))))
 580       (setq item
 581             (or
 582              (let ((tmp1 item) (tmp2 (if selector item1 item2)))
 583                (cond
 584                 ((null tmp1) tmp2)
 585                 ((null tmp2) tmp1)
 586                 ((and (numberp tmp1) (numberp tmp2))
 587                  (cond
 588                   ((eq tmp1 tmp2) tmp1)
 589                   ((eq (1+ tmp1) tmp2) (cons tmp1 tmp2))
 590                   ((eq (1+ tmp2) tmp1) (cons tmp2 tmp1))
 591                   (t nil)))
 592                 ((numberp tmp1)
 593                  (cond
 594                   ((and (>= tmp1 (car tmp2)) (<= tmp1 (cdr tmp2))) tmp2)
 595                   ((eq (1+ tmp1) (car tmp2)) (cons tmp1 (cdr tmp2)))
 596                   ((eq (1- tmp1) (cdr tmp2)) (cons (car tmp2) tmp1))
 597                   (t nil)))
 598                 ((numberp tmp2)
 599                  (cond
 600                   ((and (>= tmp2 (car tmp1)) (<= tmp2 (cdr tmp1))) tmp1)
 601                   ((eq (1+ tmp2) (car tmp1)) (cons tmp2 (cdr tmp1)))
 602                   ((eq (1- tmp2) (cdr tmp1)) (cons (car tmp1) tmp2))
 603                   (t nil)))
 604                 ((< (1+ (cdr tmp1)) (car tmp2)) nil)
 605                 ((< (1+ (cdr tmp2)) (car tmp1)) nil)
 606                 (t (cons (min (car tmp1) (car tmp2))
 607                          (max (cdr tmp1) (cdr tmp2))))))
 608              (progn
 609                (if item (push item range))
 610                (if selector item1 item2))))
 611       (if selector
 612           (setq item1 (pop range1))
 613         (setq item2 (pop range2))))
 614     (if item (push item range))
 615     (reverse range)))
 616
 617 ;;;###autoload
 618 (defun gnus-add-to-sorted-list (list num)
 619   "Add NUM into sorted LIST by side effect."
 620   (let* ((top (cons nil list))
 621          (prev top))
 622     (while (and list (< (car list) num))
 623       (setq prev list
 624             list (cdr list)))
 625     (unless (eq (car list) num)
 626       (setcdr prev (cons num list)))
 627     (cdr top)))
 628
 629 (defun gnus-range-map (func range)
 630   "Apply FUNC to each value contained by RANGE."
 631   (while range
 632     (let ((span (pop range)))
 633       (if (numberp span)
 634           (funcall func span)
 635         (let ((first (car span))
 636               (last (cdr span)))
 637           (while (<= first last)
 638             (funcall func first)
 639             (setq first (1+ first))))))))
 640
 641 (provide 'gnus-range)
 642
 643 ;;; gnus-range.el ends here