cgit.sxemacs.org Git - gnus/blob - lisp/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (require 'gnus-ems)
  34 (require 'message)
  35 (require 'gnus-art)
  36 (require 'gnus-util)
  37
  38 (defcustom gnus-post-method 'current
  39   "*Preferred method for posting USENET news.
  40
  41 If this variable is `current' (which is the default), Gnus will use
  42 the \"current\" select method when posting.  If it is `native', Gnus
  43 will use the native select method when posting.
  44
  45 This method will not be used in mail groups and the like, only in
  46 \"real\" newsgroups.
  47
  48 If not `native' nor `current', the value must be a valid method as discussed
  49 in the documentation of `gnus-select-method'.  It can also be a list of
  50 methods.  If that is the case, the user will be queried for what select
  51 method to use when posting."
  52   :group 'gnus-group-foreign
  53   :link '(custom-manual "(gnus)Posting Server")
  54   :type `(choice (const native)
  55                  (const current)
  56                  (sexp :tag "Methods" ,gnus-select-method)))
  57
  58 (defcustom gnus-outgoing-message-group nil
  59   "*All outgoing messages will be put in this group.
  60 If you want to store all your outgoing mail and articles in the group
  61 \"nnml:archive\", you set this variable to that value.  This variable
  62 can also be a list of group names.
  63
  64 If you want to have greater control over what group to put each
  65 message in, you can set this variable to a function that checks the
  66 current newsgroup name and then returns a suitable group name (or list
  67 of names)."
  68   :group 'gnus-message
  69   :type '(choice (string :tag "Group")
  70                  (function)))
  71
  72 (defcustom gnus-mailing-list-groups nil
  73   "*If non-nil a regexp matching groups that are really mailing lists.
  74 This is useful when you're reading a mailing list that has been
  75 gatewayed to a newsgroup, and you want to followup to an article in
  76 the group."
  77   :group 'gnus-message
  78   :type '(choice (regexp)
  79                  (const nil)))
  80
  81 (defcustom gnus-add-to-list nil
  82   "*If non-nil, add a `to-list' parameter automatically."
  83   :group 'gnus-message
  84   :type 'boolean)
  85
  86 (defcustom gnus-crosspost-complaint
  87   "Hi,
  88
  89 You posted the article below with the following Newsgroups header:
  90
  91 Newsgroups: %s
  92
  93 The %s group, at least, was an inappropriate recipient
  94 of this message.  Please trim your Newsgroups header to exclude this
  95 group before posting in the future.
  96
  97 Thank you.
  98
  99 "
 100   "Format string to be inserted when complaining about crossposts.
 101 The first %s will be replaced by the Newsgroups header;
 102 the second with the current group name."
 103   :group 'gnus-message
 104   :type 'string)
 105
 106 (defcustom gnus-message-setup-hook nil
 107   "Hook run after setting up a message buffer."
 108   :group 'gnus-message
 109   :type 'hook)
 110
 111 (defcustom gnus-bug-create-help-buffer t
 112   "*Should we create the *Gnus Help Bug* buffer?"
 113   :group 'gnus-message
 114   :type 'boolean)
 115
 116 (defcustom gnus-posting-styles nil
 117   "*Alist of styles to use when posting.
 118 See Info node `(gnus)Posting Styles'."
 119   :group 'gnus-message
 120   :link '(custom-manual "(gnus)Posting Styles")
 121   :type '(repeat (cons (choice (regexp)
 122                                (variable)
 123                                (list (const header)
 124                                      (string :tag "Header")
 125                                      (regexp :tag "Regexp"))
 126                                (function)
 127                                (sexp))
 128                        (repeat (list
 129                                 (choice (const signature)
 130                                         (const signature-file)
 131                                         (const organization)
 132                                         (const address)
 133                                         (const x-face-file)
 134                                         (const name)
 135                                         (const body)
 136                                         (symbol)
 137                                         (string :tag "Header"))
 138                                 (choice (string)
 139                                         (function)
 140                                         (variable)
 141                                         (sexp)))))))
 142
 143 (defcustom gnus-gcc-mark-as-read nil
 144   "If non-nil, automatically mark Gcc articles as read."
 145   :version "21.1"
 146   :group 'gnus-message
 147   :type 'boolean)
 148
 149 (make-obsolete-variable 'gnus-inews-mark-gcc-as-read
 150                         'gnus-gcc-mark-as-read)
 151
 152 (defcustom gnus-gcc-externalize-attachments nil
 153   "Should local-file attachments be included as external parts in Gcc copies?
 154 If it is `all', attach files as external parts;
 155 if a regexp and matches the Gcc group name, attach files as external parts;
 156 if nil, attach files as normal parts."
 157   :version "21.1"
 158   :group 'gnus-message
 159   :type '(choice (const nil :tag "None")
 160                  (const all :tag "Any")
 161                  (string :tag "Regexp")))
 162
 163 (gnus-define-group-parameter
 164  posting-charset-alist
 165  :type list
 166  :function-document
 167  "Return the permitted unencoded charsets for posting of GROUP."
 168  :variable gnus-group-posting-charset-alist
 169  :variable-default
 170   '(("^\\(no\\|fr\\)\\.[^,]*\\(,[ \t\n]*\\(no\\|fr\\)\\.[^,]*\\)*$" iso-8859-1 (iso-8859-1))
 171     ("^\\(fido7\\|relcom\\)\\.[^,]*\\(,[ \t\n]*\\(fido7\\|relcom\\)\\.[^,]*\\)*$" koi8-r (koi8-r))
 172     (message-this-is-mail nil nil)
 173     (message-this-is-news nil t))
 174  :variable-document
 175   "Alist of regexps and permitted unencoded charsets for posting.
 176 Each element of the alist has the form (TEST HEADER BODY-LIST), where
 177 TEST is either a regular expression matching the newsgroup header or a
 178 variable to query,
 179 HEADER is the charset which may be left unencoded in the header (nil
 180 means encode all charsets),
 181 BODY-LIST is a list of charsets which may be encoded using 8bit
 182 content-transfer encoding in the body, or one of the special values
 183 nil (always encode using quoted-printable) or t (always use 8bit).
 184
 185 Note that any value other than nil for HEADER infringes some RFCs, so
 186 use this option with care."
 187  :variable-group gnus-charset
 188  :variable-type
 189  '(repeat (list :tag "Permitted unencoded charsets"
 190                 (choice :tag "Where"
 191                         (regexp :tag "Group")
 192                         (const :tag "Mail message" :value message-this-is-mail)
 193                         (const :tag "News article" :value message-this-is-news))
 194                 (choice :tag "Header"
 195                         (const :tag "None" nil)
 196                         (symbol :tag "Charset"))
 197                 (choice :tag "Body"
 198                         (const :tag "Any" :value t)
 199                         (const :tag "None" :value nil)
 200                         (repeat :tag "Charsets"
 201                                 (symbol :tag "Charset")))))
 202  :parameter-type '(choice :tag "Permitted unencoded charsets"
 203                           :value nil
 204                           (repeat (symbol)))
 205  :parameter-document       "\
 206 List of charsets that are permitted to be unencoded.")
 207
 208 (defcustom gnus-debug-files
 209   '("gnus.el" "gnus-sum.el" "gnus-group.el"
 210     "gnus-art.el" "gnus-start.el" "gnus-async.el"
 211     "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
 212     "gnus-agent.el" "gnus-cache.el" "gnus-srvr.el"
 213     "mm-util.el" "mm-decode.el" "nnmail.el" "message.el")
 214   "Files whose variables will be reported in `gnus-bug'."
 215   :version "21.1"
 216   :group 'gnus-message
 217   :type '(repeat (string :tag "File")))
 218
 219 (defcustom gnus-debug-exclude-variables
 220   '(mm-mime-mule-charset-alist
 221     nnmail-split-fancy message-minibuffer-local-map)
 222   "Variables that should not be reported in `gnus-bug'."
 223   :version "21.1"
 224   :group 'gnus-message
 225   :type '(repeat (symbol :tag "Variable")))
 226
 227 (defcustom gnus-discouraged-post-methods
 228   '(nndraft nnml nnimap nnmaildir nnmh nnfolder nndir)
 229   "A list of back ends that are not used in \"real\" newsgroups.
 230 This variable is used only when `gnus-post-method' is `current'."
 231   :version "21.3"
 232   :group 'gnus-group-foreign
 233   :type '(repeat (symbol :tag "Back end")))
 234
 235 (defcustom gnus-message-replysign
 236   nil
 237   "Automatically sign replies to signed messages.
 238 See also the `mml-default-sign-method' variable."
 239   :group 'gnus-message
 240   :type 'boolean)
 241
 242 (defcustom gnus-message-replyencrypt
 243   nil
 244   "Automatically encrypt replies to encrypted messages.
 245 See also the `mml-default-encrypt-method' variable."
 246   :group 'gnus-message
 247   :type 'boolean)
 248
 249 (defcustom gnus-message-replysignencrypted
 250   t
 251   "Setting this causes automatically encryped messages to also be signed."
 252   :group 'gnus-message
 253   :type 'boolean)
 254
 255 (defcustom gnus-confirm-mail-reply-to-news nil
 256   "If non-nil, Gnus requests confirmation when replying to news.
 257 This is done because new users often reply by mistake when reading
 258 news.
 259 This can also be a function receiving the group name as the only
 260 parameter which should return non-nil iff a confirmation is needed, or
 261 a regexp, in which case a confirmation is asked for iff the group name
 262 matches the regexp."
 263   :group 'gnus-message
 264   :type '(choice (const :tag "No" nil)
 265                  (const :tag "Yes" t)
 266                  (regexp :tag "Iff group matches regexp")
 267                  (function :tag "Iff function evaluates to non-nil")))
 268
 269 (defcustom gnus-confirm-treat-mail-like-news
 270   nil
 271   "If non-nil, Gnus will treat mail like news with regard to confirmation
 272 when replying by mail.  See the `gnus-confirm-mail-reply-to-news' variable
 273 for fine-tuning this.
 274 If nil, Gnus will never ask for confirmation if replying to mail."
 275   :group 'gnus-message
 276   :type 'boolean)
 277
 278 (defcustom gnus-summary-resend-default-address t
 279   "If non-nil, Gnus tries to suggest a default address to resend to.
 280 If nil, the address field will always be empty after invoking
 281 `gnus-summary-resend-message'."
 282   :group 'gnus-message
 283   :type 'boolean)
 284
 285 (defcustom gnus-user-agent 'emacs-gnus-type
 286   "Which information should be exposed in the User-Agent header.
 287
 288 It can be one of the symbols `gnus' \(show only Gnus version\), `emacs-gnus'
 289 \(show only Emacs and Gnus versions\), `emacs-gnus-config' \(same as
 290 `emacs-gnus' plus system configuration\), `emacs-gnus-type' \(same as
 291 `emacs-gnus' plus system type\) or a custom string.  If you set it to a
 292 string, be sure to use a valid format, see RFC 2616."
 293   :group 'gnus-message
 294   :type '(choice
 295           (item :tag "Show Gnus and Emacs versions and system type"
 296                 emacs-gnus-type)
 297           (item :tag "Show Gnus and Emacs versions and system configuration"
 298                 emacs-gnus-config)
 299           (item :tag "Show Gnus and Emacs versions" emacs-gnus)
 300           (item :tag "Show only Gnus version" gnus)
 301           (string :tag "Other")))
 302
 303 ;;; Internal variables.
 304
 305 (defvar gnus-inhibit-posting-styles nil
 306   "Inhibit the use of posting styles.")
 307
 308 (defvar gnus-article-yanked-articles nil)
 309 (defvar gnus-message-buffer "*Mail Gnus*")
 310 (defvar gnus-article-copy nil)
 311 (defvar gnus-check-before-posting nil)
 312 (defvar gnus-last-posting-server nil)
 313 (defvar gnus-message-group-art nil)
 314
 315 (defvar gnus-msg-force-broken-reply-to nil)
 316
 317 (defconst gnus-bug-message
 318   "Sending a bug report to the Gnus Towers.
 319 ========================================
 320
 321 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 322 be sent to the Gnus Bug Exterminators.
 323
 324 The thing near the bottom of the buffer is how the environment
 325 settings will be included in the mail.  Please do not delete that.
 326 They will tell the Bug People what your environment is, so that it
 327 will be easier to locate the bugs.
 328
 329 If you have found a bug that makes Emacs go \"beep\", set
 330 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 331 and include the backtrace in your bug report.
 332
 333 Please describe the bug in annoying, painstaking detail.
 334
 335 Thank you for your help in stamping out bugs.
 336 ")
 337
 338 (eval-and-compile
 339   (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 340   (autoload 'news-setup "rnewspost")
 341   (autoload 'news-reply-mode "rnewspost")
 342   (autoload 'rmail-dont-reply-to "mail-utils")
 343   (autoload 'rmail-output "rmailout"))
 344
 345 \f
 346 ;;;
 347 ;;; Gnus Posting Functions
 348 ;;;
 349
 350 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 351   "p" gnus-summary-post-news
 352   "i" gnus-summary-news-other-window
 353   "f" gnus-summary-followup
 354   "F" gnus-summary-followup-with-original
 355   "c" gnus-summary-cancel-article
 356   "s" gnus-summary-supersede-article
 357   "r" gnus-summary-reply
 358   "y" gnus-summary-yank-message
 359   "R" gnus-summary-reply-with-original
 360   "w" gnus-summary-wide-reply
 361   "W" gnus-summary-wide-reply-with-original
 362   "v" gnus-summary-very-wide-reply
 363   "V" gnus-summary-very-wide-reply-with-original
 364   "n" gnus-summary-followup-to-mail
 365   "N" gnus-summary-followup-to-mail-with-original
 366   "m" gnus-summary-mail-other-window
 367   "u" gnus-uu-post-news
 368   "\M-c" gnus-summary-mail-crosspost-complaint
 369   "Br" gnus-summary-reply-broken-reply-to
 370   "BR" gnus-summary-reply-broken-reply-to-with-original
 371   "om" gnus-summary-mail-forward
 372   "op" gnus-summary-post-forward
 373   "Om" gnus-uu-digest-mail-forward
 374   "Op" gnus-uu-digest-post-forward)
 375
 376 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 377   "b" gnus-summary-resend-bounced-mail
 378   ;; "c" gnus-summary-send-draft
 379   "r" gnus-summary-resend-message
 380   "e" gnus-summary-resend-message-edit)
 381
 382 ;;; Internal functions.
 383
 384 (defun gnus-inews-make-draft ()
 385   `(lambda ()
 386      (gnus-inews-make-draft-meta-information
 387       ,gnus-newsgroup-name ',gnus-article-reply)))
 388
 389 (defvar gnus-article-reply nil)
 390 (defmacro gnus-setup-message (config &rest forms)
 391   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 392         (buffer (make-symbol "gnus-setup-message-buffer"))
 393         (article (make-symbol "gnus-setup-message-article"))
 394         (yanked (make-symbol "gnus-setup-yanked-articles"))
 395         (group (make-symbol "gnus-setup-message-group")))
 396     `(let ((,winconf (current-window-configuration))
 397            (,buffer (buffer-name (current-buffer)))
 398            (,article gnus-article-reply)
 399            (,yanked gnus-article-yanked-articles)
 400            (,group gnus-newsgroup-name)
 401            (message-header-setup-hook
 402             (copy-sequence message-header-setup-hook))
 403            (mbl mml-buffer-list)
 404            (message-mode-hook (copy-sequence message-mode-hook)))
 405        (setq mml-buffer-list nil)
 406        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 407        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 408        ;; #### FIXME: for a reason that I did not manage to identify yet,
 409        ;; the variable `gnus-newsgroup-name' does not honor a dynamically
 410        ;; scoped or setq'ed value from a caller like `C-u gnus-summary-mail'.
 411        ;; After evaluation of @forms below, it gets the value we actually want
 412        ;; to override, and the posting styles are used. For that reason, I've
 413        ;; added an optional argument to `gnus-configure-posting-styles' to
 414        ;; make sure that the correct value for the group name is used. -- drv
 415        (add-hook 'message-mode-hook
 416                  (lambda ()
 417                    (gnus-configure-posting-styles ,group)))
 418        (gnus-pull ',(intern gnus-draft-meta-information-header)
 419                   message-required-headers)
 420        (when (and ,group
 421                   (not (string= ,group "")))
 422          (push (cons
 423                 (intern gnus-draft-meta-information-header)
 424                 (gnus-inews-make-draft))
 425                message-required-headers))
 426        (unwind-protect
 427            (progn
 428              ,@forms)
 429          (gnus-inews-add-send-actions ,winconf ,buffer ,article ,config
 430                                       ,yanked)
 431          (setq gnus-message-buffer (current-buffer))
 432          (set (make-local-variable 'gnus-message-group-art)
 433               (cons ,group ,article))
 434          (set (make-local-variable 'gnus-newsgroup-name) ,group)
 435          (gnus-run-hooks 'gnus-message-setup-hook)
 436          (if (eq major-mode 'message-mode)
 437              (let ((mbl1 mml-buffer-list))
 438                (setq mml-buffer-list mbl)  ;; Global value
 439                (set (make-local-variable 'mml-buffer-list) mbl1);; Local value
 440                ;; LOCAL argument of add-hook differs between GNU Emacs
 441                ;; and XEmacs. make-local-hook makes sure they are local.
 442                (make-local-hook 'kill-buffer-hook)
 443                (make-local-hook 'change-major-mode-hook)
 444                (add-hook 'change-major-mode-hook 'mml-destroy-buffers nil t)
 445                (add-hook 'kill-buffer-hook 'mml-destroy-buffers t t))
 446            (mml-destroy-buffers)
 447            (setq mml-buffer-list mbl)))
 448        (message-hide-headers)
 449        (gnus-add-buffer)
 450        (gnus-configure-windows ,config t)
 451        (run-hooks 'post-command-hook)
 452        (set-buffer-modified-p nil))))
 453
 454 (defun gnus-inews-make-draft-meta-information (group article)
 455   (concat "(\"" group "\" "
 456           (if article (number-to-string
 457                        (if (listp article)
 458                            (car article)
 459                          article)) "\"\"")
 460           ")"))
 461
 462 ;;;###autoload
 463 (defun gnus-msg-mail (&optional to subject other-headers continue
 464                                 switch-action yank-action send-actions)
 465   "Start editing a mail message to be sent.
 466 Like `message-mail', but with Gnus paraphernalia, particularly the
 467 Gcc: header for archiving purposes."
 468   (interactive)
 469   (let ((buf (current-buffer))
 470         mail-buf)
 471     (gnus-setup-message 'message
 472       (message-mail to subject other-headers continue
 473                     nil yank-action send-actions))
 474     (when switch-action
 475       (setq mail-buf (current-buffer))
 476       (switch-to-buffer buf)
 477       (apply switch-action mail-buf nil)))
 478   ;; COMPOSEFUNC should return t if succeed.  Undocumented ???
 479   t)
 480
 481 (defvar save-selected-window-window)
 482
 483 ;;;###autoload
 484 (defun gnus-button-mailto (address)
 485   "Mail to ADDRESS."
 486   (set-buffer (gnus-copy-article-buffer))
 487   (gnus-setup-message 'message
 488     (message-reply address))
 489   (and (boundp 'save-selected-window-window)
 490        (not (window-live-p save-selected-window-window))
 491        (setq save-selected-window-window (selected-window))))
 492
 493 ;;;###autoload
 494 (defun gnus-button-reply (&optional to-address wide)
 495   "Like `message-reply'."
 496   (interactive)
 497   (gnus-setup-message 'message
 498     (message-reply to-address wide))
 499   (and (boundp 'save-selected-window-window)
 500        (not (window-live-p save-selected-window-window))
 501        (setq save-selected-window-window (selected-window))))
 502
 503 ;;;###autoload
 504 (define-mail-user-agent 'gnus-user-agent
 505   'gnus-msg-mail 'message-send-and-exit
 506   'message-kill-buffer 'message-send-hook)
 507
 508 (defun gnus-setup-posting-charset (group)
 509   (let ((alist gnus-group-posting-charset-alist)
 510         (group (or group ""))
 511         elem)
 512     (when group
 513       (catch 'found
 514         (while (setq elem (pop alist))
 515           (when (or (and (stringp (car elem))
 516                          (string-match (car elem) group))
 517                     (and (gnus-functionp (car elem))
 518                          (funcall (car elem) group))
 519                     (and (symbolp (car elem))
 520                          (symbol-value (car elem))))
 521             (throw 'found (cons (cadr elem) (caddr elem)))))))))
 522
 523 (defun gnus-inews-add-send-actions (winconf buffer article
 524                                             &optional config yanked)
 525   (make-local-hook 'message-sent-hook)
 526   (add-hook 'message-sent-hook (if gnus-agent 'gnus-agent-possibly-do-gcc
 527                                  'gnus-inews-do-gcc) nil t)
 528   (when gnus-agent
 529     (make-local-hook 'message-header-hook)
 530     (add-hook 'message-header-hook 'gnus-agent-possibly-save-gcc nil t))
 531   (setq message-post-method
 532         `(lambda (arg)
 533            (gnus-post-method arg ,gnus-newsgroup-name)))
 534   (setq message-newsreader (setq message-mailer (gnus-extended-version)))
 535   (message-add-action
 536    `(when (gnus-buffer-exists-p ,buffer)
 537       (set-window-configuration ,winconf))
 538    'exit 'postpone 'kill)
 539   (let ((to-be-marked (cond
 540                        (yanked yanked)
 541                        (article (if (listp article) article (list article)))
 542                        (t nil))))
 543     (message-add-action
 544      `(when (gnus-buffer-exists-p ,buffer)
 545         (save-excursion
 546           (set-buffer ,buffer)
 547           ,(when to-be-marked
 548              (if (eq config 'forward)
 549                  `(gnus-summary-mark-article-as-forwarded ',to-be-marked)
 550                `(gnus-summary-mark-article-as-replied ',to-be-marked)))))
 551      'send)))
 552
 553 (put 'gnus-setup-message 'lisp-indent-function 1)
 554 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 555
 556 ;;; Post news commands of Gnus group mode and summary mode
 557
 558 (defun gnus-group-mail (&optional arg)
 559   "Start composing a mail.
 560 If ARG, use the group under the point to find a posting style.
 561 If ARG is 1, prompt for a group name to find the posting style."
 562   (interactive "P")
 563   ;; We can't `let' gnus-newsgroup-name here, since that leads
 564   ;; to local variables leaking.
 565   (let ((group gnus-newsgroup-name)
 566         ;; make sure last viewed article doesn't affect posting styles:
 567         (gnus-article-copy)
 568         (buffer (current-buffer)))
 569     (unwind-protect
 570         (progn
 571           (setq gnus-newsgroup-name
 572                 (if arg
 573                     (if (= 1 (prefix-numeric-value arg))
 574                         (completing-read "Use posting style of group: "
 575                                          gnus-active-hashtb nil
 576                                          (gnus-read-active-file-p))
 577                       (gnus-group-group-name))
 578                   ""))
 579           ;; #### see comment in gnus-setup-message -- drv
 580           (gnus-setup-message 'message (message-mail)))
 581       (save-excursion
 582         (set-buffer buffer)
 583         (setq gnus-newsgroup-name group)))))
 584
 585 (defun gnus-group-news (&optional arg)
 586   "Start composing a news.
 587 If ARG, post to group under point.
 588 If ARG is 1, prompt for group name to post to.
 589
 590 This function prepares a news even when using mail groups.  This is useful
 591 for posting messages to mail groups without actually sending them over the
 592 network.  The corresponding backend must have a 'request-post method."
 593   (interactive "P")
 594   ;; We can't `let' gnus-newsgroup-name here, since that leads
 595   ;; to local variables leaking.
 596   (let ((group gnus-newsgroup-name)
 597         ;; make sure last viewed article doesn't affect posting styles:
 598         (gnus-article-copy)
 599         (buffer (current-buffer)))
 600     (unwind-protect
 601         (progn
 602           (setq gnus-newsgroup-name
 603                 (if arg
 604                     (if (= 1 (prefix-numeric-value arg))
 605                         (completing-read "Use group: "
 606                                          gnus-active-hashtb nil
 607                                          (gnus-read-active-file-p))
 608                       (gnus-group-group-name))
 609                   ""))
 610           ;; #### see comment in gnus-setup-message -- drv
 611           (gnus-setup-message 'message
 612             (message-news (gnus-group-real-name gnus-newsgroup-name))))
 613       (save-excursion
 614         (set-buffer buffer)
 615         (setq gnus-newsgroup-name group)))))
 616
 617 (defun gnus-group-post-news (&optional arg)
 618   "Start composing a message (a news by default).
 619 If ARG, post to group under point.  If ARG is 1, prompt for group name.
 620 Depending on the selected group, the message might be either a mail or
 621 a news."
 622   (interactive "P")
 623   ;; Bind this variable here to make message mode hooks work ok.
 624   (let ((gnus-newsgroup-name
 625          (if arg
 626              (if (= 1 (prefix-numeric-value arg))
 627                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 628                                   (gnus-read-active-file-p))
 629                (gnus-group-group-name))
 630            ""))
 631         ;; make sure last viewed article doesn't affect posting styles:
 632         (gnus-article-copy))
 633     (gnus-post-news 'post gnus-newsgroup-name nil nil nil nil
 634                     (string= gnus-newsgroup-name ""))))
 635
 636 (defun gnus-summary-mail-other-window (&optional arg)
 637   "Start composing a mail in another window.
 638 Use the posting of the current group by default.
 639 If ARG, don't do that.  If ARG is 1, prompt for group name to find the
 640 posting style."
 641   (interactive "P")
 642   ;; We can't `let' gnus-newsgroup-name here, since that leads
 643   ;; to local variables leaking.
 644   (let ((group gnus-newsgroup-name)
 645         ;; make sure last viewed article doesn't affect posting styles:
 646         (gnus-article-copy)
 647         (buffer (current-buffer)))
 648     (unwind-protect
 649         (progn
 650           (setq gnus-newsgroup-name
 651                 (if arg
 652                     (if (= 1 (prefix-numeric-value arg))
 653                         (completing-read "Use group: "
 654                                          gnus-active-hashtb nil
 655                                          (gnus-read-active-file-p))
 656                       "")
 657                   gnus-newsgroup-name))
 658           ;; #### see comment in gnus-setup-message -- drv
 659           (gnus-setup-message 'message (message-mail)))
 660       (save-excursion
 661         (set-buffer buffer)
 662         (setq gnus-newsgroup-name group)))))
 663
 664 (defun gnus-summary-news-other-window (&optional arg)
 665   "Start composing a news in another window.
 666 Post to the current group by default.
 667 If ARG, don't do that.  If ARG is 1, prompt for group name to post to.
 668
 669 This function prepares a news even when using mail groups.  This is useful
 670 for posting messages to mail groups without actually sending them over the
 671 network.  The corresponding backend must have a 'request-post method."
 672   (interactive "P")
 673   ;; We can't `let' gnus-newsgroup-name here, since that leads
 674   ;; to local variables leaking.
 675   (let ((group gnus-newsgroup-name)
 676         ;; make sure last viewed article doesn't affect posting styles:
 677         (gnus-article-copy)
 678         (buffer (current-buffer)))
 679     (unwind-protect
 680         (progn
 681           (setq gnus-newsgroup-name
 682                 (if arg
 683                     (if (= 1 (prefix-numeric-value arg))
 684                         (completing-read "Use group: "
 685                                          gnus-active-hashtb nil
 686                                          (gnus-read-active-file-p))
 687                       "")
 688                   gnus-newsgroup-name))
 689           ;; #### see comment in gnus-setup-message -- drv
 690           (gnus-setup-message 'message
 691             (progn
 692               (message-news (gnus-group-real-name gnus-newsgroup-name))
 693               (set (make-local-variable 'gnus-discouraged-post-methods)
 694                    (delq
 695                     (car (gnus-find-method-for-group gnus-newsgroup-name))
 696                     (copy-sequence gnus-discouraged-post-methods))))))
 697       (save-excursion
 698         (set-buffer buffer)
 699         (setq gnus-newsgroup-name group)))))
 700
 701 (defun gnus-summary-post-news (&optional arg)
 702   "Start composing a message.  Post to the current group by default.
 703 If ARG, don't do that.  If ARG is 1, prompt for a group name to post to.
 704 Depending on the selected group, the message might be either a mail or
 705 a news."
 706   (interactive "P")
 707   ;; Bind this variable here to make message mode hooks work ok.
 708   (let ((gnus-newsgroup-name
 709          (if arg
 710              (if (= 1 (prefix-numeric-value arg))
 711                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 712                                   (gnus-read-active-file-p))
 713                "")
 714            gnus-newsgroup-name))
 715         ;; make sure last viewed article doesn't affect posting styles:
 716         (gnus-article-copy))
 717     (gnus-post-news 'post gnus-newsgroup-name)))
 718
 719
 720 (defun gnus-summary-followup (yank &optional force-news)
 721   "Compose a followup to an article.
 722 If prefix argument YANK is non-nil, the original article is yanked
 723 automatically.
 724 YANK is a list of elements, where the car of each element is the
 725 article number, and the two following numbers is the region to be
 726 yanked."
 727   (interactive
 728    (list (and current-prefix-arg
 729               (gnus-summary-work-articles 1))))
 730   (when yank
 731     (gnus-summary-goto-subject
 732      (if (listp (car yank))
 733          (caar yank)
 734        (car yank))))
 735   (save-window-excursion
 736     (gnus-summary-select-article))
 737   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 738         (gnus-newsgroup-name gnus-newsgroup-name))
 739     ;; Send a followup.
 740     (gnus-post-news nil gnus-newsgroup-name
 741                     headers gnus-article-buffer
 742                     yank nil force-news)
 743     (gnus-summary-handle-replysign)))
 744
 745 (defun gnus-summary-followup-with-original (n &optional force-news)
 746   "Compose a followup to an article and include the original article."
 747   (interactive "P")
 748   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 749
 750 (defun gnus-summary-followup-to-mail (&optional arg)
 751   "Followup to the current mail message via news."
 752   (interactive
 753    (list (and current-prefix-arg
 754               (gnus-summary-work-articles 1))))
 755   (gnus-summary-followup arg t))
 756
 757 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 758   "Followup to the current mail message via news."
 759   (interactive "P")
 760   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 761
 762 (defun gnus-inews-yank-articles (articles)
 763   (let (beg article yank-string)
 764     (message-goto-body)
 765     (while (setq article (pop articles))
 766       (when (listp article)
 767         (setq yank-string (nth 1 article)
 768               article (nth 0 article)))
 769       (save-window-excursion
 770         (set-buffer gnus-summary-buffer)
 771         (gnus-summary-select-article nil nil nil article)
 772         (gnus-summary-remove-process-mark article))
 773       (gnus-copy-article-buffer nil yank-string)
 774       (let ((message-reply-buffer gnus-article-copy)
 775             (message-reply-headers
 776              ;; The headers are decoded.
 777              (with-current-buffer gnus-article-copy
 778                (save-restriction
 779                  (nnheader-narrow-to-headers)
 780                  (nnheader-parse-naked-head)))))
 781         (message-yank-original)
 782         (setq beg (or beg (mark t))))
 783       (when articles
 784         (insert "\n")))
 785     (push-mark)
 786     (goto-char beg)))
 787
 788 (defun gnus-summary-cancel-article (&optional n symp)
 789   "Cancel an article you posted.
 790 Uses the process-prefix convention.  If given the symbolic
 791 prefix `a', cancel using the standard posting method; if not
 792 post using the current select method."
 793   (interactive (gnus-interactive "P\ny"))
 794   (let ((articles (gnus-summary-work-articles n))
 795         (message-post-method
 796          `(lambda (arg)
 797             (gnus-post-method (eq ',symp 'a) ,gnus-newsgroup-name)))
 798         article)
 799     (while (setq article (pop articles))
 800       (when (gnus-summary-select-article t nil nil article)
 801         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 802                 (message-cancel-news))
 803           (gnus-summary-mark-as-read article gnus-canceled-mark)
 804           (gnus-cache-remove-article 1))
 805         (gnus-article-hide-headers-if-wanted))
 806       (gnus-summary-remove-process-mark article))))
 807
 808 (defun gnus-summary-supersede-article ()
 809   "Compose an article that will supersede a previous article.
 810 This is done simply by taking the old article and adding a Supersedes
 811 header line with the old Message-ID."
 812   (interactive)
 813   (let ((article (gnus-summary-article-number)))
 814     (gnus-setup-message 'reply-yank
 815       (gnus-summary-select-article t)
 816       (set-buffer gnus-original-article-buffer)
 817       (message-supersede)
 818       (push
 819        `((lambda ()
 820            (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 821              (save-excursion
 822                (set-buffer ,gnus-summary-buffer)
 823                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 824                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 825        message-send-actions))))
 826
 827 \f
 828
 829 (defun gnus-copy-article-buffer (&optional article-buffer yank-string)
 830   ;; make a copy of the article buffer with all text properties removed
 831   ;; this copy is in the buffer gnus-article-copy.
 832   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 833   ;; this buffer should be passed to all mail/news reply/post routines.
 834   (setq gnus-article-copy (gnus-get-buffer-create " *gnus article copy*"))
 835   (save-excursion
 836     (set-buffer gnus-article-copy)
 837     (mm-enable-multibyte))
 838   (let ((article-buffer (or article-buffer gnus-article-buffer))
 839         end beg)
 840     (if (not (and (get-buffer article-buffer)
 841                   (gnus-buffer-exists-p article-buffer)))
 842         (error "Can't find any article buffer")
 843       (save-excursion
 844         (set-buffer article-buffer)
 845         (let ((gnus-newsgroup-charset (or gnus-article-charset
 846                                           gnus-newsgroup-charset))
 847               (gnus-newsgroup-ignored-charsets
 848                (or gnus-article-ignored-charsets
 849                    gnus-newsgroup-ignored-charsets)))
 850           (save-restriction
 851             ;; Copy over the (displayed) article buffer, delete
 852             ;; hidden text and remove text properties.
 853             (widen)
 854             (copy-to-buffer gnus-article-copy (point-min) (point-max))
 855             (set-buffer gnus-article-copy)
 856             (when yank-string
 857               (message-goto-body)
 858               (delete-region (point) (point-max))
 859               (insert yank-string))
 860             (gnus-article-delete-text-of-type 'annotation)
 861             (gnus-remove-text-with-property 'gnus-prev)
 862             (gnus-remove-text-with-property 'gnus-next)
 863             (gnus-remove-text-with-property 'gnus-decoration)
 864             (insert
 865              (prog1
 866                  (buffer-substring-no-properties (point-min) (point-max))
 867                (erase-buffer)))
 868             ;; Find the original headers.
 869             (set-buffer gnus-original-article-buffer)
 870             (goto-char (point-min))
 871             (while (looking-at message-unix-mail-delimiter)
 872               (forward-line 1))
 873             (let ((mail-header-separator ""))
 874               (setq beg (point)
 875                     end (or (message-goto-body)
 876                             ;; There may be just a header.
 877                             (point-max))))
 878             ;; Delete the headers from the displayed articles.
 879             (set-buffer gnus-article-copy)
 880             (let ((mail-header-separator ""))
 881               (delete-region (goto-char (point-min))
 882                              (or (message-goto-body) (point-max))))
 883             ;; Insert the original article headers.
 884             (insert-buffer-substring gnus-original-article-buffer beg end)
 885             ;; Decode charsets.
 886             (let ((gnus-article-decode-hook
 887                    (delq 'article-decode-charset
 888                          (copy-sequence gnus-article-decode-hook))))
 889               (run-hooks 'gnus-article-decode-hook)))))
 890       gnus-article-copy)))
 891
 892 (defun gnus-post-news (post &optional group header article-buffer yank subject
 893                             force-news)
 894   (when article-buffer
 895     (gnus-copy-article-buffer))
 896   (let ((gnus-article-reply (and article-buffer (gnus-summary-article-number)))
 897         (gnus-article-yanked-articles yank)
 898         (add-to-list gnus-add-to-list))
 899     (gnus-setup-message (cond (yank 'reply-yank)
 900                               (article-buffer 'reply)
 901                               (t 'message))
 902       (let* ((group (or group gnus-newsgroup-name))
 903              (charset (gnus-group-name-charset nil group))
 904              (pgroup group)
 905              to-address to-group mailing-list to-list
 906              newsgroup-p)
 907         (when group
 908           (setq to-address (gnus-parameter-to-address group)
 909                 to-group (gnus-group-find-parameter group 'to-group)
 910                 to-list (gnus-parameter-to-list group)
 911                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 912                 mailing-list (when gnus-mailing-list-groups
 913                                (string-match gnus-mailing-list-groups group))
 914                 group (gnus-group-name-decode (gnus-group-real-name group)
 915                                               charset)))
 916         (if (or (and to-group
 917                      (gnus-news-group-p to-group))
 918                 newsgroup-p
 919                 force-news
 920                 (and (gnus-news-group-p
 921                       (or pgroup gnus-newsgroup-name)
 922                       (or header gnus-current-article))
 923                      (not mailing-list)
 924                      (not to-list)
 925                      (not to-address)))
 926             ;; This is news.
 927             (if post
 928                 (message-news (or to-group group))
 929               (set-buffer gnus-article-copy)
 930               (gnus-msg-treat-broken-reply-to)
 931               (message-followup (if (or newsgroup-p force-news)
 932                                     (if (save-restriction
 933                                           (article-narrow-to-head)
 934                                           (message-fetch-field "newsgroups"))
 935                                         nil
 936                                       "")
 937                                   to-group)))
 938           ;; The is mail.
 939           (if post
 940               (progn
 941                 (message-mail (or to-address to-list))
 942                 ;; Arrange for mail groups that have no `to-address' to
 943                 ;; get that when the user sends off the mail.
 944                 (when (and (not to-list)
 945                            (not to-address)
 946                            add-to-list)
 947                   (push (list 'gnus-inews-add-to-address pgroup)
 948                         message-send-actions)))
 949             (set-buffer gnus-article-copy)
 950             (gnus-msg-treat-broken-reply-to)
 951             (message-wide-reply to-address)))
 952         (when yank
 953           (gnus-inews-yank-articles yank))))))
 954
 955 (defun gnus-msg-treat-broken-reply-to (&optional force)
 956   "Remove the Reply-to header if broken-reply-to."
 957   (when (or force
 958             (gnus-group-find-parameter
 959              gnus-newsgroup-name 'broken-reply-to))
 960     (save-restriction
 961       (message-narrow-to-head)
 962       (message-remove-header "reply-to"))))
 963
 964 (defun gnus-post-method (arg group &optional silent)
 965   "Return the posting method based on GROUP and ARG.
 966 If SILENT, don't prompt the user."
 967   (let ((gnus-post-method (or (gnus-parameter-post-method group)
 968                               gnus-post-method))
 969         (group-method (gnus-find-method-for-group group)))
 970     (cond
 971      ;; If the group-method is nil (which shouldn't happen) we use
 972      ;; the default method.
 973      ((null group-method)
 974       (or (and (listp gnus-post-method) ;If not current/native/nil
 975                (not (listp (car gnus-post-method))) ; and not a list of methods
 976                gnus-post-method)        ;then use it.
 977           gnus-select-method
 978           message-post-method))
 979      ;; We want the inverse of the default
 980      ((and arg (not (eq arg 0)))
 981       (if (eq gnus-post-method 'current)
 982           gnus-select-method
 983         group-method))
 984      ;; We query the user for a post method.
 985      ((or arg
 986           (and (listp gnus-post-method)
 987                (listp (car gnus-post-method))))
 988       (let* ((methods
 989               ;; Collect all methods we know about.
 990               (append
 991                (when (listp gnus-post-method)
 992                  (if (listp (car gnus-post-method))
 993                      gnus-post-method
 994                    (list gnus-post-method)))
 995                gnus-secondary-select-methods
 996                (mapcar 'cdr gnus-server-alist)
 997                (mapcar 'car gnus-opened-servers)
 998                (list gnus-select-method)
 999                (list group-method)))
1000              method-alist post-methods method)
1001         ;; Weed out all mail methods.
1002         (while methods
1003           (setq method (gnus-server-get-method "" (pop methods)))
1004           (when (and (or (gnus-method-option-p method 'post)
1005                          (gnus-method-option-p method 'post-mail))
1006                      (not (member method post-methods)))
1007             (push method post-methods)))
1008         ;; Create a name-method alist.
1009         (setq method-alist
1010               (mapcar
1011                (lambda (m)
1012                  (if (equal (cadr m) "")
1013                      (list (symbol-name (car m)) m)
1014                    (list (concat (cadr m) " (" (symbol-name (car m)) ")") m)))
1015                post-methods))
1016         ;; Query the user.
1017         (cadr
1018          (assoc
1019           (setq gnus-last-posting-server
1020                 (if (and silent
1021                          gnus-last-posting-server)
1022                     ;; Just use the last value.
1023                     gnus-last-posting-server
1024                   (completing-read
1025                    "Posting method: " method-alist nil t
1026                    (cons (or gnus-last-posting-server "") 0))))
1027           method-alist))))
1028      ;; Override normal method.
1029      ((and (eq gnus-post-method 'current)
1030            (not (memq (car group-method) gnus-discouraged-post-methods))
1031            (gnus-get-function group-method 'request-post t))
1032       (assert (not arg))
1033       group-method)
1034      ;; Use gnus-post-method.
1035      ((listp gnus-post-method)          ;A method...
1036       (assert (not (listp (car gnus-post-method)))) ;... not a list of methods.
1037       gnus-post-method)
1038      ;; Use the normal select method (nil or native).
1039      (t gnus-select-method))))
1040
1041 \f
1042
1043 ;; Dummies to avoid byte-compile warning.
1044 (eval-when-compile
1045   (defvar nnspool-rejected-article-hook)
1046   (defvar xemacs-codename))
1047
1048 (defun gnus-extended-version ()
1049   "Stringified Gnus version and Emacs version.
1050 See the variable `gnus-user-agent'."
1051   (interactive)
1052   (let* ((gnus-v
1053           (concat "Gnus/"
1054                   (prin1-to-string (gnus-continuum-version gnus-version) t)
1055                   " (" gnus-version ")"))
1056          (system-v
1057           (cond
1058            ((eq gnus-user-agent 'emacs-gnus-config)
1059             system-configuration)
1060            ((eq gnus-user-agent 'emacs-gnus-type)
1061             (symbol-name system-type))
1062            (t nil)))
1063          (emacs-v
1064           (cond
1065            ((eq gnus-user-agent 'gnus)
1066             nil)
1067            ((string-match "^\\(\\([.0-9]+\\)*\\)\\.[0-9]+$" emacs-version)
1068             (concat "Emacs/" (match-string 1 emacs-version)
1069                     (if system-v
1070                         (concat " (" system-v ")")
1071                       "")))
1072            ((string-match
1073              "\\([A-Z]*[Mm][Aa][Cc][Ss]\\)[^(]*\\(\\((beta.*)\\|'\\)\\)?"
1074              emacs-version)
1075             (concat
1076              (match-string 1 emacs-version)
1077              (format "/%d.%d" emacs-major-version emacs-minor-version)
1078              (if (match-beginning 3)
1079                  (match-string 3 emacs-version)
1080                "")
1081              (if (boundp 'xemacs-codename)
1082                  (concat
1083                   " (" xemacs-codename
1084                   (if system-v
1085                       (concat ", " system-v ")")
1086                     ")"))
1087                "")))
1088            (t emacs-version))))
1089     (if (stringp gnus-user-agent)
1090         gnus-user-agent
1091       (concat gnus-v
1092               (when emacs-v
1093                 (concat " " emacs-v))))))
1094
1095 \f
1096 ;;;
1097 ;;; Gnus Mail Functions
1098 ;;;
1099
1100 ;;; Mail reply commands of Gnus summary mode
1101
1102 (defun gnus-summary-reply (&optional yank wide very-wide)
1103   "Start composing a mail reply to the current message.
1104 If prefix argument YANK is non-nil, the original article is yanked
1105 automatically.
1106 If WIDE, make a wide reply.
1107 If VERY-WIDE, make a very wide reply."
1108   (interactive
1109    (list (and current-prefix-arg
1110               (gnus-summary-work-articles 1))))
1111   ;; Allow user to require confirmation before replying by mail to the
1112   ;; author of a news article (or mail message).
1113   (when (or
1114             (not (or (gnus-news-group-p gnus-newsgroup-name)
1115                      gnus-confirm-treat-mail-like-news))
1116             (not (cond ((stringp gnus-confirm-mail-reply-to-news)
1117                         (string-match gnus-confirm-mail-reply-to-news
1118                                       gnus-newsgroup-name))
1119                        ((functionp gnus-confirm-mail-reply-to-news)
1120                         (funcall gnus-confirm-mail-reply-to-news gnus-newsgroup-name))
1121                        (t gnus-confirm-mail-reply-to-news)))
1122             (y-or-n-p "Really reply by mail to article author? "))
1123     (let* ((article
1124             (if (listp (car yank))
1125                 (caar yank)
1126               (car yank)))
1127            (gnus-article-reply (or article (gnus-summary-article-number)))
1128            (gnus-article-yanked-articles yank)
1129            (headers ""))
1130       ;; Stripping headers should be specified with mail-yank-ignored-headers.
1131       (when yank
1132         (gnus-summary-goto-subject article))
1133       (gnus-setup-message (if yank 'reply-yank 'reply)
1134         (if (not very-wide)
1135             (gnus-summary-select-article)
1136           (dolist (article very-wide)
1137             (gnus-summary-select-article nil nil nil article)
1138             (save-excursion
1139               (set-buffer (gnus-copy-article-buffer))
1140               (gnus-msg-treat-broken-reply-to)
1141               (save-restriction
1142                 (message-narrow-to-head)
1143                 (setq headers (concat headers (buffer-string)))))))
1144         (set-buffer (gnus-copy-article-buffer))
1145         (gnus-msg-treat-broken-reply-to gnus-msg-force-broken-reply-to)
1146         (save-restriction
1147           (message-narrow-to-head)
1148           (when very-wide
1149             (erase-buffer)
1150             (insert headers))
1151           (goto-char (point-max)))
1152         (mml-quote-region (point) (point-max))
1153         (message-reply nil wide)
1154         (when yank
1155           (gnus-inews-yank-articles yank))
1156         (gnus-summary-handle-replysign)))))
1157
1158 (defun gnus-summary-handle-replysign ()
1159   "Check the various replysign variables and take action accordingly."
1160   (when (or gnus-message-replysign gnus-message-replyencrypt)
1161     (let (signed encrypted)
1162       (save-excursion
1163         (set-buffer gnus-article-buffer)
1164         (setq signed (memq 'signed gnus-article-wash-types))
1165         (setq encrypted (memq 'encrypted gnus-article-wash-types)))
1166       (cond ((and gnus-message-replyencrypt encrypted)
1167              (mml-secure-message mml-default-encrypt-method
1168                                  (if gnus-message-replysignencrypted
1169                                      'signencrypt
1170                                    'encrypt)))
1171             ((and gnus-message-replysign signed)
1172              (mml-secure-message mml-default-sign-method 'sign))))))
1173
1174 (defun gnus-summary-reply-with-original (n &optional wide)
1175   "Start composing a reply mail to the current message.
1176 The original article will be yanked."
1177   (interactive "P")
1178   (gnus-summary-reply (gnus-summary-work-articles n) wide))
1179
1180 (defun gnus-summary-reply-broken-reply-to (&optional yank wide very-wide)
1181   "Like `gnus-summary-reply' except removing reply-to field.
1182 If prefix argument YANK is non-nil, the original article is yanked
1183 automatically.
1184 If WIDE, make a wide reply.
1185 If VERY-WIDE, make a very wide reply."
1186   (interactive
1187    (list (and current-prefix-arg
1188               (gnus-summary-work-articles 1))))
1189   (let ((gnus-msg-force-broken-reply-to t))
1190     (gnus-summary-reply yank wide very-wide)))
1191
1192 (defun gnus-summary-reply-broken-reply-to-with-original (n &optional wide)
1193   "Like `gnus-summary-reply-with-original' except removing reply-to field.
1194 The original article will be yanked."
1195   (interactive "P")
1196   (gnus-summary-reply-broken-reply-to (gnus-summary-work-articles n) wide))
1197
1198 (defun gnus-summary-wide-reply (&optional yank)
1199   "Start composing a wide reply mail to the current message.
1200 If prefix argument YANK is non-nil, the original article is yanked
1201 automatically."
1202   (interactive
1203    (list (and current-prefix-arg
1204               (gnus-summary-work-articles 1))))
1205   (gnus-summary-reply yank t))
1206
1207 (defun gnus-summary-wide-reply-with-original (n)
1208   "Start composing a wide reply mail to the current message.
1209 The original article will be yanked."
1210   (interactive "P")
1211   (gnus-summary-reply-with-original n t))
1212
1213 (defun gnus-summary-very-wide-reply (&optional yank)
1214   "Start composing a very wide reply mail to the current message.
1215 If prefix argument YANK is non-nil, the original article is yanked
1216 automatically."
1217   (interactive
1218    (list (and current-prefix-arg
1219               (gnus-summary-work-articles 1))))
1220   (gnus-summary-reply yank t (gnus-summary-work-articles yank)))
1221
1222 (defun gnus-summary-very-wide-reply-with-original (n)
1223   "Start composing a very wide reply mail to the current message.
1224 The original article will be yanked."
1225   (interactive "P")
1226   (gnus-summary-reply
1227    (gnus-summary-work-articles n) t (gnus-summary-work-articles n)))
1228
1229 (defun gnus-summary-mail-forward (&optional arg post)
1230   "Forward the current message(s) to another user.
1231 If process marks exist, forward all marked messages;
1232 if ARG is nil, see `message-forward-as-mime' and `message-forward-show-mml';
1233 if ARG is 1, decode the message and forward directly inline;
1234 if ARG is 2, forward message as an rfc822 MIME section;
1235 if ARG is 3, decode message and forward as an rfc822 MIME section;
1236 if ARG is 4, forward message directly inline;
1237 otherwise, use flipped `message-forward-as-mime'.
1238 If POST, post instead of mail.
1239 For the `inline' alternatives, also see the variable
1240 `message-forward-ignored-headers'."
1241   (interactive "P")
1242   (if (cdr (gnus-summary-work-articles nil))
1243       ;; Process marks are given.
1244       (gnus-uu-digest-mail-forward arg post)
1245     ;; No process marks.
1246     (let ((message-forward-as-mime message-forward-as-mime)
1247           (message-forward-show-mml message-forward-show-mml))
1248       (cond
1249        ((null arg))
1250        ((eq arg 1)
1251         (setq message-forward-as-mime nil
1252               message-forward-show-mml t))
1253        ((eq arg 2)
1254         (setq message-forward-as-mime t
1255               message-forward-show-mml nil))
1256        ((eq arg 3)
1257         (setq message-forward-as-mime t
1258               message-forward-show-mml t))
1259        ((eq arg 4)
1260         (setq message-forward-as-mime nil
1261               message-forward-show-mml nil))
1262        (t
1263         (setq message-forward-as-mime (not message-forward-as-mime))))
1264       (let* ((gnus-article-reply (gnus-summary-article-number))
1265              (gnus-article-yanked-articles (list gnus-article-reply)))
1266         (gnus-setup-message 'forward
1267           (gnus-summary-select-article)
1268           (let ((mail-parse-charset
1269                  (or (and (gnus-buffer-live-p gnus-article-buffer)
1270                           (with-current-buffer gnus-article-buffer
1271                             gnus-article-charset))
1272                      gnus-newsgroup-charset))
1273                 (mail-parse-ignored-charsets
1274                  gnus-newsgroup-ignored-charsets))
1275             (set-buffer gnus-original-article-buffer)
1276             (message-forward post)))))))
1277
1278 (defun gnus-summary-resend-message (address n)
1279   "Resend the current article to ADDRESS."
1280   (interactive
1281    (list (message-read-from-minibuffer
1282           "Resend message(s) to: "
1283           (when (and gnus-summary-resend-default-address
1284                      (gnus-buffer-live-p gnus-original-article-buffer))
1285             ;; If some other article is currently selected, the
1286             ;; initial-contents is wrong. Whatever, it is just the
1287             ;; initial-contents.
1288             (with-current-buffer gnus-original-article-buffer
1289               (nnmail-fetch-field "to"))))
1290          current-prefix-arg))
1291   (let ((articles (gnus-summary-work-articles n))
1292         article)
1293     (while (setq article (pop articles))
1294       (gnus-summary-select-article nil nil nil article)
1295       (save-excursion
1296         (set-buffer gnus-original-article-buffer)
1297         (message-resend address))
1298       (gnus-summary-mark-article-as-forwarded article))))
1299
1300 ;; From: Matthieu Moy <Matthieu.Moy@imag.fr>
1301 (defun gnus-summary-resend-message-edit ()
1302   "Resend an article that has already been sent.
1303 A new buffer will be created to allow the user to modify body and
1304 contents of the message, and then, everything will happen as when
1305 composing a new message."
1306   (interactive)
1307   (let ((article (gnus-summary-article-number)))
1308     (gnus-setup-message 'reply-yank
1309       (gnus-summary-select-article t)
1310       (set-buffer gnus-original-article-buffer)
1311       (let ((cur (current-buffer))
1312             (to (message-fetch-field "to")))
1313         ;; Get a normal message buffer.
1314         (message-pop-to-buffer (message-buffer-name "Resend" to))
1315         (insert-buffer-substring cur)
1316         (mime-to-mml)
1317         (message-narrow-to-head-1)
1318         ;; Gnus will generate a new one when sending.
1319         (message-remove-header "Message-ID")
1320         (message-remove-header message-ignored-resent-headers t)
1321         ;; Remove unwanted headers.
1322         (goto-char (point-max))
1323         (insert mail-header-separator)
1324         (goto-char (point-min))
1325         (re-search-forward "^To:\\|^Newsgroups:" nil 'move)
1326         (forward-char 1)
1327         (widen)))))
1328
1329 (defun gnus-summary-post-forward (&optional arg)
1330   "Forward the current article to a newsgroup.
1331 See `gnus-summary-mail-forward' for ARG."
1332   (interactive "P")
1333   (gnus-summary-mail-forward arg t))
1334
1335 (defvar gnus-nastygram-message
1336   "The following article was inappropriately posted to %s.\n\n"
1337   "Format string to insert in nastygrams.
1338 The current group name will be inserted at \"%s\".")
1339
1340 (defun gnus-summary-mail-nastygram (n)
1341   "Send a nastygram to the author of the current article."
1342   (interactive "P")
1343   (when (or gnus-expert-user
1344             (gnus-y-or-n-p
1345              "Really send a nastygram to the author of the current article? "))
1346     (let ((group gnus-newsgroup-name))
1347       (gnus-summary-reply-with-original n)
1348       (set-buffer gnus-message-buffer)
1349       (message-goto-body)
1350       (insert (format gnus-nastygram-message group))
1351       (message-send-and-exit))))
1352
1353 (defun gnus-summary-mail-crosspost-complaint (n)
1354   "Send a complaint about crossposting to the current article(s)."
1355   (interactive "P")
1356   (let ((articles (gnus-summary-work-articles n))
1357         article)
1358     (while (setq article (pop articles))
1359       (set-buffer gnus-summary-buffer)
1360       (gnus-summary-goto-subject article)
1361       (let ((group (gnus-group-real-name gnus-newsgroup-name))
1362             newsgroups followup-to)
1363         (gnus-summary-select-article)
1364         (set-buffer gnus-original-article-buffer)
1365         (if (and (<= (length (message-tokenize-header
1366                               (setq newsgroups
1367                                     (mail-fetch-field "newsgroups"))
1368                               ", "))
1369                      1)
1370                  (or (not (setq followup-to (mail-fetch-field "followup-to")))
1371                      (not (member group (message-tokenize-header
1372                                          followup-to ", ")))))
1373             (if followup-to
1374                 (gnus-message 1 "Followup-to restricted")
1375               (gnus-message 1 "Not a crossposted article"))
1376           (set-buffer gnus-summary-buffer)
1377           (gnus-summary-reply-with-original 1)
1378           (set-buffer gnus-message-buffer)
1379           (message-goto-body)
1380           (insert (format gnus-crosspost-complaint newsgroups group))
1381           (message-goto-subject)
1382           (re-search-forward " *$")
1383           (replace-match " (crosspost notification)" t t)
1384           (gnus-deactivate-mark)
1385           (when (gnus-y-or-n-p "Send this complaint? ")
1386             (message-send-and-exit)))))))
1387
1388 (defun gnus-mail-parse-comma-list ()
1389   (let (accumulated
1390         beg)
1391     (skip-chars-forward " ")
1392     (while (not (eobp))
1393       (setq beg (point))
1394       (skip-chars-forward "^,")
1395       (while (zerop
1396               (save-excursion
1397                 (save-restriction
1398                   (let ((i 0))
1399                     (narrow-to-region beg (point))
1400                     (goto-char beg)
1401                     (logand (progn
1402                               (while (search-forward "\"" nil t)
1403                                 (incf i))
1404                               (if (zerop i) 2 i))
1405                             2)))))
1406         (skip-chars-forward ",")
1407         (skip-chars-forward "^,"))
1408       (skip-chars-backward " ")
1409       (push (buffer-substring beg (point))
1410             accumulated)
1411       (skip-chars-forward "^,")
1412       (skip-chars-forward ", "))
1413     accumulated))
1414
1415 (defun gnus-inews-add-to-address (group)
1416   (let ((to-address (mail-fetch-field "to")))
1417     (when (and to-address
1418                (gnus-alive-p))
1419       ;; This mail group doesn't have a `to-list', so we add one
1420       ;; here.  Magic!
1421       (when (gnus-y-or-n-p
1422              (format "Do you want to add this as `to-list': %s " to-address))
1423         (gnus-group-add-parameter group (cons 'to-list to-address))))))
1424
1425 (defun gnus-put-message ()
1426   "Put the current message in some group and return to Gnus."
1427   (interactive)
1428   (let ((reply gnus-article-reply)
1429         (winconf gnus-prev-winconf)
1430         (group gnus-newsgroup-name))
1431     (unless (and group
1432                  (not (gnus-group-read-only-p group)))
1433       (setq group (read-string "Put in group: " nil (gnus-writable-groups))))
1434
1435     (when (gnus-gethash group gnus-newsrc-hashtb)
1436       (error "No such group: %s" group))
1437     (save-excursion
1438       (save-restriction
1439         (widen)
1440         (message-narrow-to-headers)
1441         (let ((gnus-deletable-headers nil))
1442           (message-generate-headers
1443            (if (message-news-p)
1444                message-required-news-headers
1445              message-required-mail-headers)))
1446         (goto-char (point-max))
1447         (if (string-match " " group)
1448             (insert "Gcc: \"" group "\"\n")
1449           (insert "Gcc: " group "\n"))
1450         (widen)))
1451     (gnus-inews-do-gcc)
1452     (when (and (get-buffer gnus-group-buffer)
1453                (gnus-buffer-exists-p (car-safe reply))
1454                (cdr reply))
1455       (set-buffer (car reply))
1456       (gnus-summary-mark-article-as-replied (cdr reply)))
1457     (when winconf
1458       (set-window-configuration winconf))))
1459
1460 (defun gnus-article-mail (yank)
1461   "Send a reply to the address near point.
1462 If YANK is non-nil, include the original article."
1463   (interactive "P")
1464   (let ((address
1465          (buffer-substring
1466           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
1467           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
1468     (when address
1469       (gnus-msg-mail address)
1470       (when yank
1471         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
1472
1473 (defvar nntp-server-type)
1474 (defun gnus-bug ()
1475   "Send a bug report to the Gnus maintainers."
1476   (interactive)
1477   (unless (gnus-alive-p)
1478     (error "Gnus has been shut down"))
1479   (gnus-setup-message (if (message-mail-user-agent) 'message 'bug)
1480     (unless (message-mail-user-agent)
1481       (delete-other-windows)
1482       (when gnus-bug-create-help-buffer
1483         (switch-to-buffer "*Gnus Help Bug*")
1484         (erase-buffer)
1485         (insert gnus-bug-message)
1486         (goto-char (point-min)))
1487       (message-pop-to-buffer "*Gnus Bug*"))
1488     (let ((message-this-is-mail t))
1489       (message-setup `((To . ,gnus-maintainer) (Subject . ""))))
1490     (when gnus-bug-create-help-buffer
1491       (push `(gnus-bug-kill-buffer) message-send-actions))
1492     (goto-char (point-min))
1493     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
1494     (forward-line 1)
1495     (insert (gnus-version) "\n"
1496             (emacs-version) "\n")
1497     (when (and (boundp 'nntp-server-type)
1498                (stringp nntp-server-type))
1499       (insert nntp-server-type))
1500     (insert "\n\n\n\n\n")
1501     (let (text)
1502       (save-excursion
1503         (set-buffer (gnus-get-buffer-create " *gnus environment info*"))
1504         (erase-buffer)
1505         (gnus-debug)
1506         (setq text (buffer-string)))
1507       (insert "<#part type=application/emacs-lisp disposition=inline description=\"User settings\">\n" text "\n<#/part>"))
1508     (goto-char (point-min))
1509     (search-forward "Subject: " nil t)
1510     (message "")))
1511
1512 (defun gnus-bug-kill-buffer ()
1513   (when (get-buffer "*Gnus Help Bug*")
1514     (kill-buffer "*Gnus Help Bug*")))
1515
1516 (defun gnus-summary-yank-message (buffer n)
1517   "Yank the current article into a composed message."
1518   (interactive
1519    (list (completing-read "Buffer: " (mapcar 'list (message-buffers)) nil t)
1520          current-prefix-arg))
1521   (gnus-summary-iterate n
1522     (let ((gnus-display-mime-function nil)
1523           (gnus-inhibit-treatment t))
1524       (gnus-summary-select-article))
1525     (save-excursion
1526       (set-buffer buffer)
1527       (message-yank-buffer gnus-article-buffer))))
1528
1529 (defun gnus-debug ()
1530   "Attempts to go through the Gnus source file and report what variables have been changed.
1531 The source file has to be in the Emacs load path."
1532   (interactive)
1533   (let ((files gnus-debug-files)
1534         (point (point))
1535         file expr olist sym)
1536     (gnus-message 4 "Please wait while we snoop your variables...")
1537     (sit-for 0)
1538     ;; Go through all the files looking for non-default values for variables.
1539     (save-excursion
1540       (set-buffer (gnus-get-buffer-create " *gnus bug info*"))
1541       (while files
1542         (erase-buffer)
1543         (when (and (setq file (locate-library (pop files)))
1544                    (file-exists-p file))
1545           (insert-file-contents file)
1546           (goto-char (point-min))
1547           (if (not (re-search-forward "^;;* *Internal variables" nil t))
1548               (gnus-message 4 "Malformed sources in file %s" file)
1549             (narrow-to-region (point-min) (point))
1550             (goto-char (point-min))
1551             (while (setq expr (ignore-errors (read (current-buffer))))
1552               (ignore-errors
1553                 (and (or (eq (car expr) 'defvar)
1554                          (eq (car expr) 'defcustom))
1555                      (stringp (nth 3 expr))
1556                      (not (memq (nth 1 expr) gnus-debug-exclude-variables))
1557                      (or (not (boundp (nth 1 expr)))
1558                          (not (equal (eval (nth 2 expr))
1559                                      (symbol-value (nth 1 expr)))))
1560                      (push (nth 1 expr) olist)))))))
1561       (kill-buffer (current-buffer)))
1562     (when (setq olist (nreverse olist))
1563       (insert "------------------ Environment follows ------------------\n\n"))
1564     (while olist
1565       (if (boundp (car olist))
1566           (ignore-errors
1567             (pp `(setq ,(car olist)
1568                        ,(if (or (consp (setq sym (symbol-value (car olist))))
1569                                 (and (symbolp sym)
1570                                      (not (or (eq sym nil)
1571                                               (eq sym t)))))
1572                             (list 'quote (symbol-value (car olist)))
1573                           (symbol-value (car olist))))
1574                 (current-buffer)))
1575         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
1576       (setq olist (cdr olist)))
1577     (insert "\n\n")
1578     ;; Remove any control chars - they seem to cause trouble for some
1579     ;; mailers.  (Byte-compiled output from the stuff above.)
1580     (goto-char point)
1581     (while (re-search-forward "[\000-\010\013-\037\200-\237]" nil t)
1582       (replace-match (format "\\%03o" (string-to-char (match-string 0)))
1583                      t t))))
1584
1585 ;;; Treatment of rejected articles.
1586 ;;; Bounced mail.
1587
1588 (defun gnus-summary-resend-bounced-mail (&optional fetch)
1589   "Re-mail the current message.
1590 This only makes sense if the current message is a bounce message than
1591 contains some mail you have written which has been bounced back to
1592 you.
1593 If FETCH, try to fetch the article that this is a reply to, if indeed
1594 this is a reply."
1595   (interactive "P")
1596   (gnus-summary-select-article t)
1597   (set-buffer gnus-original-article-buffer)
1598   (gnus-setup-message 'compose-bounce
1599     (let* ((references (mail-fetch-field "references"))
1600            (parent (and references (gnus-parent-id references))))
1601       (message-bounce)
1602       ;; If there are references, we fetch the article we answered to.
1603       (and fetch parent
1604            (gnus-summary-refer-article parent)
1605            (gnus-summary-show-all-headers)))))
1606
1607 ;;; Gcc handling.
1608
1609 (defun gnus-inews-group-method (group)
1610   (cond
1611    ;; If the group doesn't exist, we assume
1612    ;; it's an archive group...
1613    ((and (null (gnus-get-info group))
1614          (eq (car (gnus-server-to-method gnus-message-archive-method))
1615              (car (gnus-server-to-method (gnus-group-method group)))))
1616     gnus-message-archive-method)
1617    ;; Use the method.
1618    ((gnus-info-method (gnus-get-info group))
1619     (gnus-info-method (gnus-get-info group)))
1620    ;; Find the method.
1621    (t (gnus-server-to-method (gnus-group-method group)))))
1622
1623 ;; Do Gcc handling, which copied the message over to some group.
1624 (defun gnus-inews-do-gcc (&optional gcc)
1625   (interactive)
1626   (save-excursion
1627     (save-restriction
1628       (message-narrow-to-headers)
1629       (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
1630             (cur (current-buffer))
1631             groups group method group-art
1632             mml-externalize-attachments)
1633         (when gcc
1634           (message-remove-header "gcc")
1635           (widen)
1636           (setq groups (message-unquote-tokens
1637                         (message-tokenize-header gcc " ,")))
1638           ;; Copy the article over to some group(s).
1639           (while (setq group (pop groups))
1640             (unless (gnus-check-server
1641                      (setq method (gnus-inews-group-method group)))
1642               (error "Can't open server %s" (if (stringp method) method
1643                                               (car method))))
1644             (unless (gnus-request-group group nil method)
1645               (gnus-request-create-group group method))
1646             (setq mml-externalize-attachments
1647                   (if (stringp gnus-gcc-externalize-attachments)
1648                       (string-match gnus-gcc-externalize-attachments group)
1649                     gnus-gcc-externalize-attachments))
1650             (save-excursion
1651               (nnheader-set-temp-buffer " *acc*")
1652               (insert-buffer-substring cur)
1653               (message-encode-message-body)
1654               (save-restriction
1655                 (message-narrow-to-headers)
1656                 (let* ((mail-parse-charset message-default-charset)
1657                        (newsgroups-field (save-restriction
1658                                            (message-narrow-to-headers-or-head)
1659                                            (message-fetch-field "Newsgroups")))
1660                        (followup-field (save-restriction
1661                                          (message-narrow-to-headers-or-head)
1662                                          (message-fetch-field "Followup-To")))
1663                        ;; BUG: We really need to get the charset for
1664                        ;; each name in the Newsgroups and Followup-To
1665                        ;; lines to allow crossposting between group
1666                        ;; namess with incompatible character sets.
1667                        ;; -- Per Abrahamsen <abraham@dina.kvl.dk> 2001-10-08.
1668                        (group-field-charset
1669                         (gnus-group-name-charset
1670                          method (or newsgroups-field "")))
1671                        (followup-field-charset
1672                         (gnus-group-name-charset
1673                          method (or followup-field "")))
1674                        (rfc2047-header-encoding-alist
1675                         (append
1676                          (when group-field-charset
1677                            (list (cons "Newsgroups" group-field-charset)))
1678                          (when followup-field-charset
1679                            (list (cons "Followup-To" followup-field-charset)))
1680                          rfc2047-header-encoding-alist)))
1681                   (mail-encode-encoded-word-buffer)))
1682               (goto-char (point-min))
1683               (when (re-search-forward
1684                      (concat "^" (regexp-quote mail-header-separator) "$")
1685                      nil t)
1686                 (replace-match "" t t ))
1687               (unless (setq group-art
1688                             (gnus-request-accept-article group method t t))
1689                 (gnus-message 1 "Couldn't store article in group %s: %s"
1690                               group (gnus-status-message method))
1691                 (sit-for 2))
1692               (when (and group-art
1693                          ;; FIXME: Should gcc-mark-as-read work when
1694                          ;; Gnus is not running?
1695                          (gnus-alive-p)
1696                          (or gnus-gcc-mark-as-read
1697                              (and
1698                               (boundp 'gnus-inews-mark-gcc-as-read)
1699                               (symbol-value 'gnus-inews-mark-gcc-as-read))))
1700                 (gnus-group-mark-article-read group (cdr group-art)))
1701               (kill-buffer (current-buffer)))))))))
1702
1703 (defun gnus-inews-insert-gcc ()
1704   "Insert Gcc headers based on `gnus-outgoing-message-group'."
1705   (save-excursion
1706     (save-restriction
1707       (message-narrow-to-headers)
1708       (let* ((group gnus-outgoing-message-group)
1709              (gcc (cond
1710                    ((gnus-functionp group)
1711                     (funcall group))
1712                    ((or (stringp group) (list group))
1713                     group))))
1714         (when gcc
1715           (insert "Gcc: "
1716                   (if (stringp gcc)
1717                       (if (string-match " " gcc)
1718                           (concat "\"" gcc "\"")
1719                         gcc)
1720                     (mapconcat (lambda (group)
1721                                  (if (string-match " " group)
1722                                      (concat "\"" group "\"")
1723                                    group))
1724                                gcc " "))
1725                   "\n"))))))
1726
1727 (defun gnus-inews-insert-archive-gcc (&optional group)
1728   "Insert the Gcc to say where the article is to be archived."
1729   (let* ((var gnus-message-archive-group)
1730          (group (or group gnus-newsgroup-name ""))
1731          (gcc-self-val
1732           (and gnus-newsgroup-name
1733                (not (equal gnus-newsgroup-name ""))
1734                (gnus-group-find-parameter
1735                 gnus-newsgroup-name 'gcc-self)))
1736          result
1737          (groups
1738           (cond
1739            ((null gnus-message-archive-method)
1740             ;; Ignore.
1741             nil)
1742            ((stringp var)
1743             ;; Just a single group.
1744             (list var))
1745            ((null var)
1746             ;; We don't want this.
1747             nil)
1748            ((and (listp var) (stringp (car var)))
1749             ;; A list of groups.
1750             var)
1751            ((gnus-functionp var)
1752             ;; A function.
1753             (funcall var group))
1754            (t
1755             ;; An alist of regexps/functions/forms.
1756             (while (and var
1757                         (not
1758                          (setq result
1759                                (cond
1760                                 ((stringp (caar var))
1761                                  ;; Regexp.
1762                                  (when (string-match (caar var) group)
1763                                    (cdar var)))
1764                                 ((gnus-functionp (car var))
1765                                  ;; Function.
1766                                  (funcall (car var) group))
1767                                 (t
1768                                  (eval (car var)))))))
1769               (setq var (cdr var)))
1770             result)))
1771          name)
1772     (when (or groups gcc-self-val)
1773       (when (stringp groups)
1774         (setq groups (list groups)))
1775       (save-excursion
1776         (save-restriction
1777           (message-narrow-to-headers)
1778           (goto-char (point-max))
1779           (insert "Gcc: ")
1780           (if gcc-self-val
1781               ;; Use the `gcc-self' param value instead.
1782               (progn
1783                 (insert
1784                  (if (stringp gcc-self-val)
1785                      (if (string-match " " gcc-self-val)
1786                          (concat "\"" gcc-self-val "\"")
1787                        gcc-self-val)
1788                    (if (string-match " " group)
1789                        (concat "\"" group "\"")
1790                      group)))
1791                 (if (not (eq gcc-self-val 'none))
1792                     (insert "\n")
1793                   (gnus-delete-line)))
1794             ;; Use the list of groups.
1795             (while (setq name (pop groups))
1796               (let ((str (if (string-match ":" name)
1797                              name
1798                            (gnus-group-prefixed-name
1799                             name gnus-message-archive-method))))
1800                 (insert (if (string-match " " str)
1801                             (concat "\"" str "\"")
1802                           str)))
1803               (when groups
1804                 (insert " ")))
1805             (insert "\n")))))))
1806
1807 (defun gnus-mailing-list-followup-to ()
1808   "Look at the headers in the current buffer and return a Mail-Followup-To address."
1809   (let ((x-been-there (gnus-fetch-original-field "x-beenthere"))
1810         (list-post (gnus-fetch-original-field "list-post")))
1811     (when (and list-post
1812                (string-match "mailto:\\([^>]+\\)" list-post))
1813       (setq list-post (match-string 1 list-post)))
1814     (or list-post
1815         x-been-there)))
1816
1817 ;;; Posting styles.
1818
1819 (defun gnus-configure-posting-styles (&optional group-name)
1820   "Configure posting styles according to `gnus-posting-styles'."
1821   (unless gnus-inhibit-posting-styles
1822     (let ((group (or group-name gnus-newsgroup-name ""))
1823           (styles gnus-posting-styles)
1824           style match variable attribute value v results
1825           filep name address element)
1826       ;; If the group has a posting-style parameter, add it at the end with a
1827       ;; regexp matching everything, to be sure it takes precedence over all
1828       ;; the others.
1829       (when gnus-newsgroup-name
1830         (let ((tmp-style (gnus-group-find-parameter group 'posting-style t)))
1831           (when tmp-style
1832             (setq styles (append styles (list (cons ".*" tmp-style)))))))
1833       ;; Go through all styles and look for matches.
1834       (dolist (style styles)
1835         (setq match (pop style))
1836         (goto-char (point-min))
1837         (when (cond
1838                ((stringp match)
1839                 ;; Regexp string match on the group name.
1840                 (string-match match group))
1841                ((eq match 'header)
1842                 ;; Obsolete format of header match.
1843                 (and (gnus-buffer-live-p gnus-article-copy)
1844                      (with-current-buffer gnus-article-copy
1845                        (let ((header (message-fetch-field (pop style))))
1846                          (and header
1847                               (string-match (pop style) header))))))
1848                ((or (symbolp match)
1849                     (gnus-functionp match))
1850                 (cond
1851                  ((gnus-functionp match)
1852                   ;; Function to be called.
1853                   (funcall match))
1854                  ((boundp match)
1855                   ;; Variable to be checked.
1856                   (symbol-value match))))
1857                ((listp match)
1858                 (cond
1859                  ((eq (car match) 'header)
1860                   ;; New format of header match.
1861                   (and (gnus-buffer-live-p gnus-article-copy)
1862                        (with-current-buffer gnus-article-copy
1863                          (let ((header (message-fetch-field (nth 1 match))))
1864                            (and header
1865                                 (string-match (nth 2 match) header))))))
1866                  (t
1867                   ;; This is a form to be evaled.
1868                   (eval match)))))
1869           ;; We have a match, so we set the variables.
1870           (dolist (attribute style)
1871             (setq element (pop attribute)
1872                   variable nil
1873                   filep nil)
1874             (setq value
1875                   (cond
1876                    ((eq (car attribute) :file)
1877                     (setq filep t)
1878                     (cadr attribute))
1879                    ((eq (car attribute) :value)
1880                     (cadr attribute))
1881                    (t
1882                     (car attribute))))
1883             ;; We get the value.
1884             (setq v
1885                   (cond
1886                    ((stringp value)
1887                     value)
1888                    ((or (symbolp value)
1889                         (gnus-functionp value))
1890                     (cond ((gnus-functionp value)
1891                            (funcall value))
1892                           ((boundp value)
1893                            (symbol-value value))))
1894                    ((listp value)
1895                     (eval value))))
1896             ;; Translate obsolescent value.
1897             (cond
1898              ((eq element 'signature-file)
1899               (setq element 'signature
1900                     filep t))
1901              ((eq element 'x-face-file)
1902               (setq element 'x-face
1903                     filep t)))
1904             ;; Get the contents of file elems.
1905             (when (and filep v)
1906               (setq v (with-temp-buffer
1907                         (insert-file-contents v)
1908                         (goto-char (point-max))
1909                         (while (bolp)
1910                           (delete-char -1))
1911                         (buffer-string))))
1912             (setq results (delq (assoc element results) results))
1913             (push (cons element v) results))))
1914       ;; Now we have all the styles, so we insert them.
1915       (setq name (assq 'name results)
1916             address (assq 'address results))
1917       (setq results (delq name (delq address results)))
1918       ;; make-local-hook is not obsolete in Emacs 20 or XEmacs.
1919       (make-local-hook 'message-setup-hook)
1920       (setq results (sort results (lambda (x y)
1921                                     (string-lessp (car x) (car y)))))
1922       (dolist (result results)
1923         (add-hook 'message-setup-hook
1924                   (cond
1925                    ((eq 'eval (car result))
1926                     'ignore)
1927                    ((eq 'body (car result))
1928                     `(lambda ()
1929                        (save-excursion
1930                          (message-goto-body)
1931                          (insert ,(cdr result)))))
1932                    ((eq 'signature (car result))
1933                     (set (make-local-variable 'message-signature) nil)
1934                     (set (make-local-variable 'message-signature-file) nil)
1935                     (if (not (cdr result))
1936                         'ignore
1937                       `(lambda ()
1938                          (save-excursion
1939                            (let ((message-signature ,(cdr result)))
1940                              (when message-signature
1941                                (message-insert-signature)))))))
1942                    (t
1943                     (let ((header
1944                            (if (symbolp (car result))
1945                                (capitalize (symbol-name (car result)))
1946                              (car result))))
1947                       `(lambda ()
1948                          (save-excursion
1949                            (message-remove-header ,header)
1950                            (let ((value ,(cdr result)))
1951                              (when value
1952                                (message-goto-eoh)
1953                                (insert ,header ": " value)
1954                                (unless (bolp)
1955                                  (insert "\n")))))))))
1956                   nil 'local))
1957       (when (or name address)
1958         (add-hook 'message-setup-hook
1959                   `(lambda ()
1960                      (set (make-local-variable 'user-mail-address)
1961                           ,(or (cdr address) user-mail-address))
1962                      (let ((user-full-name ,(or (cdr name) (user-full-name)))
1963                            (user-mail-address
1964                             ,(or (cdr address) user-mail-address)))
1965                        (save-excursion
1966                          (message-remove-header "From")
1967                          (message-goto-eoh)
1968                          (insert "From: " (message-make-from) "\n"))))
1969                   nil 'local)))))
1970
1971 ;;; Allow redefinition of functions.
1972
1973 (gnus-ems-redefine)
1974
1975 (provide 'gnus-msg)
1976
1977 ;;; gnus-msg.el ends here