cgit.sxemacs.org Git - gnus/blob - lisp/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   5 ;;      Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'gnus)
  30 (require 'gnus-ems)
  31 (require 'message)
  32 (require 'gnus-art)
  33
  34 ;; Added by Sudish Joseph <joseph@cis.ohio-state.edu>.
  35 (defvar gnus-post-method nil
  36   "*Preferred method for posting USENET news.
  37 If this variable is nil, Gnus will use the current method to decide
  38 which method to use when posting.  If it is non-nil, it will override
  39 the current method.  This method will not be used in mail groups and
  40 the like, only in \"real\" newsgroups.
  41
  42 The value must be a valid method as discussed in the documentation of
  43 `gnus-select-method'.  It can also be a list of methods.  If that is
  44 the case, the user will be queried for what select method to use when
  45 posting.")
  46
  47 (defvar gnus-outgoing-message-group nil
  48   "*All outgoing messages will be put in this group.
  49 If you want to store all your outgoing mail and articles in the group
  50 \"nnml:archive\", you set this variable to that value.  This variable
  51 can also be a list of group names.
  52
  53 If you want to have greater control over what group to put each
  54 message in, you can set this variable to a function that checks the
  55 current newsgroup name and then returns a suitable group name (or list
  56 of names).")
  57
  58 (defvar gnus-mailing-list-groups nil
  59   "*Regexp matching groups that are really mailing lists.
  60 This is useful when you're reading a mailing list that has been
  61 gatewayed to a newsgroup, and you want to followup to an article in
  62 the group.")
  63
  64 (defvar gnus-sent-message-ids-file
  65   (nnheader-concat gnus-directory "Sent-Message-IDs")
  66   "File where Gnus saves a cache of sent message ids.")
  67
  68 (defvar gnus-sent-message-ids-length 1000
  69   "The number of sent Message-IDs to save.")
  70
  71 (defvar gnus-crosspost-complaint
  72   "Hi,
  73
  74 You posted the article below with the following Newsgroups header:
  75
  76 Newsgroups: %s
  77
  78 The %s group, at least, was an inappropriate recipient
  79 of this message.  Please trim your Newsgroups header to exclude this
  80 group before posting in the future.
  81
  82 Thank you.
  83
  84 "
  85   "Format string to be inserted when complaining about crossposts.
  86 The first %s will be replaced by the Newsgroups header;
  87 the second with the current group name.")
  88
  89 ;;; Internal variables.
  90
  91 (defvar gnus-message-buffer "*Mail Gnus*")
  92 (defvar gnus-article-copy nil)
  93 (defvar gnus-last-posting-server nil)
  94
  95 (defconst gnus-bug-message
  96   "Sending a bug report to the Gnus Towers.
  97 ========================================
  98
  99 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 100 be sent to the Gnus Bug Exterminators.
 101
 102 At the bottom of the buffer you'll see lots of variable settings.
 103 Please do not delete those.  They will tell the Bug People what your
 104 environment is, so that it will be easier to locate the bugs.
 105
 106 If you have found a bug that makes Emacs go \"beep\", set
 107 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 108 and include the backtrace in your bug report.
 109
 110 Please describe the bug in annoying, painstaking detail.
 111
 112 Thank you for your help in stamping out bugs.
 113 ")
 114
 115 (eval-and-compile
 116   (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 117   (autoload 'news-setup "rnewspost")
 118   (autoload 'news-reply-mode "rnewspost")
 119   (autoload 'rmail-dont-reply-to "mail-utils")
 120   (autoload 'rmail-output "rmailout"))
 121
 122 \f
 123 ;;;
 124 ;;; Gnus Posting Functions
 125 ;;;
 126
 127 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 128   "p" gnus-summary-post-news
 129   "f" gnus-summary-followup
 130   "F" gnus-summary-followup-with-original
 131   "c" gnus-summary-cancel-article
 132   "s" gnus-summary-supersede-article
 133   "r" gnus-summary-reply
 134   "R" gnus-summary-reply-with-original
 135   "n" gnus-summary-followup-to-mail
 136   "N" gnus-summary-followup-to-mail-with-original
 137   "m" gnus-summary-mail-other-window
 138   "u" gnus-uu-post-news
 139   "\M-c" gnus-summary-mail-crosspost-complaint
 140   "om" gnus-summary-mail-forward
 141   "op" gnus-summary-post-forward
 142   "Om" gnus-uu-digest-mail-forward
 143   "Op" gnus-uu-digest-post-forward)
 144
 145 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 146   "b" gnus-summary-resend-bounced-mail
 147   ;; "c" gnus-summary-send-draft
 148   "r" gnus-summary-resend-message)
 149
 150 ;;; Internal functions.
 151
 152 (defvar gnus-article-reply nil)
 153 (defmacro gnus-setup-message (config &rest forms)
 154   (let ((winconf (make-symbol "winconf"))
 155         (buffer (make-symbol "buffer"))
 156         (article (make-symbol "article")))
 157     `(let ((,winconf (current-window-configuration))
 158            (,buffer (current-buffer))
 159            (,article (and gnus-article-reply (gnus-summary-article-number)))
 160            (message-header-setup-hook
 161             (copy-sequence message-header-setup-hook)))
 162        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 163        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 164        ,@forms
 165        (gnus-inews-add-send-actions ,winconf ,buffer ,article)
 166        (setq gnus-message-buffer (current-buffer))
 167        (make-local-variable 'gnus-newsgroup-name)
 168        (gnus-configure-windows ,config t))))
 169
 170 (defun gnus-inews-add-send-actions (winconf buffer article)
 171   (gnus-make-local-hook 'message-sent-hook)
 172   (gnus-add-hook 'message-sent-hook 'gnus-inews-do-gcc nil t)
 173   (setq message-post-method
 174         `(lambda (arg)
 175            (gnus-post-method arg ,gnus-newsgroup-name)))
 176   (setq message-newsreader (setq message-mailer (gnus-extended-version)))
 177   (message-add-action
 178    `(set-window-configuration ,winconf) 'exit 'postpone 'kill)
 179   (message-add-action
 180    `(when (buffer-name ,buffer)
 181       (save-excursion
 182         (set-buffer ,buffer)
 183         ,(when article
 184            `(gnus-summary-mark-article-as-replied ,article))))
 185    'send))
 186
 187 (put 'gnus-setup-message 'lisp-indent-function 1)
 188 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 189
 190 ;;; Post news commands of Gnus group mode and summary mode
 191
 192 (defun gnus-group-mail ()
 193   "Start composing a mail."
 194   (interactive)
 195   (gnus-setup-message 'message
 196     (message-mail)))
 197
 198 (defun gnus-group-post-news (&optional arg)
 199   "Start composing a news message.
 200 If ARG, post to the group under point.
 201 If ARG is 1, prompt for a group name."
 202   (interactive "P")
 203   ;; Bind this variable here to make message mode hooks
 204   ;; work ok.
 205   (let ((gnus-newsgroup-name
 206          (if arg
 207              (if (= 1 (prefix-numeric-value arg))
 208                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 209                                   (gnus-read-active-file-p))
 210                (gnus-group-group-name))
 211            "")))
 212     (gnus-post-news 'post gnus-newsgroup-name)))
 213
 214 (defun gnus-summary-post-news ()
 215   "Start composing a news message."
 216   (interactive)
 217   (gnus-set-global-variables)
 218   (gnus-post-news 'post gnus-newsgroup-name))
 219
 220 (defun gnus-summary-followup (yank &optional force-news)
 221   "Compose a followup to an article.
 222 If prefix argument YANK is non-nil, original article is yanked automatically."
 223   (interactive
 224    (list (and current-prefix-arg
 225               (gnus-summary-work-articles 1))))
 226   (gnus-set-global-variables)
 227   (when yank
 228     (gnus-summary-goto-subject (car yank)))
 229   (save-window-excursion
 230     (gnus-summary-select-article))
 231   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 232         (gnus-newsgroup-name gnus-newsgroup-name))
 233     ;; Send a followup.
 234     (gnus-post-news nil gnus-newsgroup-name
 235                     headers gnus-article-buffer
 236                     yank nil force-news)))
 237
 238 (defun gnus-summary-followup-with-original (n &optional force-news)
 239   "Compose a followup to an article and include the original article."
 240   (interactive "P")
 241   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 242
 243 (defun gnus-summary-followup-to-mail (&optional arg)
 244   "Followup to the current mail message via news."
 245   (interactive
 246    (list (and current-prefix-arg
 247               (gnus-summary-work-articles 1))))
 248   (gnus-summary-followup arg t))
 249
 250 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 251   "Followup to the current mail message via news."
 252   (interactive "P")
 253   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 254
 255 (defun gnus-inews-yank-articles (articles)
 256   (let (beg article)
 257     (message-goto-body)
 258     (while (setq article (pop articles))
 259       (save-window-excursion
 260         (set-buffer gnus-summary-buffer)
 261         (gnus-summary-select-article nil nil nil article)
 262         (gnus-summary-remove-process-mark article))
 263       (gnus-copy-article-buffer)
 264       (let ((message-reply-buffer gnus-article-copy)
 265             (message-reply-headers gnus-current-headers))
 266         (message-yank-original)
 267         (setq beg (or beg (mark t))))
 268       (when articles
 269         (insert "\n")))
 270     (push-mark)
 271     (goto-char beg)))
 272
 273 (defun gnus-summary-cancel-article (n)
 274   "Cancel an article you posted."
 275   (interactive "P")
 276   (gnus-set-global-variables)
 277   (let ((articles (gnus-summary-work-articles n))
 278         (message-post-method
 279          `(lambda (arg)
 280             (gnus-post-method nil ,gnus-newsgroup-name)))
 281         article)
 282     (while (setq article (pop articles))
 283       (when (gnus-summary-select-article t nil nil article)
 284         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 285                 (message-cancel-news))
 286           (gnus-summary-mark-as-read article gnus-canceled-mark)
 287           (gnus-cache-remove-article 1))
 288         (gnus-article-hide-headers-if-wanted))
 289       (gnus-summary-remove-process-mark article))))
 290
 291 (defun gnus-summary-supersede-article ()
 292   "Compose an article that will supersede a previous article.
 293 This is done simply by taking the old article and adding a Supersedes
 294 header line with the old Message-ID."
 295   (interactive)
 296   (gnus-set-global-variables)
 297   (let ((article (gnus-summary-article-number)))
 298     (gnus-setup-message 'reply-yank
 299       (gnus-summary-select-article t)
 300       (set-buffer gnus-original-article-buffer)
 301       (message-supersede)
 302       (push
 303        `((lambda ()
 304            (gnus-cache-possibly-remove-article ,article nil nil nil t)))
 305        message-send-actions))))
 306
 307 \f
 308
 309 (defun gnus-copy-article-buffer (&optional article-buffer)
 310   ;; make a copy of the article buffer with all text properties removed
 311   ;; this copy is in the buffer gnus-article-copy.
 312   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 313   ;; this buffer should be passed to all mail/news reply/post routines.
 314   (setq gnus-article-copy (get-buffer-create " *gnus article copy*"))
 315   (buffer-disable-undo gnus-article-copy)
 316   (or (memq gnus-article-copy gnus-buffer-list)
 317       (push gnus-article-copy gnus-buffer-list))
 318   (let ((article-buffer (or article-buffer gnus-article-buffer))
 319         end beg contents)
 320     (when (and (get-buffer article-buffer)
 321                (buffer-name (get-buffer article-buffer)))
 322       (save-excursion
 323         (set-buffer article-buffer)
 324         (save-restriction
 325           ;; Copy over the (displayed) article buffer, delete
 326           ;; hidden text and remove text properties.
 327           (widen)
 328           (copy-to-buffer gnus-article-copy (point-min) (point-max))
 329           (set-buffer gnus-article-copy)
 330           (article-delete-text-of-type 'annotation)
 331           (insert
 332            (prog1
 333                (format "%s" (buffer-string))
 334              (erase-buffer)))
 335           ;; Find the original headers.
 336           (set-buffer gnus-original-article-buffer)
 337           (goto-char (point-min))
 338           (while (looking-at message-unix-mail-delimiter)
 339             (forward-line 1))
 340           (setq beg (point))
 341           (setq end (or (search-forward "\n\n" nil t) (point)))
 342           ;; Delete the headers from the displayed articles.
 343           (set-buffer gnus-article-copy)
 344           (delete-region (goto-char (point-min))
 345                          (or (search-forward "\n\n" nil t) (point)))
 346           ;; Insert the original article headers.
 347           (insert-buffer-substring gnus-original-article-buffer beg end)
 348           (article-decode-rfc1522)))
 349       gnus-article-copy)))
 350
 351 (defun gnus-post-news (post &optional group header article-buffer yank subject
 352                             force-news)
 353   (when article-buffer
 354     (gnus-copy-article-buffer))
 355   (let ((gnus-article-reply article-buffer))
 356     (gnus-setup-message (cond (yank 'reply-yank)
 357                               (article-buffer 'reply)
 358                               (t 'message))
 359       (let* ((group (or group gnus-newsgroup-name))
 360              (pgroup group)
 361              to-address to-group mailing-list to-list)
 362         (when group
 363           (setq to-address (gnus-group-find-parameter group 'to-address)
 364                 to-group (gnus-group-find-parameter group 'to-group)
 365                 to-list (gnus-group-find-parameter group 'to-list)
 366                 mailing-list (when gnus-mailing-list-groups
 367                                (string-match gnus-mailing-list-groups group))
 368                 group (gnus-group-real-name group)))
 369         (if (or (and to-group
 370                      (gnus-news-group-p to-group))
 371                 force-news
 372                 (and (gnus-news-group-p
 373                       (or pgroup gnus-newsgroup-name)
 374                       (if header (mail-header-number header)
 375                         gnus-current-article))
 376                      (not mailing-list)
 377                      (not to-list)
 378                      (not to-address)))
 379             ;; This is news.
 380             (if post
 381                 (message-news (or to-group group))
 382               (set-buffer gnus-article-copy)
 383               (message-followup (if force-news nil to-group)))
 384           ;; The is mail.
 385           (if post
 386               (progn
 387                 (message-mail (or to-address to-list))
 388                 ;; Arrange for mail groups that have no `to-address' to
 389                 ;; get that when the user sends off the mail.
 390                 (push (list 'gnus-inews-add-to-address group)
 391                       message-send-actions))
 392             (set-buffer gnus-article-copy)
 393             (message-wide-reply to-address)))
 394         (when yank
 395           (gnus-inews-yank-articles yank))))))
 396
 397 (defun gnus-post-method (arg group &optional silent)
 398   "Return the posting method based on GROUP and ARG.
 399 If SILENT, don't prompt the user."
 400   (let ((group-method (gnus-find-method-for-group group)))
 401     (cond
 402      ;; If the group-method is nil (which shouldn't happen) we use
 403      ;; the default method.
 404      ((null group-method)
 405       (or gnus-post-method gnus-select-method message-post-method))
 406      ;; We want this group's method.
 407      ((and arg (not (eq arg 0)))
 408       group-method)
 409      ;; We query the user for a post method.
 410      ((or arg
 411           (and gnus-post-method
 412                (listp (car gnus-post-method))))
 413       (let* ((methods
 414               ;; Collect all methods we know about.
 415               (append
 416                (when gnus-post-method
 417                  (if (listp (car gnus-post-method))
 418                      gnus-post-method
 419                    (list gnus-post-method)))
 420                gnus-secondary-select-methods
 421                (list gnus-select-method)
 422                (list group-method)))
 423              method-alist post-methods method)
 424         ;; Weed out all mail methods.
 425         (while methods
 426           (setq method (gnus-server-get-method "" (pop methods)))
 427           (when (or (gnus-method-option-p method 'post)
 428                     (gnus-method-option-p method 'post-mail))
 429             (push method post-methods)))
 430         ;; Create a name-method alist.
 431         (setq method-alist
 432               (mapcar
 433                (lambda (m)
 434                  (list (concat (cadr m) " (" (symbol-name (car m)) ")") m))
 435                post-methods))
 436         ;; Query the user.
 437         (cadr
 438          (assoc
 439           (setq gnus-last-posting-server
 440                 (if (and silent
 441                          gnus-last-posting-server)
 442                     ;; Just use the last value.
 443                     gnus-last-posting-server
 444                   (completing-read
 445                    "Posting method: " method-alist nil t
 446                    (cons (or gnus-last-posting-server "") 0))))
 447           method-alist))))
 448      ;; Override normal method.
 449      (gnus-post-method
 450       gnus-post-method)
 451      ;; Use the normal select method.
 452      (t gnus-select-method))))
 453
 454 (defun gnus-inews-narrow-to-headers ()
 455   (widen)
 456   (narrow-to-region
 457    (goto-char (point-min))
 458    (or (and (re-search-forward
 459              (concat "^" (regexp-quote mail-header-separator) "$") nil t)
 460             (match-beginning 0))
 461        (point-max)))
 462   (goto-char (point-min)))
 463
 464 ;;;
 465 ;;; Check whether the message has been sent already.
 466 ;;;
 467
 468 (defvar gnus-inews-sent-ids nil)
 469
 470 (defun gnus-inews-reject-message ()
 471   "Check whether this message has already been sent."
 472   (when gnus-sent-message-ids-file
 473     (let ((message-id (save-restriction (gnus-inews-narrow-to-headers)
 474                                         (mail-fetch-field "message-id")))
 475           end)
 476       (when message-id
 477         (unless gnus-inews-sent-ids
 478           (condition-case ()
 479               (load  t t t)
 480             (error nil)))
 481         (if (member message-id gnus-inews-sent-ids)
 482             ;; Reject this message.
 483             (not (gnus-yes-or-no-p
 484                   (format "Message %s already sent.  Send anyway? "
 485                           message-id)))
 486           (push message-id gnus-inews-sent-ids)
 487           ;; Chop off the last Message-IDs.
 488           (when (setq end (nthcdr gnus-sent-message-ids-length
 489                                   gnus-inews-sent-ids))
 490             (setcdr end nil))
 491           (nnheader-temp-write gnus-sent-message-ids-file
 492             (gnus-prin1 `(setq gnus-inews-sent-ids ',gnus-inews-sent-ids)))
 493           nil)))))
 494
 495 \f
 496
 497 ;; Dummy to avoid byte-compile warning.
 498 (defvar nnspool-rejected-article-hook)
 499
 500 ;;; Since the X-Newsreader/X-Mailer are ``vanity'' headers, they might
 501 ;;; as well include the Emacs version as well.
 502 ;;; The following function works with later GNU Emacs, and XEmacs.
 503 (defun gnus-extended-version ()
 504   "Stringified Gnus version and Emacs version"
 505   (interactive)
 506   (concat
 507    gnus-version
 508    "/"
 509    (cond
 510     ((string-match "^\\([0-9]+\\.[0-9]+\\)\\.[.0-9]+$" emacs-version)
 511      (concat "Emacs " (substring emacs-version
 512                                  (match-beginning 1)
 513                                  (match-end 1))))
 514     ((string-match "\\([A-Z]*[Mm][Aa][Cc][Ss]\\)" emacs-version)
 515      (concat (substring emacs-version
 516                         (match-beginning 1)
 517                         (match-end 1))
 518              (format " %d.%d" emacs-major-version emacs-minor-version)))
 519     (t emacs-version))))
 520
 521 ;; Written by "Mr. Per Persson" <pp@gnu.ai.mit.edu>.
 522 (defun gnus-inews-insert-mime-headers ()
 523   (goto-char (point-min))
 524   (let ((mail-header-separator
 525          (progn
 526            (goto-char (point-min))
 527            (if (and (search-forward (concat "\n" mail-header-separator "\n")
 528                                     nil t)
 529                     (not (search-backward "\n\n" nil t)))
 530                mail-header-separator
 531              ""))))
 532     (or (mail-position-on-field "Mime-Version")
 533         (insert "1.0")
 534         (cond ((save-restriction
 535                  (widen)
 536                  (goto-char (point-min))
 537                  (re-search-forward "[\200-\377]" nil t))
 538                (or (mail-position-on-field "Content-Type")
 539                    (insert "text/plain; charset=ISO-8859-1"))
 540                (or (mail-position-on-field "Content-Transfer-Encoding")
 541                    (insert "8bit")))
 542               (t (or (mail-position-on-field "Content-Type")
 543                      (insert "text/plain; charset=US-ASCII"))
 544                  (or (mail-position-on-field "Content-Transfer-Encoding")
 545                      (insert "7bit")))))))
 546
 547 \f
 548 ;;;
 549 ;;; Gnus Mail Functions
 550 ;;;
 551
 552 ;;; Mail reply commands of Gnus summary mode
 553
 554 (defun gnus-summary-reply (&optional yank)
 555   "Reply mail to news author.
 556 If prefix argument YANK is non-nil, original article is yanked automatically."
 557   (interactive
 558    (list (and current-prefix-arg
 559               (gnus-summary-work-articles 1))))
 560   ;; Bug fix by jbw@bigbird.bu.edu (Joe Wells)
 561   ;; Stripping headers should be specified with mail-yank-ignored-headers.
 562   (gnus-set-global-variables)
 563   (when yank
 564     (gnus-summary-goto-subject (car yank)))
 565   (let ((gnus-article-reply t))
 566     (gnus-setup-message (if yank 'reply-yank 'reply)
 567       (gnus-summary-select-article)
 568       (set-buffer (gnus-copy-article-buffer))
 569       (message-reply nil nil (gnus-group-find-parameter
 570                               gnus-newsgroup-name 'broken-reply-to))
 571       (when yank
 572         (gnus-inews-yank-articles yank)))))
 573
 574 (defun gnus-summary-reply-with-original (n)
 575   "Reply mail to news author with original article."
 576   (interactive "P")
 577   (gnus-summary-reply (gnus-summary-work-articles n)))
 578
 579 (defun gnus-summary-mail-forward (&optional full-headers post)
 580   "Forward the current message to another user.
 581 If FULL-HEADERS (the prefix), include full headers when forwarding."
 582   (interactive "P")
 583   (gnus-set-global-variables)
 584   (gnus-setup-message 'forward
 585     (gnus-summary-select-article)
 586     (set-buffer gnus-original-article-buffer)
 587     (let ((message-included-forward-headers
 588            (if full-headers "" message-included-forward-headers)))
 589       (message-forward post))))
 590
 591 (defun gnus-summary-resend-message (address)
 592   "Resend the current article to ADDRESS."
 593   (interactive "sResend message to: ")
 594   (gnus-summary-select-article)
 595   (save-excursion
 596     (set-buffer gnus-original-article-buffer)
 597     (message-resend address)))
 598
 599 (defun gnus-summary-post-forward (&optional full-headers)
 600   "Forward the current article to a newsgroup.
 601 If FULL-HEADERS (the prefix), include full headers when forwarding."
 602   (interactive "P")
 603   (gnus-summary-mail-forward full-headers t))
 604
 605 (defvar gnus-nastygram-message
 606   "The following article was inappropriately posted to %s.\n\n"
 607   "Format string to insert in nastygrams.
 608 The current group name will be inserted at \"%s\".")
 609
 610 (defun gnus-summary-mail-nastygram (n)
 611   "Send a nastygram to the author of the current article."
 612   (interactive "P")
 613   (when (or gnus-expert-user
 614             (gnus-y-or-n-p
 615              "Really send a nastygram to the author of the current article? "))
 616     (let ((group gnus-newsgroup-name))
 617       (gnus-summary-reply-with-original n)
 618       (set-buffer gnus-message-buffer)
 619       (message-goto-body)
 620       (insert (format gnus-nastygram-message group))
 621       (message-send-and-exit))))
 622
 623 (defun gnus-summary-mail-crosspost-complaint (n)
 624   "Send a complaint about crossposting to the current article(s)."
 625   (interactive "P")
 626   (let ((articles (gnus-summary-work-articles n))
 627         article)
 628     (while (setq article (pop articles))
 629       (set-buffer gnus-summary-buffer)
 630       (gnus-summary-goto-subject article)
 631       (let ((group (gnus-group-real-name gnus-newsgroup-name))
 632             newsgroups followup-to)
 633         (gnus-summary-select-article)
 634         (set-buffer gnus-original-article-buffer)
 635         (if (and (<= (length (message-tokenize-header
 636                               (setq newsgroups (mail-fetch-field "newsgroups"))
 637                               ", "))
 638                      1)
 639                  (or (not (setq followup-to (mail-fetch-field "followup-to")))
 640                      (not (member group (message-tokenize-header
 641                                          followup-to ", ")))))
 642             (if followup-to
 643                 (gnus-message 1 "Followup-to restricted")
 644               (gnus-message 1 "Not a crossposted article"))
 645           (set-buffer gnus-summary-buffer)
 646           (gnus-summary-reply-with-original 1)
 647           (set-buffer gnus-message-buffer)
 648           (message-goto-body)
 649           (insert (format gnus-crosspost-complaint newsgroups group))
 650           (message-goto-subject)
 651           (re-search-forward " *$")
 652           (replace-match " (crosspost notification)" t t)
 653           (when (gnus-y-or-n-p "Send this complaint? ")
 654             (message-send-and-exit)))))))
 655
 656 (defun gnus-summary-mail-other-window ()
 657   "Compose mail in other window."
 658   (interactive)
 659   (gnus-setup-message 'message
 660     (message-mail)))
 661
 662 (defun gnus-mail-parse-comma-list ()
 663   (let (accumulated
 664         beg)
 665     (skip-chars-forward " ")
 666     (while (not (eobp))
 667       (setq beg (point))
 668       (skip-chars-forward "^,")
 669       (while (zerop
 670               (save-excursion
 671                 (save-restriction
 672                   (let ((i 0))
 673                     (narrow-to-region beg (point))
 674                     (goto-char beg)
 675                     (logand (progn
 676                               (while (search-forward "\"" nil t)
 677                                 (incf i))
 678                               (if (zerop i) 2 i))
 679                             2)))))
 680         (skip-chars-forward ",")
 681         (skip-chars-forward "^,"))
 682       (skip-chars-backward " ")
 683       (push (buffer-substring beg (point))
 684             accumulated)
 685       (skip-chars-forward "^,")
 686       (skip-chars-forward ", "))
 687     accumulated))
 688
 689 (defun gnus-inews-add-to-address (group)
 690   (let ((to-address (mail-fetch-field "to")))
 691     (when (and to-address
 692                (gnus-alive-p))
 693       ;; This mail group doesn't have a `to-list', so we add one
 694       ;; here.  Magic!
 695       (gnus-group-add-parameter group (cons 'to-list to-address)))))
 696
 697 (defun gnus-put-message ()
 698   "Put the current message in some group and return to Gnus."
 699   (interactive)
 700   (let ((reply gnus-article-reply)
 701         (winconf gnus-prev-winconf)
 702         (group gnus-newsgroup-name))
 703
 704     (or (and group (not (gnus-group-read-only-p group)))
 705         (setq group (read-string "Put in group: " nil
 706                                  (gnus-writable-groups))))
 707     (when (gnus-gethash group gnus-newsrc-hashtb)
 708       (error "No such group: %s" group))
 709
 710     (save-excursion
 711       (save-restriction
 712         (widen)
 713         (gnus-inews-narrow-to-headers)
 714         (let (gnus-deletable-headers)
 715           (if (message-news-p)
 716               (message-generate-headers message-required-news-headers)
 717             (message-generate-headers message-required-mail-headers)))
 718         (goto-char (point-max))
 719         (insert "Gcc: " group "\n")
 720         (widen)))
 721
 722     (gnus-inews-do-gcc)
 723
 724     (when (get-buffer gnus-group-buffer)
 725       (when (gnus-buffer-exists-p (car-safe reply))
 726         (set-buffer (car reply))
 727         (and (cdr reply)
 728              (gnus-summary-mark-article-as-replied
 729               (cdr reply))))
 730       (when winconf
 731         (set-window-configuration winconf)))))
 732
 733 (defun gnus-article-mail (yank)
 734   "Send a reply to the address near point.
 735 If YANK is non-nil, include the original article."
 736   (interactive "P")
 737   (let ((address
 738          (buffer-substring
 739           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
 740           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
 741     (when address
 742       (message-reply address)
 743       (when yank
 744         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
 745
 746 (defun gnus-bug ()
 747   "Send a bug report to the Gnus maintainers."
 748   (interactive)
 749   (unless (gnus-alive-p)
 750     (error "Gnus has been shut down"))
 751   (gnus-setup-message 'bug
 752     (delete-other-windows)
 753     (switch-to-buffer "*Gnus Help Bug*")
 754     (erase-buffer)
 755     (insert gnus-bug-message)
 756     (goto-char (point-min))
 757     (message-pop-to-buffer "*Gnus Bug*")
 758     (message-setup `((To . ,gnus-maintainer) (Subject . "")))
 759     (push `(gnus-bug-kill-buffer) message-send-actions)
 760     (goto-char (point-min))
 761     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
 762     (forward-line 1)
 763     (insert (gnus-version) "\n")
 764     (insert (emacs-version))
 765     (insert "\n\n\n\n\n")
 766     (gnus-debug)
 767     (goto-char (point-min))
 768     (search-forward "Subject: " nil t)
 769     (message "")))
 770
 771 (defun gnus-bug-kill-buffer ()
 772   (when (get-buffer "*Gnus Help Bug*")
 773     (kill-buffer "*Gnus Help Bug*")))
 774
 775 (defun gnus-debug ()
 776   "Attempts to go through the Gnus source file and report what variables have been changed.
 777 The source file has to be in the Emacs load path."
 778   (interactive)
 779   (let ((files '("gnus.el" "gnus-sum.el" "gnus-group.el"
 780                  "gnus-art.el" "gnus-start.el"
 781                  "gnus-msg.el" "gnus-score.el" "gnus-win.el"
 782                  "nnmail.el" "message.el"))
 783         file expr olist sym)
 784     (gnus-message 4 "Please wait while we snoop your variables...")
 785     (sit-for 0)
 786     ;; Go through all the files looking for non-default values for variables.
 787     (save-excursion
 788       (set-buffer (get-buffer-create " *gnus bug info*"))
 789       (buffer-disable-undo (current-buffer))
 790       (while files
 791         (erase-buffer)
 792         (when (and (setq file (locate-library (pop files)))
 793                    (file-exists-p file))
 794           (insert-file-contents file)
 795           (goto-char (point-min))
 796           (if (not (re-search-forward "^;;* *Internal variables" nil t))
 797               (gnus-message 4 "Malformed sources in file %s" file)
 798             (narrow-to-region (point-min) (point))
 799             (goto-char (point-min))
 800             (while (setq expr (condition-case ()
 801                                   (read (current-buffer)) (error nil)))
 802               (condition-case ()
 803                   (and (eq (car expr) 'defvar)
 804                        (stringp (nth 3 expr))
 805                        (or (not (boundp (nth 1 expr)))
 806                            (not (equal (eval (nth 2 expr))
 807                                        (symbol-value (nth 1 expr)))))
 808                        (push (nth 1 expr) olist))
 809                 (error nil))))))
 810       (kill-buffer (current-buffer)))
 811     (when (setq olist (nreverse olist))
 812       (insert "------------------ Environment follows ------------------\n\n"))
 813     (while olist
 814       (if (boundp (car olist))
 815           (condition-case ()
 816               (pp `(setq ,(car olist)
 817                          ,(if (or (consp (setq sym (symbol-value (car olist))))
 818                                   (and (symbolp sym)
 819                                        (not (or (eq sym nil)
 820                                                 (eq sym t)))))
 821                               (list 'quote (symbol-value (car olist)))
 822                             (symbol-value (car olist))))
 823                   (current-buffer))
 824             (error
 825              (format "(setq %s 'whatever)\n" (car olist))))
 826         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
 827       (setq olist (cdr olist)))
 828     (insert "\n\n")
 829     ;; Remove any null chars - they seem to cause trouble for some
 830     ;; mailers.  (Byte-compiled output from the stuff above.)
 831     (goto-char (point-min))
 832     (while (re-search-forward "[\000\200]" nil t)
 833       (replace-match "" t t))))
 834
 835 ;;; Treatment of rejected articles.
 836 ;;; Bounced mail.
 837
 838 (defun gnus-summary-resend-bounced-mail (&optional fetch)
 839   "Re-mail the current message.
 840 This only makes sense if the current message is a bounce message than
 841 contains some mail you have written which has been bounced back to
 842 you.
 843 If FETCH, try to fetch the article that this is a reply to, if indeed
 844 this is a reply."
 845   (interactive "P")
 846   (gnus-summary-select-article t)
 847   (set-buffer gnus-original-article-buffer)
 848   (gnus-setup-message 'compose-bounce
 849     (let* ((references (mail-fetch-field "references"))
 850            (parent (and references (gnus-parent-id references))))
 851       (message-bounce)
 852       ;; If there are references, we fetch the article we answered to.
 853       (and fetch parent
 854            (gnus-summary-refer-article parent)
 855            (gnus-summary-show-all-headers)))))
 856
 857 ;;; Gcc handling.
 858
 859 ;; Do Gcc handling, which copied the message over to some group.
 860 (defun gnus-inews-do-gcc (&optional gcc)
 861   (when (gnus-alive-p)
 862     (save-excursion
 863       (save-restriction
 864         (message-narrow-to-headers)
 865         (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
 866               (cur (current-buffer))
 867               groups group method)
 868           (when gcc
 869             (message-remove-header "gcc")
 870             (widen)
 871             (setq groups (message-tokenize-header gcc " ,"))
 872             ;; Copy the article over to some group(s).
 873             (while (setq group (pop groups))
 874               (gnus-check-server
 875                (setq method
 876                      (cond ((and (null (gnus-get-info group))
 877                                  (eq (car gnus-message-archive-method)
 878                                      (car
 879                                       (gnus-server-to-method
 880                                        (gnus-group-method group)))))
 881                             ;; If the group doesn't exist, we assume
 882                             ;; it's an archive group...
 883                             gnus-message-archive-method)
 884                            ;; Use the method.
 885                            ((gnus-info-method (gnus-get-info group))
 886                             (gnus-info-method (gnus-get-info group)))
 887                            ;; Find the method.
 888                            (t (gnus-group-method group)))))
 889               (gnus-check-server method)
 890               (unless (gnus-request-group group t method)
 891                 (gnus-request-create-group group method))
 892               (save-excursion
 893                 (nnheader-set-temp-buffer " *acc*")
 894                 (insert-buffer-substring cur)
 895                 (goto-char (point-min))
 896                 (when (re-search-forward
 897                        (concat "^" (regexp-quote mail-header-separator) "$")
 898                        nil t)
 899                   (replace-match "" t t ))
 900                 (unless (gnus-request-accept-article group method t)
 901                   (gnus-message 1 "Couldn't store article in group %s: %s"
 902                                 group (gnus-status-message method))
 903                   (sit-for 2))
 904                 (kill-buffer (current-buffer))))))))))
 905
 906 (defun gnus-inews-insert-gcc ()
 907   "Insert Gcc headers based on `gnus-outgoing-message-group'."
 908   (save-excursion
 909     (save-restriction
 910       (gnus-inews-narrow-to-headers)
 911       (let* ((group gnus-outgoing-message-group)
 912              (gcc (cond
 913                    ((gnus-functionp group)
 914                     (funcall group))
 915                    ((or (stringp group) (list group))
 916                     group))))
 917         (when gcc
 918           (insert "Gcc: "
 919                   (if (stringp gcc) gcc
 920                     (mapconcat 'identity gcc " "))
 921                   "\n"))))))
 922
 923 (defun gnus-inews-insert-archive-gcc (&optional group)
 924   "Insert the Gcc to say where the article is to be archived."
 925   (let* ((var gnus-message-archive-group)
 926          (group (or group gnus-newsgroup-name ""))
 927          result
 928          gcc-self-val
 929          (groups
 930           (cond
 931            ((null gnus-message-archive-method)
 932             ;; Ignore.
 933             nil)
 934            ((stringp var)
 935             ;; Just a single group.
 936             (list var))
 937            ((null var)
 938             ;; We don't want this.
 939             nil)
 940            ((and (listp var) (stringp (car var)))
 941             ;; A list of groups.
 942             var)
 943            ((gnus-functionp var)
 944             ;; A function.
 945             (funcall var group))
 946            (t
 947             ;; An alist of regexps/functions/forms.
 948             (while (and var
 949                         (not
 950                          (setq result
 951                                (cond
 952                                 ((stringp (caar var))
 953                                  ;; Regexp.
 954                                  (when (string-match (caar var) group)
 955                                    (cdar var)))
 956                                 ((gnus-functionp (car var))
 957                                  ;; Function.
 958                                  (funcall (car var) group))
 959                                 (t
 960                                  (eval (car var)))))))
 961               (setq var (cdr var)))
 962             result)))
 963          name)
 964     (when groups
 965       (when (stringp groups)
 966         (setq groups (list groups)))
 967       (save-excursion
 968         (save-restriction
 969           (gnus-inews-narrow-to-headers)
 970           (goto-char (point-max))
 971           (insert "Gcc: ")
 972           (if (and gnus-newsgroup-name
 973                    (setq gcc-self-val
 974                          (gnus-group-find-parameter
 975                           gnus-newsgroup-name 'gcc-self)))
 976               (progn
 977                 (insert
 978                  (if (stringp gcc-self-val)
 979                      gcc-self-val
 980                    group))
 981                 (if (not (eq gcc-self-val 'none))
 982                     (insert "\n")
 983                   (progn
 984                     (beginning-of-line)
 985                     (kill-line))))
 986             (while (setq name (pop groups))
 987               (insert (if (string-match ":" name)
 988                           name
 989                         (gnus-group-prefixed-name
 990                          name gnus-message-archive-method)))
 991               (when groups
 992                 (insert " ")))
 993             (insert "\n")))))))
 994
 995 (defun gnus-summary-send-draft ()
 996   "Enter a mail/post buffer to edit and send the draft."
 997   (interactive)
 998   (gnus-set-global-variables)
 999   (let (buf)
1000     (if (not (setq buf (gnus-request-restore-buffer
1001                         (gnus-summary-article-number) gnus-newsgroup-name)))
1002         (error "Couldn't restore the article")
1003       (switch-to-buffer buf)
1004       (when (eq major-mode 'news-reply-mode)
1005         (local-set-key "\C-c\C-c" 'gnus-inews-news))
1006       ;; Insert the separator.
1007       (goto-char (point-min))
1008       (search-forward "\n\n")
1009       (forward-char -1)
1010       (insert mail-header-separator)
1011       ;; Configure windows.
1012       (let ((gnus-draft-buffer (current-buffer)))
1013         (gnus-configure-windows 'draft t)
1014         (goto-char (point))))))
1015
1016 (gnus-add-shutdown 'gnus-inews-close 'gnus)
1017
1018 (defun gnus-inews-close ()
1019   (setq gnus-inews-sent-ids nil))
1020
1021 ;;; Allow redefinition of functions.
1022
1023 (gnus-ems-redefine)
1024
1025 (provide 'gnus-msg)
1026
1027 ;;; gnus-msg.el ends here