cgit.sxemacs.org Git - gnus/blob - lisp/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   5 ;;      Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'gnus)
  30 (require 'gnus-ems)
  31 (require 'message)
  32 (require 'gnus-art)
  33
  34 ;; Added by Sudish Joseph <joseph@cis.ohio-state.edu>.
  35 (defvar gnus-post-method nil
  36   "*Preferred method for posting USENET news.
  37 If this variable is nil, Gnus will use the current method to decide
  38 which method to use when posting.  If it is non-nil, it will override
  39 the current method.  This method will not be used in mail groups and
  40 the like, only in \"real\" newsgroups.
  41
  42 The value must be a valid method as discussed in the documentation of
  43 `gnus-select-method'.  It can also be a list of methods.  If that is
  44 the case, the user will be queried for what select method to use when
  45 posting.")
  46
  47 (defvar gnus-outgoing-message-group nil
  48   "*All outgoing messages will be put in this group.
  49 If you want to store all your outgoing mail and articles in the group
  50 \"nnml:archive\", you set this variable to that value.  This variable
  51 can also be a list of group names.
  52
  53 If you want to have greater control over what group to put each
  54 message in, you can set this variable to a function that checks the
  55 current newsgroup name and then returns a suitable group name (or list
  56 of names).")
  57
  58 (defvar gnus-mailing-list-groups nil
  59   "*Regexp matching groups that are really mailing lists.
  60 This is useful when you're reading a mailing list that has been
  61 gatewayed to a newsgroup, and you want to followup to an article in
  62 the group.")
  63
  64 (defvar gnus-sent-message-ids-file
  65   (nnheader-concat gnus-directory "Sent-Message-IDs")
  66   "File where Gnus saves a cache of sent message ids.")
  67
  68 (defvar gnus-sent-message-ids-length 1000
  69   "The number of sent Message-IDs to save.")
  70
  71 (defvar gnus-crosspost-complaint
  72   "Hi,
  73
  74 You posted the article below with the following Newsgroups header:
  75
  76 Newsgroups: %s
  77
  78 The %s group, at least, was an inappropriate recipient
  79 of this message.  Please trim your Newsgroups header to exclude this
  80 group before posting in the future.
  81
  82 Thank you.
  83
  84 "
  85   "Format string to be inserted when complaining about crossposts.
  86 The first %s will be replaced by the Newsgroups header;
  87 the second with the current group name.")
  88
  89 ;;; Internal variables.
  90
  91 (defvar gnus-message-buffer "*Mail Gnus*")
  92 (defvar gnus-article-copy nil)
  93 (defvar gnus-last-posting-server nil)
  94
  95 (defconst gnus-bug-message
  96   "Sending a bug report to the Gnus Towers.
  97 ========================================
  98
  99 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 100 be sent to the Gnus Bug Exterminators.
 101
 102 At the bottom of the buffer you'll see lots of variable settings.
 103 Please do not delete those.  They will tell the Bug People what your
 104 environment is, so that it will be easier to locate the bugs.
 105
 106 If you have found a bug that makes Emacs go \"beep\", set
 107 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 108 and include the backtrace in your bug report.
 109
 110 Please describe the bug in annoying, painstaking detail.
 111
 112 Thank you for your help in stamping out bugs.
 113 ")
 114
 115 (eval-and-compile
 116   (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 117   (autoload 'news-setup "rnewspost")
 118   (autoload 'news-reply-mode "rnewspost")
 119   (autoload 'rmail-dont-reply-to "mail-utils")
 120   (autoload 'rmail-output "rmailout"))
 121
 122 \f
 123 ;;;
 124 ;;; Gnus Posting Functions
 125 ;;;
 126
 127 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 128   "p" gnus-summary-post-news
 129   "f" gnus-summary-followup
 130   "F" gnus-summary-followup-with-original
 131   "c" gnus-summary-cancel-article
 132   "s" gnus-summary-supersede-article
 133   "r" gnus-summary-reply
 134   "R" gnus-summary-reply-with-original
 135   "n" gnus-summary-followup-to-mail
 136   "N" gnus-summary-followup-to-mail-with-original
 137   "m" gnus-summary-mail-other-window
 138   "u" gnus-uu-post-news
 139   "\M-c" gnus-summary-mail-crosspost-complaint
 140   "om" gnus-summary-mail-forward
 141   "op" gnus-summary-post-forward
 142   "Om" gnus-uu-digest-mail-forward
 143   "Op" gnus-uu-digest-post-forward)
 144
 145 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 146   "b" gnus-summary-resend-bounced-mail
 147   ;; "c" gnus-summary-send-draft
 148   "r" gnus-summary-resend-message)
 149
 150 ;;; Internal functions.
 151
 152 (defvar gnus-article-reply nil)
 153 (defmacro gnus-setup-message (config &rest forms)
 154   (let ((winconf (make-symbol "winconf"))
 155         (buffer (make-symbol "buffer"))
 156         (article (make-symbol "article")))
 157     `(let ((,winconf (current-window-configuration))
 158            (,buffer (current-buffer))
 159            (,article (and gnus-article-reply (gnus-summary-article-number)))
 160            (message-header-setup-hook
 161             (copy-sequence message-header-setup-hook)))
 162        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 163        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 164        ,@forms
 165        (gnus-inews-add-send-actions ,winconf ,buffer ,article)
 166        (setq gnus-message-buffer (current-buffer))
 167        (make-local-variable 'gnus-newsgroup-name)
 168        (gnus-configure-windows ,config t))))
 169
 170 (defun gnus-inews-add-send-actions (winconf buffer article)
 171   (gnus-make-local-hook 'message-sent-hook)
 172   (gnus-add-hook 'message-sent-hook 'gnus-inews-do-gcc nil t)
 173   (setq message-post-method
 174         `(lambda (arg)
 175            (gnus-post-method arg ,gnus-newsgroup-name)))
 176   (setq message-newsreader (setq message-mailer (gnus-extended-version)))
 177   (message-add-action
 178    `(set-window-configuration ,winconf) 'exit 'postpone 'kill)
 179   (message-add-action
 180    `(when (buffer-name ,buffer)
 181       (save-excursion
 182         (set-buffer ,buffer)
 183         ,(when article
 184            `(gnus-summary-mark-article-as-replied ,article))))
 185    'send))
 186
 187 (put 'gnus-setup-message 'lisp-indent-function 1)
 188 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 189
 190 ;;; Post news commands of Gnus group mode and summary mode
 191
 192 (defun gnus-group-mail ()
 193   "Start composing a mail."
 194   (interactive)
 195   (gnus-setup-message 'message
 196     (message-mail)))
 197
 198 (defun gnus-group-post-news (&optional arg)
 199   "Start composing a news message.
 200 If ARG, post to the group under point.
 201 If ARG is 1, prompt for a group name."
 202   (interactive "P")
 203   ;; Bind this variable here to make message mode hooks
 204   ;; work ok.
 205   (let ((gnus-newsgroup-name
 206          (if arg
 207              (if (= 1 (prefix-numeric-value arg))
 208                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 209                                   (gnus-read-active-file-p))
 210                (gnus-group-group-name))
 211            "")))
 212     (gnus-post-news 'post gnus-newsgroup-name)))
 213
 214 (defun gnus-summary-post-news ()
 215   "Start composing a news message."
 216   (interactive)
 217   (gnus-set-global-variables)
 218   (gnus-post-news 'post gnus-newsgroup-name))
 219
 220 (defun gnus-summary-followup (yank &optional force-news)
 221   "Compose a followup to an article.
 222 If prefix argument YANK is non-nil, original article is yanked automatically."
 223   (interactive
 224    (list (and current-prefix-arg
 225               (gnus-summary-work-articles 1))))
 226   (gnus-set-global-variables)
 227   (when yank
 228     (gnus-summary-goto-subject (car yank)))
 229   (save-window-excursion
 230     (gnus-summary-select-article))
 231   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 232         (gnus-newsgroup-name gnus-newsgroup-name))
 233     ;; Send a followup.
 234     (gnus-post-news nil gnus-newsgroup-name
 235                     headers gnus-article-buffer
 236                     yank nil force-news)))
 237
 238 (defun gnus-summary-followup-with-original (n &optional force-news)
 239   "Compose a followup to an article and include the original article."
 240   (interactive "P")
 241   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 242
 243 (defun gnus-summary-followup-to-mail (&optional arg)
 244   "Followup to the current mail message via news."
 245   (interactive
 246    (list (and current-prefix-arg
 247               (gnus-summary-work-articles 1))))
 248   (gnus-summary-followup arg t))
 249
 250 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 251   "Followup to the current mail message via news."
 252   (interactive "P")
 253   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 254
 255 (defun gnus-inews-yank-articles (articles)
 256   (let (beg article)
 257     (message-goto-body)
 258     (while (setq article (pop articles))
 259       (save-window-excursion
 260         (set-buffer gnus-summary-buffer)
 261         (gnus-summary-select-article nil nil nil article)
 262         (gnus-summary-remove-process-mark article))
 263       (gnus-copy-article-buffer)
 264       (let ((message-reply-buffer gnus-article-copy)
 265             (message-reply-headers gnus-current-headers))
 266         (message-yank-original)
 267         (setq beg (or beg (mark t))))
 268       (when articles
 269         (insert "\n")))
 270     (push-mark)
 271     (goto-char beg)))
 272
 273 (defun gnus-summary-cancel-article (n)
 274   "Cancel an article you posted."
 275   (interactive "P")
 276   (gnus-set-global-variables)
 277   (let ((articles (gnus-summary-work-articles n))
 278         (message-post-method
 279          `(lambda (arg)
 280             (gnus-post-method nil ,gnus-newsgroup-name)))
 281         article)
 282     (while (setq article (pop articles))
 283       (when (gnus-summary-select-article t nil nil article)
 284         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 285                 (message-cancel-news))
 286           (gnus-summary-mark-as-read article gnus-canceled-mark)
 287           (gnus-cache-remove-article 1))
 288         (gnus-article-hide-headers-if-wanted))
 289       (gnus-summary-remove-process-mark article))))
 290
 291 (defun gnus-summary-supersede-article ()
 292   "Compose an article that will supersede a previous article.
 293 This is done simply by taking the old article and adding a Supersedes
 294 header line with the old Message-ID."
 295   (interactive)
 296   (gnus-set-global-variables)
 297   (let ((article (gnus-summary-article-number)))
 298     (gnus-setup-message 'reply-yank
 299       (gnus-summary-select-article t)
 300       (set-buffer gnus-original-article-buffer)
 301       (message-supersede)
 302       (push
 303        `((lambda ()
 304            (gnus-cache-possibly-remove-article ,article nil nil nil t)))
 305        message-send-actions))))
 306
 307 \f
 308
 309 (defun gnus-copy-article-buffer (&optional article-buffer)
 310   ;; make a copy of the article buffer with all text properties removed
 311   ;; this copy is in the buffer gnus-article-copy.
 312   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 313   ;; this buffer should be passed to all mail/news reply/post routines.
 314   (setq gnus-article-copy (get-buffer-create " *gnus article copy*"))
 315   (buffer-disable-undo gnus-article-copy)
 316   (or (memq gnus-article-copy gnus-buffer-list)
 317       (push gnus-article-copy gnus-buffer-list))
 318   (let ((article-buffer (or article-buffer gnus-article-buffer))
 319         end beg contents)
 320     (when (and (get-buffer article-buffer)
 321                (buffer-name (get-buffer article-buffer)))
 322       (save-excursion
 323         (set-buffer article-buffer)
 324         (save-restriction
 325           ;; Copy over the (displayed) article buffer, delete
 326           ;; hidden text and remove text properties.
 327           (widen)
 328           (copy-to-buffer gnus-article-copy (point-min) (point-max))
 329           (set-buffer gnus-article-copy)
 330           (article-delete-text-of-type 'annotation)
 331           (insert
 332            (prog1
 333                (format "%s" (buffer-string))
 334              (erase-buffer)))
 335           ;; Find the original headers.
 336           (set-buffer gnus-original-article-buffer)
 337           (goto-char (point-min))
 338           (while (looking-at message-unix-mail-delimiter)
 339             (forward-line 1))
 340           (setq beg (point))
 341           (setq end (or (search-forward "\n\n" nil t) (point)))
 342           ;; Delete the headers from the displayed articles.
 343           (set-buffer gnus-article-copy)
 344           (delete-region (goto-char (point-min))
 345                          (or (search-forward "\n\n" nil t) (point)))
 346           ;; Insert the original article headers.
 347           (insert-buffer-substring gnus-original-article-buffer beg end)
 348           (article-decode-rfc1522)))
 349       gnus-article-copy)))
 350
 351 (defun gnus-post-news (post &optional group header article-buffer yank subject
 352                             force-news)
 353   (when article-buffer
 354     (gnus-copy-article-buffer))
 355   (let ((gnus-article-reply article-buffer))
 356     (gnus-setup-message (cond (yank 'reply-yank)
 357                               (article-buffer 'reply)
 358                               (t 'message))
 359       (let* ((group (or group gnus-newsgroup-name))
 360              (pgroup group)
 361              to-address to-group mailing-list to-list)
 362         (when group
 363           (setq to-address (gnus-group-find-parameter group 'to-address)
 364                 to-group (gnus-group-find-parameter group 'to-group)
 365                 to-list (gnus-group-find-parameter group 'to-list)
 366                 mailing-list (when gnus-mailing-list-groups
 367                                (string-match gnus-mailing-list-groups group))
 368                 group (gnus-group-real-name group)))
 369         (if (or (and to-group
 370                      (gnus-news-group-p to-group))
 371                 force-news
 372                 (and (gnus-news-group-p
 373                       (or pgroup gnus-newsgroup-name)
 374                       (if header (mail-header-number header)
 375                         gnus-current-article))
 376                      (not mailing-list)
 377                      (not to-list)
 378                      (not to-address)))
 379             ;; This is news.
 380             (if post
 381                 (message-news (or to-group group))
 382               (set-buffer gnus-article-copy)
 383               (message-followup (if force-news nil to-group)))
 384           ;; The is mail.
 385           (if post
 386               (progn
 387                 (message-mail (or to-address to-list))
 388                 ;; Arrange for mail groups that have no `to-address' to
 389                 ;; get that when the user sends off the mail.
 390                 (push (list 'gnus-inews-add-to-address group)
 391                       message-send-actions))
 392             (set-buffer gnus-article-copy)
 393             (message-wide-reply to-address)))
 394         (when yank
 395           (gnus-inews-yank-articles yank))))))
 396
 397 (defun gnus-post-method (arg group &optional silent)
 398   "Return the posting method based on GROUP and ARG.
 399 If SILENT, don't prompt the user."
 400   (let ((group-method (gnus-find-method-for-group group)))
 401     (cond
 402      ;; If the group-method is nil (which shouldn't happen) we use
 403      ;; the default method.
 404      ((null group-method)
 405       (or gnus-post-method gnus-select-method message-post-method))
 406      ;; We want this group's method.
 407      ((and arg (not (eq arg 0)))
 408       group-method)
 409      ;; We query the user for a post method.
 410      ((or arg
 411           (and gnus-post-method
 412                (listp (car gnus-post-method))))
 413       (let* ((methods
 414               ;; Collect all methods we know about.
 415               (append
 416                (when gnus-post-method
 417                  (if (listp (car gnus-post-method))
 418                      gnus-post-method
 419                    (list gnus-post-method)))
 420                gnus-secondary-select-methods
 421                (list gnus-select-method)
 422                (list group-method)))
 423              method-alist post-methods method)
 424         ;; Weed out all mail methods.
 425         (while methods
 426           (setq method (gnus-server-get-method "" (pop methods)))
 427           (when (or (gnus-method-option-p method 'post)
 428                     (gnus-method-option-p method 'post-mail))
 429             (push method post-methods)))
 430         ;; Create a name-method alist.
 431         (setq method-alist
 432               (mapcar
 433                (lambda (m)
 434                  (list (concat (cadr m) " (" (symbol-name (car m)) ")") m))
 435                post-methods))
 436         ;; Query the user.
 437         (cadr
 438          (assoc
 439           (setq gnus-last-posting-server
 440                 (if (and silent
 441                          gnus-last-posting-server)
 442                     ;; Just use the last value.
 443                     gnus-last-posting-server
 444                   (completing-read
 445                    "Posting method: " method-alist nil t
 446                    (cons (or gnus-last-posting-server "") 0))))
 447           method-alist))))
 448      ;; Override normal method.
 449      (gnus-post-method
 450       gnus-post-method)
 451      ;; Use the normal select method.
 452      (t gnus-select-method))))
 453
 454 (defun gnus-inews-narrow-to-headers ()
 455   (widen)
 456   (narrow-to-region
 457    (goto-char (point-min))
 458    (or (and (re-search-forward
 459              (concat "^" (regexp-quote mail-header-separator) "$") nil t)
 460             (match-beginning 0))
 461        (point-max)))
 462   (goto-char (point-min)))
 463
 464 ;;;
 465 ;;; Check whether the message has been sent already.
 466 ;;;
 467
 468 (defvar gnus-inews-sent-ids nil)
 469
 470 (defun gnus-inews-reject-message ()
 471   "Check whether this message has already been sent."
 472   (when gnus-sent-message-ids-file
 473     (let ((message-id (save-restriction (gnus-inews-narrow-to-headers)
 474                                         (mail-fetch-field "message-id")))
 475           end)
 476       (when message-id
 477         (unless gnus-inews-sent-ids
 478           (ignore-errors
 479             (load t t t)))
 480         (if (member message-id gnus-inews-sent-ids)
 481             ;; Reject this message.
 482             (not (gnus-yes-or-no-p
 483                   (format "Message %s already sent.  Send anyway? "
 484                           message-id)))
 485           (push message-id gnus-inews-sent-ids)
 486           ;; Chop off the last Message-IDs.
 487           (when (setq end (nthcdr gnus-sent-message-ids-length
 488                                   gnus-inews-sent-ids))
 489             (setcdr end nil))
 490           (nnheader-temp-write gnus-sent-message-ids-file
 491             (gnus-prin1 `(setq gnus-inews-sent-ids ',gnus-inews-sent-ids)))
 492           nil)))))
 493
 494 \f
 495
 496 ;; Dummy to avoid byte-compile warning.
 497 (defvar nnspool-rejected-article-hook)
 498
 499 ;;; Since the X-Newsreader/X-Mailer are ``vanity'' headers, they might
 500 ;;; as well include the Emacs version as well.
 501 ;;; The following function works with later GNU Emacs, and XEmacs.
 502 (defun gnus-extended-version ()
 503   "Stringified Gnus version and Emacs version"
 504   (interactive)
 505   (concat
 506    gnus-version
 507    "/"
 508    (cond
 509     ((string-match "^\\([0-9]+\\.[0-9]+\\)\\.[.0-9]+$" emacs-version)
 510      (concat "Emacs " (substring emacs-version
 511                                  (match-beginning 1)
 512                                  (match-end 1))))
 513     ((string-match "\\([A-Z]*[Mm][Aa][Cc][Ss]\\)" emacs-version)
 514      (concat (substring emacs-version
 515                         (match-beginning 1)
 516                         (match-end 1))
 517              (format " %d.%d" emacs-major-version emacs-minor-version)))
 518     (t emacs-version))))
 519
 520 ;; Written by "Mr. Per Persson" <pp@gnu.ai.mit.edu>.
 521 (defun gnus-inews-insert-mime-headers ()
 522   (goto-char (point-min))
 523   (let ((mail-header-separator
 524          (progn
 525            (goto-char (point-min))
 526            (if (and (search-forward (concat "\n" mail-header-separator "\n")
 527                                     nil t)
 528                     (not (search-backward "\n\n" nil t)))
 529                mail-header-separator
 530              ""))))
 531     (or (mail-position-on-field "Mime-Version")
 532         (insert "1.0")
 533         (cond ((save-restriction
 534                  (widen)
 535                  (goto-char (point-min))
 536                  (re-search-forward "[\200-\377]" nil t))
 537                (or (mail-position-on-field "Content-Type")
 538                    (insert "text/plain; charset=ISO-8859-1"))
 539                (or (mail-position-on-field "Content-Transfer-Encoding")
 540                    (insert "8bit")))
 541               (t (or (mail-position-on-field "Content-Type")
 542                      (insert "text/plain; charset=US-ASCII"))
 543                  (or (mail-position-on-field "Content-Transfer-Encoding")
 544                      (insert "7bit")))))))
 545
 546 \f
 547 ;;;
 548 ;;; Gnus Mail Functions
 549 ;;;
 550
 551 ;;; Mail reply commands of Gnus summary mode
 552
 553 (defun gnus-summary-reply (&optional yank)
 554   "Reply mail to news author.
 555 If prefix argument YANK is non-nil, original article is yanked automatically."
 556   (interactive
 557    (list (and current-prefix-arg
 558               (gnus-summary-work-articles 1))))
 559   ;; Bug fix by jbw@bigbird.bu.edu (Joe Wells)
 560   ;; Stripping headers should be specified with mail-yank-ignored-headers.
 561   (gnus-set-global-variables)
 562   (when yank
 563     (gnus-summary-goto-subject (car yank)))
 564   (let ((gnus-article-reply t))
 565     (gnus-setup-message (if yank 'reply-yank 'reply)
 566       (gnus-summary-select-article)
 567       (set-buffer (gnus-copy-article-buffer))
 568       (message-reply nil nil (gnus-group-find-parameter
 569                               gnus-newsgroup-name 'broken-reply-to))
 570       (when yank
 571         (gnus-inews-yank-articles yank)))))
 572
 573 (defun gnus-summary-reply-with-original (n)
 574   "Reply mail to news author with original article."
 575   (interactive "P")
 576   (gnus-summary-reply (gnus-summary-work-articles n)))
 577
 578 (defun gnus-summary-mail-forward (&optional full-headers post)
 579   "Forward the current message to another user.
 580 If FULL-HEADERS (the prefix), include full headers when forwarding."
 581   (interactive "P")
 582   (gnus-set-global-variables)
 583   (gnus-setup-message 'forward
 584     (gnus-summary-select-article)
 585     (set-buffer gnus-original-article-buffer)
 586     (let ((message-included-forward-headers
 587            (if full-headers "" message-included-forward-headers)))
 588       (message-forward post))))
 589
 590 (defun gnus-summary-resend-message (address)
 591   "Resend the current article to ADDRESS."
 592   (interactive "sResend message to: ")
 593   (gnus-summary-select-article)
 594   (save-excursion
 595     (set-buffer gnus-original-article-buffer)
 596     (message-resend address)))
 597
 598 (defun gnus-summary-post-forward (&optional full-headers)
 599   "Forward the current article to a newsgroup.
 600 If FULL-HEADERS (the prefix), include full headers when forwarding."
 601   (interactive "P")
 602   (gnus-summary-mail-forward full-headers t))
 603
 604 (defvar gnus-nastygram-message
 605   "The following article was inappropriately posted to %s.\n\n"
 606   "Format string to insert in nastygrams.
 607 The current group name will be inserted at \"%s\".")
 608
 609 (defun gnus-summary-mail-nastygram (n)
 610   "Send a nastygram to the author of the current article."
 611   (interactive "P")
 612   (when (or gnus-expert-user
 613             (gnus-y-or-n-p
 614              "Really send a nastygram to the author of the current article? "))
 615     (let ((group gnus-newsgroup-name))
 616       (gnus-summary-reply-with-original n)
 617       (set-buffer gnus-message-buffer)
 618       (message-goto-body)
 619       (insert (format gnus-nastygram-message group))
 620       (message-send-and-exit))))
 621
 622 (defun gnus-summary-mail-crosspost-complaint (n)
 623   "Send a complaint about crossposting to the current article(s)."
 624   (interactive "P")
 625   (let ((articles (gnus-summary-work-articles n))
 626         article)
 627     (while (setq article (pop articles))
 628       (set-buffer gnus-summary-buffer)
 629       (gnus-summary-goto-subject article)
 630       (let ((group (gnus-group-real-name gnus-newsgroup-name))
 631             newsgroups followup-to)
 632         (gnus-summary-select-article)
 633         (set-buffer gnus-original-article-buffer)
 634         (if (and (<= (length (message-tokenize-header
 635                               (setq newsgroups (mail-fetch-field "newsgroups"))
 636                               ", "))
 637                      1)
 638                  (or (not (setq followup-to (mail-fetch-field "followup-to")))
 639                      (not (member group (message-tokenize-header
 640                                          followup-to ", ")))))
 641             (if followup-to
 642                 (gnus-message 1 "Followup-to restricted")
 643               (gnus-message 1 "Not a crossposted article"))
 644           (set-buffer gnus-summary-buffer)
 645           (gnus-summary-reply-with-original 1)
 646           (set-buffer gnus-message-buffer)
 647           (message-goto-body)
 648           (insert (format gnus-crosspost-complaint newsgroups group))
 649           (message-goto-subject)
 650           (re-search-forward " *$")
 651           (replace-match " (crosspost notification)" t t)
 652           (when (gnus-y-or-n-p "Send this complaint? ")
 653             (message-send-and-exit)))))))
 654
 655 (defun gnus-summary-mail-other-window ()
 656   "Compose mail in other window."
 657   (interactive)
 658   (gnus-setup-message 'message
 659     (message-mail)))
 660
 661 (defun gnus-mail-parse-comma-list ()
 662   (let (accumulated
 663         beg)
 664     (skip-chars-forward " ")
 665     (while (not (eobp))
 666       (setq beg (point))
 667       (skip-chars-forward "^,")
 668       (while (zerop
 669               (save-excursion
 670                 (save-restriction
 671                   (let ((i 0))
 672                     (narrow-to-region beg (point))
 673                     (goto-char beg)
 674                     (logand (progn
 675                               (while (search-forward "\"" nil t)
 676                                 (incf i))
 677                               (if (zerop i) 2 i))
 678                             2)))))
 679         (skip-chars-forward ",")
 680         (skip-chars-forward "^,"))
 681       (skip-chars-backward " ")
 682       (push (buffer-substring beg (point))
 683             accumulated)
 684       (skip-chars-forward "^,")
 685       (skip-chars-forward ", "))
 686     accumulated))
 687
 688 (defun gnus-inews-add-to-address (group)
 689   (let ((to-address (mail-fetch-field "to")))
 690     (when (and to-address
 691                (gnus-alive-p))
 692       ;; This mail group doesn't have a `to-list', so we add one
 693       ;; here.  Magic!
 694       (gnus-group-add-parameter group (cons 'to-list to-address)))))
 695
 696 (defun gnus-put-message ()
 697   "Put the current message in some group and return to Gnus."
 698   (interactive)
 699   (let ((reply gnus-article-reply)
 700         (winconf gnus-prev-winconf)
 701         (group gnus-newsgroup-name))
 702
 703     (or (and group (not (gnus-group-read-only-p group)))
 704         (setq group (read-string "Put in group: " nil
 705                                  (gnus-writable-groups))))
 706     (when (gnus-gethash group gnus-newsrc-hashtb)
 707       (error "No such group: %s" group))
 708
 709     (save-excursion
 710       (save-restriction
 711         (widen)
 712         (gnus-inews-narrow-to-headers)
 713         (let (gnus-deletable-headers)
 714           (if (message-news-p)
 715               (message-generate-headers message-required-news-headers)
 716             (message-generate-headers message-required-mail-headers)))
 717         (goto-char (point-max))
 718         (insert "Gcc: " group "\n")
 719         (widen)))
 720
 721     (gnus-inews-do-gcc)
 722
 723     (when (get-buffer gnus-group-buffer)
 724       (when (gnus-buffer-exists-p (car-safe reply))
 725         (set-buffer (car reply))
 726         (and (cdr reply)
 727              (gnus-summary-mark-article-as-replied
 728               (cdr reply))))
 729       (when winconf
 730         (set-window-configuration winconf)))))
 731
 732 (defun gnus-article-mail (yank)
 733   "Send a reply to the address near point.
 734 If YANK is non-nil, include the original article."
 735   (interactive "P")
 736   (let ((address
 737          (buffer-substring
 738           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
 739           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
 740     (when address
 741       (message-reply address)
 742       (when yank
 743         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
 744
 745 (defun gnus-bug ()
 746   "Send a bug report to the Gnus maintainers."
 747   (interactive)
 748   (unless (gnus-alive-p)
 749     (error "Gnus has been shut down"))
 750   (gnus-setup-message 'bug
 751     (delete-other-windows)
 752     (switch-to-buffer "*Gnus Help Bug*")
 753     (erase-buffer)
 754     (insert gnus-bug-message)
 755     (goto-char (point-min))
 756     (message-pop-to-buffer "*Gnus Bug*")
 757     (message-setup `((To . ,gnus-maintainer) (Subject . "")))
 758     (push `(gnus-bug-kill-buffer) message-send-actions)
 759     (goto-char (point-min))
 760     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
 761     (forward-line 1)
 762     (insert (gnus-version) "\n")
 763     (insert (emacs-version))
 764     (insert "\n\n\n\n\n")
 765     (gnus-debug)
 766     (goto-char (point-min))
 767     (search-forward "Subject: " nil t)
 768     (message "")))
 769
 770 (defun gnus-bug-kill-buffer ()
 771   (when (get-buffer "*Gnus Help Bug*")
 772     (kill-buffer "*Gnus Help Bug*")))
 773
 774 (defun gnus-debug ()
 775   "Attempts to go through the Gnus source file and report what variables have been changed.
 776 The source file has to be in the Emacs load path."
 777   (interactive)
 778   (let ((files '("gnus.el" "gnus-sum.el" "gnus-group.el"
 779                  "gnus-art.el" "gnus-start.el"
 780                  "gnus-msg.el" "gnus-score.el" "gnus-win.el"
 781                  "nnmail.el" "message.el"))
 782         file expr olist sym)
 783     (gnus-message 4 "Please wait while we snoop your variables...")
 784     (sit-for 0)
 785     ;; Go through all the files looking for non-default values for variables.
 786     (save-excursion
 787       (set-buffer (get-buffer-create " *gnus bug info*"))
 788       (buffer-disable-undo (current-buffer))
 789       (while files
 790         (erase-buffer)
 791         (when (and (setq file (locate-library (pop files)))
 792                    (file-exists-p file))
 793           (insert-file-contents file)
 794           (goto-char (point-min))
 795           (if (not (re-search-forward "^;;* *Internal variables" nil t))
 796               (gnus-message 4 "Malformed sources in file %s" file)
 797             (narrow-to-region (point-min) (point))
 798             (goto-char (point-min))
 799             (while (setq expr (ignore-errors (read (current-buffer))))
 800               (ignore-errors
 801                 (and (eq (car expr) 'defvar)
 802                      (stringp (nth 3 expr))
 803                      (or (not (boundp (nth 1 expr)))
 804                          (not (equal (eval (nth 2 expr))
 805                                      (symbol-value (nth 1 expr)))))
 806                      (push (nth 1 expr) olist)))))))
 807       (kill-buffer (current-buffer)))
 808     (when (setq olist (nreverse olist))
 809       (insert "------------------ Environment follows ------------------\n\n"))
 810     (while olist
 811       (if (boundp (car olist))
 812           (condition-case ()
 813               (pp `(setq ,(car olist)
 814                          ,(if (or (consp (setq sym (symbol-value (car olist))))
 815                                   (and (symbolp sym)
 816                                        (not (or (eq sym nil)
 817                                                 (eq sym t)))))
 818                               (list 'quote (symbol-value (car olist)))
 819                             (symbol-value (car olist))))
 820                   (current-buffer))
 821             (error
 822              (format "(setq %s 'whatever)\n" (car olist))))
 823         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
 824       (setq olist (cdr olist)))
 825     (insert "\n\n")
 826     ;; Remove any null chars - they seem to cause trouble for some
 827     ;; mailers.  (Byte-compiled output from the stuff above.)
 828     (goto-char (point-min))
 829     (while (re-search-forward "[\000\200]" nil t)
 830       (replace-match "" t t))))
 831
 832 ;;; Treatment of rejected articles.
 833 ;;; Bounced mail.
 834
 835 (defun gnus-summary-resend-bounced-mail (&optional fetch)
 836   "Re-mail the current message.
 837 This only makes sense if the current message is a bounce message than
 838 contains some mail you have written which has been bounced back to
 839 you.
 840 If FETCH, try to fetch the article that this is a reply to, if indeed
 841 this is a reply."
 842   (interactive "P")
 843   (gnus-summary-select-article t)
 844   (set-buffer gnus-original-article-buffer)
 845   (gnus-setup-message 'compose-bounce
 846     (let* ((references (mail-fetch-field "references"))
 847            (parent (and references (gnus-parent-id references))))
 848       (message-bounce)
 849       ;; If there are references, we fetch the article we answered to.
 850       (and fetch parent
 851            (gnus-summary-refer-article parent)
 852            (gnus-summary-show-all-headers)))))
 853
 854 ;;; Gcc handling.
 855
 856 ;; Do Gcc handling, which copied the message over to some group.
 857 (defun gnus-inews-do-gcc (&optional gcc)
 858   (when (gnus-alive-p)
 859     (save-excursion
 860       (save-restriction
 861         (message-narrow-to-headers)
 862         (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
 863               (cur (current-buffer))
 864               groups group method)
 865           (when gcc
 866             (message-remove-header "gcc")
 867             (widen)
 868             (setq groups (message-tokenize-header gcc " ,"))
 869             ;; Copy the article over to some group(s).
 870             (while (setq group (pop groups))
 871               (gnus-check-server
 872                (setq method
 873                      (cond ((and (null (gnus-get-info group))
 874                                  (eq (car gnus-message-archive-method)
 875                                      (car
 876                                       (gnus-server-to-method
 877                                        (gnus-group-method group)))))
 878                             ;; If the group doesn't exist, we assume
 879                             ;; it's an archive group...
 880                             gnus-message-archive-method)
 881                            ;; Use the method.
 882                            ((gnus-info-method (gnus-get-info group))
 883                             (gnus-info-method (gnus-get-info group)))
 884                            ;; Find the method.
 885                            (t (gnus-group-method group)))))
 886               (gnus-check-server method)
 887               (unless (gnus-request-group group t method)
 888                 (gnus-request-create-group group method))
 889               (save-excursion
 890                 (nnheader-set-temp-buffer " *acc*")
 891                 (insert-buffer-substring cur)
 892                 (goto-char (point-min))
 893                 (when (re-search-forward
 894                        (concat "^" (regexp-quote mail-header-separator) "$")
 895                        nil t)
 896                   (replace-match "" t t ))
 897                 (unless (gnus-request-accept-article group method t)
 898                   (gnus-message 1 "Couldn't store article in group %s: %s"
 899                                 group (gnus-status-message method))
 900                   (sit-for 2))
 901                 (kill-buffer (current-buffer))))))))))
 902
 903 (defun gnus-inews-insert-gcc ()
 904   "Insert Gcc headers based on `gnus-outgoing-message-group'."
 905   (save-excursion
 906     (save-restriction
 907       (gnus-inews-narrow-to-headers)
 908       (let* ((group gnus-outgoing-message-group)
 909              (gcc (cond
 910                    ((gnus-functionp group)
 911                     (funcall group))
 912                    ((or (stringp group) (list group))
 913                     group))))
 914         (when gcc
 915           (insert "Gcc: "
 916                   (if (stringp gcc) gcc
 917                     (mapconcat 'identity gcc " "))
 918                   "\n"))))))
 919
 920 (defun gnus-inews-insert-archive-gcc (&optional group)
 921   "Insert the Gcc to say where the article is to be archived."
 922   (let* ((var gnus-message-archive-group)
 923          (group (or group gnus-newsgroup-name ""))
 924          result
 925          gcc-self-val
 926          (groups
 927           (cond
 928            ((null gnus-message-archive-method)
 929             ;; Ignore.
 930             nil)
 931            ((stringp var)
 932             ;; Just a single group.
 933             (list var))
 934            ((null var)
 935             ;; We don't want this.
 936             nil)
 937            ((and (listp var) (stringp (car var)))
 938             ;; A list of groups.
 939             var)
 940            ((gnus-functionp var)
 941             ;; A function.
 942             (funcall var group))
 943            (t
 944             ;; An alist of regexps/functions/forms.
 945             (while (and var
 946                         (not
 947                          (setq result
 948                                (cond
 949                                 ((stringp (caar var))
 950                                  ;; Regexp.
 951                                  (when (string-match (caar var) group)
 952                                    (cdar var)))
 953                                 ((gnus-functionp (car var))
 954                                  ;; Function.
 955                                  (funcall (car var) group))
 956                                 (t
 957                                  (eval (car var)))))))
 958               (setq var (cdr var)))
 959             result)))
 960          name)
 961     (when groups
 962       (when (stringp groups)
 963         (setq groups (list groups)))
 964       (save-excursion
 965         (save-restriction
 966           (gnus-inews-narrow-to-headers)
 967           (goto-char (point-max))
 968           (insert "Gcc: ")
 969           (if (and gnus-newsgroup-name
 970                    (setq gcc-self-val
 971                          (gnus-group-find-parameter
 972                           gnus-newsgroup-name 'gcc-self)))
 973               (progn
 974                 (insert
 975                  (if (stringp gcc-self-val)
 976                      gcc-self-val
 977                    group))
 978                 (if (not (eq gcc-self-val 'none))
 979                     (insert "\n")
 980                   (progn
 981                     (beginning-of-line)
 982                     (kill-line))))
 983             (while (setq name (pop groups))
 984               (insert (if (string-match ":" name)
 985                           name
 986                         (gnus-group-prefixed-name
 987                          name gnus-message-archive-method)))
 988               (when groups
 989                 (insert " ")))
 990             (insert "\n")))))))
 991
 992 (defun gnus-summary-send-draft ()
 993   "Enter a mail/post buffer to edit and send the draft."
 994   (interactive)
 995   (gnus-set-global-variables)
 996   (let (buf)
 997     (if (not (setq buf (gnus-request-restore-buffer
 998                         (gnus-summary-article-number) gnus-newsgroup-name)))
 999         (error "Couldn't restore the article")
1000       (switch-to-buffer buf)
1001       (when (eq major-mode 'news-reply-mode)
1002         (local-set-key "\C-c\C-c" 'gnus-inews-news))
1003       ;; Insert the separator.
1004       (goto-char (point-min))
1005       (search-forward "\n\n")
1006       (forward-char -1)
1007       (insert mail-header-separator)
1008       ;; Configure windows.
1009       (let ((gnus-draft-buffer (current-buffer)))
1010         (gnus-configure-windows 'draft t)
1011         (goto-char (point))))))
1012
1013 (gnus-add-shutdown 'gnus-inews-close 'gnus)
1014
1015 (defun gnus-inews-close ()
1016   (setq gnus-inews-sent-ids nil))
1017
1018 ;;; Allow redefinition of functions.
1019
1020 (gnus-ems-redefine)
1021
1022 (provide 'gnus-msg)
1023
1024 ;;; gnus-msg.el ends here