cgit.sxemacs.org Git - gnus/blob - lisp/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2 ;; Copyright (C) 1995,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   5 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32 (require 'gnus-ems)
  33 (require 'message)
  34 (require 'gnus-art)
  35
  36 (defcustom gnus-post-method nil
  37   "*Preferred method for posting USENET news.
  38
  39 If this variable is `current', Gnus will use the \"current\" select
  40 method when posting.  If it is nil (which is the default), Gnus will
  41 use the native posting method of the server.
  42
  43 This method will not be used in mail groups and the like, only in
  44 \"real\" newsgroups.
  45
  46 If not nil nor `native', the value must be a valid method as discussed
  47 in the documentation of `gnus-select-method'. It can also be a list of
  48 methods. If that is the case, the user will be queried for what select
  49 method to use when posting."
  50   :group 'gnus-group-foreign
  51   :type `(choice (const nil)
  52                  (const current)
  53                  (const native)
  54                  (sexp :tag "Methods" ,gnus-select-method)))
  55
  56 (defvar gnus-outgoing-message-group nil
  57   "*All outgoing messages will be put in this group.
  58 If you want to store all your outgoing mail and articles in the group
  59 \"nnml:archive\", you set this variable to that value.  This variable
  60 can also be a list of group names.
  61
  62 If you want to have greater control over what group to put each
  63 message in, you can set this variable to a function that checks the
  64 current newsgroup name and then returns a suitable group name (or list
  65 of names).")
  66
  67 (defvar gnus-mailing-list-groups nil
  68   "*Regexp matching groups that are really mailing lists.
  69 This is useful when you're reading a mailing list that has been
  70 gatewayed to a newsgroup, and you want to followup to an article in
  71 the group.")
  72
  73 (defvar gnus-add-to-list nil
  74   "*If non-nil, add a `to-list' parameter automatically.")
  75
  76 (defvar gnus-crosspost-complaint
  77   "Hi,
  78
  79 You posted the article below with the following Newsgroups header:
  80
  81 Newsgroups: %s
  82
  83 The %s group, at least, was an inappropriate recipient
  84 of this message.  Please trim your Newsgroups header to exclude this
  85 group before posting in the future.
  86
  87 Thank you.
  88
  89 "
  90   "Format string to be inserted when complaining about crossposts.
  91 The first %s will be replaced by the Newsgroups header;
  92 the second with the current group name.")
  93
  94 (defvar gnus-message-setup-hook nil
  95   "Hook run after setting up a message buffer.")
  96
  97 (defvar gnus-bug-create-help-buffer t
  98   "*Should we create the *Gnus Help Bug* buffer?")
  99
 100 (defvar gnus-posting-styles nil
 101   "*Alist of styles to use when posting.")
 102
 103 (defvar gnus-posting-style-alist
 104   '((organization . message-user-organization)
 105     (signature . message-signature)
 106     (signature-file . message-signature-file)
 107     (address . user-mail-address)
 108     (name . user-full-name))
 109   "*Mapping from style parameters to variables.")
 110
 111 ;;; Internal variables.
 112
 113 (defvar gnus-inhibit-posting-styles nil
 114   "Inhibit the use of posting styles.")
 115
 116 (defvar gnus-message-buffer "*Mail Gnus*")
 117 (defvar gnus-article-copy nil)
 118 (defvar gnus-last-posting-server nil)
 119 (defvar gnus-message-group-art nil)
 120
 121 (defconst gnus-bug-message
 122   "Sending a bug report to the Gnus Towers.
 123 ========================================
 124
 125 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 126 be sent to the Gnus Bug Exterminators.
 127
 128 At the bottom of the buffer you'll see lots of variable settings.
 129 Please do not delete those.  They will tell the Bug People what your
 130 environment is, so that it will be easier to locate the bugs.
 131
 132 If you have found a bug that makes Emacs go \"beep\", set
 133 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 134 and include the backtrace in your bug report.
 135
 136 Please describe the bug in annoying, painstaking detail.
 137
 138 Thank you for your help in stamping out bugs.
 139 ")
 140
 141 (eval-and-compile
 142   (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 143   (autoload 'news-setup "rnewspost")
 144   (autoload 'news-reply-mode "rnewspost")
 145   (autoload 'rmail-dont-reply-to "mail-utils")
 146   (autoload 'rmail-output "rmailout"))
 147
 148 \f
 149 ;;;
 150 ;;; Gnus Posting Functions
 151 ;;;
 152
 153 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 154   "p" gnus-summary-post-news
 155   "f" gnus-summary-followup
 156   "F" gnus-summary-followup-with-original
 157   "c" gnus-summary-cancel-article
 158   "s" gnus-summary-supersede-article
 159   "r" gnus-summary-reply
 160   "R" gnus-summary-reply-with-original
 161   "w" gnus-summary-wide-reply
 162   "W" gnus-summary-wide-reply-with-original
 163   "n" gnus-summary-followup-to-mail
 164   "N" gnus-summary-followup-to-mail-with-original
 165   "m" gnus-summary-mail-other-window
 166   "u" gnus-uu-post-news
 167   "\M-c" gnus-summary-mail-crosspost-complaint
 168   "om" gnus-summary-mail-forward
 169   "op" gnus-summary-post-forward
 170   "Om" gnus-uu-digest-mail-forward
 171   "Op" gnus-uu-digest-post-forward)
 172
 173 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 174   "b" gnus-summary-resend-bounced-mail
 175   ;; "c" gnus-summary-send-draft
 176   "r" gnus-summary-resend-message)
 177
 178 ;;; Internal functions.
 179
 180 (defvar gnus-article-reply nil)
 181 (defmacro gnus-setup-message (config &rest forms)
 182   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 183         (buffer (make-symbol "gnus-setup-message-buffer"))
 184         (article (make-symbol "gnus-setup-message-article"))
 185         (group (make-symbol "gnus-setup-message-group")))
 186     `(let ((,winconf (current-window-configuration))
 187            (,buffer (buffer-name (current-buffer)))
 188            (,article (and gnus-article-reply (gnus-summary-article-number)))
 189            (,group gnus-newsgroup-name)
 190            (message-header-setup-hook
 191             (copy-sequence message-header-setup-hook))
 192            (message-mode-hook (copy-sequence message-mode-hook)))
 193        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 194        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 195        (add-hook 'message-mode-hook 'gnus-configure-posting-styles)
 196        (unwind-protect
 197            (progn
 198              ,@forms)
 199          (gnus-inews-add-send-actions ,winconf ,buffer ,article)
 200          (setq gnus-message-buffer (current-buffer))
 201          (set (make-local-variable 'gnus-message-group-art)
 202               (cons ,group ,article))
 203          (make-local-variable 'gnus-newsgroup-name)
 204          (gnus-run-hooks 'gnus-message-setup-hook))
 205        (gnus-add-buffer)
 206        (gnus-configure-windows ,config t)
 207        (set-buffer-modified-p nil))))
 208
 209 (defun gnus-inews-add-send-actions (winconf buffer article)
 210   (make-local-hook 'message-sent-hook)
 211   (add-hook 'message-sent-hook 'gnus-inews-do-gcc nil t)
 212   (setq message-post-method
 213         `(lambda (arg)
 214            (gnus-post-method arg ,gnus-newsgroup-name)))
 215   (setq message-newsreader (setq message-mailer (gnus-extended-version)))
 216   (message-add-action
 217    `(set-window-configuration ,winconf) 'exit 'postpone 'kill)
 218   (message-add-action
 219    `(when (gnus-buffer-exists-p ,buffer)
 220       (save-excursion
 221         (set-buffer ,buffer)
 222         ,(when article
 223            `(gnus-summary-mark-article-as-replied ,article))))
 224    'send))
 225
 226 (put 'gnus-setup-message 'lisp-indent-function 1)
 227 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 228
 229 ;;; Post news commands of Gnus group mode and summary mode
 230
 231 (defun gnus-group-mail (&optional arg)
 232   "Start composing a mail.
 233 If ARG, use the group under the point to find a posting style.
 234 If ARG is 1, prompt for a group name to find the posting style."
 235   (interactive "P")
 236   (let ((gnus-newsgroup-name
 237          (if arg
 238              (if (= 1 (prefix-numeric-value arg))
 239                  (completing-read "Use style of group: " gnus-active-hashtb nil
 240                                   (gnus-read-active-file-p))
 241                (gnus-group-group-name))
 242            "")))
 243     (gnus-setup-message 'message (message-mail))
 244     ))
 245
 246 (defun gnus-group-post-news (&optional arg)
 247   "Start composing a news message.
 248 If ARG, post to the group under point.
 249 If ARG is 1, prompt for a group name."
 250   (interactive "P")
 251   ;; Bind this variable here to make message mode hooks work ok.
 252   (let ((gnus-newsgroup-name
 253          (if arg
 254              (if (= 1 (prefix-numeric-value arg))
 255                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 256                                   (gnus-read-active-file-p))
 257                (gnus-group-group-name))
 258            "")))
 259     (gnus-post-news 'post gnus-newsgroup-name)))
 260
 261 (defun gnus-summary-post-news ()
 262   "Start composing a news message."
 263   (interactive)
 264   (gnus-post-news 'post gnus-newsgroup-name))
 265
 266 (defun gnus-summary-followup (yank &optional force-news)
 267   "Compose a followup to an article.
 268 If prefix argument YANK is non-nil, original article is yanked automatically."
 269   (interactive
 270    (list (and current-prefix-arg
 271               (gnus-summary-work-articles 1))))
 272   (when yank
 273     (gnus-summary-goto-subject (car yank)))
 274   (save-window-excursion
 275     (gnus-summary-select-article))
 276   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 277         (gnus-newsgroup-name gnus-newsgroup-name))
 278     ;; Send a followup.
 279     (gnus-post-news nil gnus-newsgroup-name
 280                     headers gnus-article-buffer
 281                     yank nil force-news)))
 282
 283 (defun gnus-summary-followup-with-original (n &optional force-news)
 284   "Compose a followup to an article and include the original article."
 285   (interactive "P")
 286   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 287
 288 (defun gnus-summary-followup-to-mail (&optional arg)
 289   "Followup to the current mail message via news."
 290   (interactive
 291    (list (and current-prefix-arg
 292               (gnus-summary-work-articles 1))))
 293   (gnus-summary-followup arg t))
 294
 295 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 296   "Followup to the current mail message via news."
 297   (interactive "P")
 298   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 299
 300 (defun gnus-inews-yank-articles (articles)
 301   (let (beg article)
 302     (message-goto-body)
 303     (while (setq article (pop articles))
 304       (save-window-excursion
 305         (set-buffer gnus-summary-buffer)
 306         (gnus-summary-select-article nil nil nil article)
 307         (gnus-summary-remove-process-mark article))
 308       (gnus-copy-article-buffer)
 309       (let ((message-reply-buffer gnus-article-copy)
 310             (message-reply-headers gnus-current-headers))
 311         (message-yank-original)
 312         (setq beg (or beg (mark t))))
 313       (when articles
 314         (insert "\n")))
 315     (push-mark)
 316     (goto-char beg)))
 317
 318 (defun gnus-summary-cancel-article (&optional n symp)
 319   "Cancel an article you posted.
 320 Uses the process-prefix convention.  If given the symbolic
 321 prefix `a', cancel using the standard posting method; if not
 322 post using the current select method."
 323   (interactive (gnus-interactive "P\ny"))
 324   (let ((articles (gnus-summary-work-articles n))
 325         (message-post-method
 326          `(lambda (arg)
 327             (gnus-post-method (not (eq symp 'a)) ,gnus-newsgroup-name)))
 328         article)
 329     (while (setq article (pop articles))
 330       (when (gnus-summary-select-article t nil nil article)
 331         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 332                 (message-cancel-news))
 333           (gnus-summary-mark-as-read article gnus-canceled-mark)
 334           (gnus-cache-remove-article 1))
 335         (gnus-article-hide-headers-if-wanted))
 336       (gnus-summary-remove-process-mark article))))
 337
 338 (defun gnus-summary-supersede-article ()
 339   "Compose an article that will supersede a previous article.
 340 This is done simply by taking the old article and adding a Supersedes
 341 header line with the old Message-ID."
 342   (interactive)
 343   (let ((article (gnus-summary-article-number)))
 344     (gnus-setup-message 'reply-yank
 345       (gnus-summary-select-article t)
 346       (set-buffer gnus-original-article-buffer)
 347       (message-supersede)
 348       (push
 349        `((lambda ()
 350            (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 351              (save-excursion
 352                (set-buffer ,gnus-summary-buffer)
 353                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 354                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 355        message-send-actions))))
 356
 357 \f
 358
 359 (defun gnus-copy-article-buffer (&optional article-buffer)
 360   ;; make a copy of the article buffer with all text properties removed
 361   ;; this copy is in the buffer gnus-article-copy.
 362   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 363   ;; this buffer should be passed to all mail/news reply/post routines.
 364   (setq gnus-article-copy (gnus-get-buffer-create " *gnus article copy*"))
 365   (buffer-disable-undo gnus-article-copy)
 366   (save-excursion
 367     (set-buffer gnus-article-copy)
 368     (mm-enable-multibyte))
 369   (let ((article-buffer (or article-buffer gnus-article-buffer))
 370         end beg)
 371     (if (not (and (get-buffer article-buffer)
 372                   (gnus-buffer-exists-p article-buffer)))
 373         (error "Can't find any article buffer")
 374       (save-excursion
 375         (set-buffer article-buffer)
 376         (save-restriction
 377           ;; Copy over the (displayed) article buffer, delete
 378           ;; hidden text and remove text properties.
 379           (widen)
 380           (copy-to-buffer gnus-article-copy (point-min) (point-max))
 381           (set-buffer gnus-article-copy)
 382           (gnus-article-delete-text-of-type 'annotation)
 383           (gnus-remove-text-with-property 'gnus-prev)
 384           (gnus-remove-text-with-property 'gnus-next)
 385           (insert
 386            (prog1
 387                (format "%s" (buffer-string))
 388              (erase-buffer)))
 389           ;; Find the original headers.
 390           (set-buffer gnus-original-article-buffer)
 391           (goto-char (point-min))
 392           (while (looking-at message-unix-mail-delimiter)
 393             (forward-line 1))
 394           (setq beg (point))
 395           (setq end (or (search-forward "\n\n" nil t) (point)))
 396           ;; Delete the headers from the displayed articles.
 397           (set-buffer gnus-article-copy)
 398           (delete-region (goto-char (point-min))
 399                          (or (search-forward "\n\n" nil t) (point)))
 400           ;; Insert the original article headers.
 401           (insert-buffer-substring gnus-original-article-buffer beg end)
 402           (gnus-article-decode-rfc1522)))
 403       gnus-article-copy)))
 404
 405 (defun gnus-post-news (post &optional group header article-buffer yank subject
 406                             force-news)
 407   (when article-buffer
 408     (gnus-copy-article-buffer))
 409   (let ((gnus-article-reply article-buffer)
 410         (add-to-list gnus-add-to-list))
 411     (gnus-setup-message (cond (yank 'reply-yank)
 412                               (article-buffer 'reply)
 413                               (t 'message))
 414       (let* ((group (or group gnus-newsgroup-name))
 415              (pgroup group)
 416              to-address to-group mailing-list to-list
 417              newsgroup-p)
 418         (when group
 419           (setq to-address (gnus-group-find-parameter group 'to-address)
 420                 to-group (gnus-group-find-parameter group 'to-group)
 421                 to-list (gnus-group-find-parameter group 'to-list)
 422                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 423                 mailing-list (when gnus-mailing-list-groups
 424                                (string-match gnus-mailing-list-groups group))
 425                 group (gnus-group-real-name group)))
 426         (if (or (and to-group
 427                      (gnus-news-group-p to-group))
 428                 newsgroup-p
 429                 force-news
 430                 (and (gnus-news-group-p
 431                       (or pgroup gnus-newsgroup-name)
 432                       (if header (mail-header-number header)
 433                         gnus-current-article))
 434                      (not mailing-list)
 435                      (not to-list)
 436                      (not to-address)))
 437             ;; This is news.
 438             (if post
 439                 (message-news (or to-group group))
 440               (set-buffer gnus-article-copy)
 441               (gnus-msg-treat-broken-reply-to)
 442               (message-followup (if (or newsgroup-p force-news) nil to-group)))
 443           ;; The is mail.
 444           (if post
 445               (progn
 446                 (message-mail (or to-address to-list))
 447                 ;; Arrange for mail groups that have no `to-address' to
 448                 ;; get that when the user sends off the mail.
 449                 (when (and (not to-list)
 450                            (not to-address)
 451                            add-to-list)
 452                   (push (list 'gnus-inews-add-to-address pgroup)
 453                         message-send-actions)))
 454             (set-buffer gnus-article-copy)
 455             (gnus-msg-treat-broken-reply-to)
 456             (message-wide-reply to-address)))
 457         (when yank
 458           (gnus-inews-yank-articles yank))))))
 459
 460 (defun gnus-msg-treat-broken-reply-to ()
 461   "Remove the Reply-to header iff broken-reply-to."
 462   (when (gnus-group-find-parameter
 463          gnus-newsgroup-name 'broken-reply-to)
 464     (save-restriction
 465       (message-narrow-to-head)
 466       (message-remove-header "reply-to"))))
 467
 468 (defun gnus-post-method (arg group &optional silent)
 469   "Return the posting method based on GROUP and ARG.
 470 If SILENT, don't prompt the user."
 471   (let ((group-method (gnus-find-method-for-group group)))
 472     (cond
 473      ;; If the group-method is nil (which shouldn't happen) we use
 474      ;; the default method.
 475      ((null group-method)
 476       (or (and (null (eq gnus-post-method 'active)) gnus-post-method)
 477                gnus-select-method message-post-method))
 478      ;; We want the inverse of the default
 479      ((and arg (not (eq arg 0)))
 480       (if (eq gnus-post-method 'active)
 481           gnus-select-method
 482         group-method))
 483      ;; We query the user for a post method.
 484      ((or arg
 485           (and gnus-post-method
 486                (not (eq gnus-post-method 'current))
 487                (listp (car gnus-post-method))))
 488       (let* ((methods
 489               ;; Collect all methods we know about.
 490               (append
 491                (when (and gnus-post-method
 492                           (not (eq gnus-post-method 'current)))
 493                  (if (listp (car gnus-post-method))
 494                      gnus-post-method
 495                    (list gnus-post-method)))
 496                gnus-secondary-select-methods
 497                (mapcar 'cdr gnus-server-alist)
 498                (mapcar 'car gnus-opened-servers)
 499                (list gnus-select-method)
 500                (list group-method)))
 501              method-alist post-methods method)
 502         ;; Weed out all mail methods.
 503         (while methods
 504           (setq method (gnus-server-get-method "" (pop methods)))
 505           (when (and (or (gnus-method-option-p method 'post)
 506                          (gnus-method-option-p method 'post-mail))
 507                      (not (member method post-methods)))
 508             (push method post-methods)))
 509         ;; Create a name-method alist.
 510         (setq method-alist
 511               (mapcar
 512                (lambda (m)
 513                  (list (concat (cadr m) " (" (symbol-name (car m)) ")") m))
 514                post-methods))
 515         ;; Query the user.
 516         (cadr
 517          (assoc
 518           (setq gnus-last-posting-server
 519                 (if (and silent
 520                          gnus-last-posting-server)
 521                     ;; Just use the last value.
 522                     gnus-last-posting-server
 523                   (completing-read
 524                    "Posting method: " method-alist nil t
 525                    (cons (or gnus-last-posting-server "") 0))))
 526           method-alist))))
 527      ;; Override normal method.
 528      ((and (eq gnus-post-method 'current)
 529            (not (eq (car group-method) 'nndraft))
 530            (not arg))
 531       group-method)
 532      ((and gnus-post-method
 533            (not (eq gnus-post-method 'current)))
 534       gnus-post-method)
 535      ;; Use the normal select method.
 536      (t gnus-select-method))))
 537
 538 \f
 539
 540 ;; Dummy to avoid byte-compile warning.
 541 (defvar nnspool-rejected-article-hook)
 542 (defvar xemacs-codename)
 543
 544 ;;; Since the X-Newsreader/X-Mailer are ``vanity'' headers, they might
 545 ;;; as well include the Emacs version as well.
 546 ;;; The following function works with later GNU Emacs, and XEmacs.
 547 (defun gnus-extended-version ()
 548   "Stringified Gnus version and Emacs version."
 549   (interactive)
 550   (concat
 551    gnus-version
 552    "/"
 553    (cond
 554     ((string-match "^\\([0-9]+\\.[0-9]+\\)\\.[.0-9]+$" emacs-version)
 555      (concat "Emacs " (substring emacs-version
 556                                  (match-beginning 1)
 557                                  (match-end 1))))
 558     ((string-match "\\([A-Z]*[Mm][Aa][Cc][Ss]\\)[^(]*\\(\\((beta.*)\\|'\\)\\)?"
 559                    emacs-version)
 560      (concat (substring emacs-version
 561                         (match-beginning 1)
 562                         (match-end 1))
 563              (format " %d.%d" emacs-major-version emacs-minor-version)
 564              (if (match-beginning 3)
 565                  (substring emacs-version
 566                             (match-beginning 3)
 567                             (match-end 3))
 568                "")
 569              (if (boundp 'xemacs-codename)
 570                  (concat " - \"" xemacs-codename "\""))))
 571     (t emacs-version))))
 572
 573 \f
 574 ;;;
 575 ;;; Gnus Mail Functions
 576 ;;;
 577
 578 ;;; Mail reply commands of Gnus summary mode
 579
 580 (defun gnus-summary-reply (&optional yank wide)
 581   "Start composing a reply mail to the current message.
 582 If prefix argument YANK is non-nil, the original article is yanked
 583 automatically."
 584   (interactive
 585    (list (and current-prefix-arg
 586               (gnus-summary-work-articles 1))))
 587   ;; Stripping headers should be specified with mail-yank-ignored-headers.
 588   (when yank
 589     (gnus-summary-goto-subject (car yank)))
 590   (let ((gnus-article-reply t))
 591     (gnus-setup-message (if yank 'reply-yank 'reply)
 592       (gnus-summary-select-article)
 593       (set-buffer (gnus-copy-article-buffer))
 594       (gnus-msg-treat-broken-reply-to)
 595       (message-reply nil wide)
 596       (when yank
 597         (gnus-inews-yank-articles yank)))))
 598
 599 (defun gnus-summary-reply-with-original (n &optional wide)
 600   "Start composing a reply mail to the current message.
 601 The original article will be yanked."
 602   (interactive "P")
 603   (gnus-summary-reply (gnus-summary-work-articles n) wide))
 604
 605 (defun gnus-summary-wide-reply (&optional yank)
 606   "Start composing a wide reply mail to the current message.
 607 If prefix argument YANK is non-nil, the original article is yanked
 608 automatically."
 609   (interactive
 610    (list (and current-prefix-arg
 611               (gnus-summary-work-articles 1))))
 612   (gnus-summary-reply yank t))
 613
 614 (defun gnus-summary-wide-reply-with-original (n)
 615   "Start composing a wide reply mail to the current message.
 616 The original article will be yanked."
 617   (interactive "P")
 618   (gnus-summary-reply-with-original n t))
 619
 620 (defun gnus-summary-mail-forward (&optional full-headers post)
 621   "Forward the current message to another user.
 622 If FULL-HEADERS (the prefix), include full headers when forwarding."
 623   (interactive "P")
 624   (gnus-setup-message 'forward
 625     (gnus-summary-select-article)
 626     (set-buffer gnus-original-article-buffer)
 627     (let ((message-included-forward-headers
 628            (if full-headers "" message-included-forward-headers)))
 629       (message-forward post))))
 630
 631 (defun gnus-summary-resend-message (address n)
 632   "Resend the current article to ADDRESS."
 633   (interactive "sResend message(s) to: \nP")
 634   (let ((articles (gnus-summary-work-articles n))
 635         article)
 636     (while (setq article (pop articles))
 637       (gnus-summary-select-article nil nil nil article)
 638       (save-excursion
 639         (set-buffer gnus-original-article-buffer)
 640         (message-resend address)))))
 641
 642 (defun gnus-summary-post-forward (&optional full-headers)
 643   "Forward the current article to a newsgroup.
 644 If FULL-HEADERS (the prefix), include full headers when forwarding."
 645   (interactive "P")
 646   (gnus-summary-mail-forward full-headers t))
 647
 648 (defvar gnus-nastygram-message
 649   "The following article was inappropriately posted to %s.\n\n"
 650   "Format string to insert in nastygrams.
 651 The current group name will be inserted at \"%s\".")
 652
 653 (defun gnus-summary-mail-nastygram (n)
 654   "Send a nastygram to the author of the current article."
 655   (interactive "P")
 656   (when (or gnus-expert-user
 657             (gnus-y-or-n-p
 658              "Really send a nastygram to the author of the current article? "))
 659     (let ((group gnus-newsgroup-name))
 660       (gnus-summary-reply-with-original n)
 661       (set-buffer gnus-message-buffer)
 662       (message-goto-body)
 663       (insert (format gnus-nastygram-message group))
 664       (message-send-and-exit))))
 665
 666 (defun gnus-summary-mail-crosspost-complaint (n)
 667   "Send a complaint about crossposting to the current article(s)."
 668   (interactive "P")
 669   (let ((articles (gnus-summary-work-articles n))
 670         article)
 671     (while (setq article (pop articles))
 672       (set-buffer gnus-summary-buffer)
 673       (gnus-summary-goto-subject article)
 674       (let ((group (gnus-group-real-name gnus-newsgroup-name))
 675             newsgroups followup-to)
 676         (gnus-summary-select-article)
 677         (set-buffer gnus-original-article-buffer)
 678         (if (and (<= (length (message-tokenize-header
 679                               (setq newsgroups (mail-fetch-field "newsgroups"))
 680                               ", "))
 681                      1)
 682                  (or (not (setq followup-to (mail-fetch-field "followup-to")))
 683                      (not (member group (message-tokenize-header
 684                                          followup-to ", ")))))
 685             (if followup-to
 686                 (gnus-message 1 "Followup-to restricted")
 687               (gnus-message 1 "Not a crossposted article"))
 688           (set-buffer gnus-summary-buffer)
 689           (gnus-summary-reply-with-original 1)
 690           (set-buffer gnus-message-buffer)
 691           (message-goto-body)
 692           (insert (format gnus-crosspost-complaint newsgroups group))
 693           (message-goto-subject)
 694           (re-search-forward " *$")
 695           (replace-match " (crosspost notification)" t t)
 696           (gnus-deactivate-mark)
 697           (when (gnus-y-or-n-p "Send this complaint? ")
 698             (message-send-and-exit)))))))
 699
 700 (defun gnus-summary-mail-other-window ()
 701   "Compose mail in other window."
 702   (interactive)
 703   (gnus-setup-message 'message
 704     (message-mail)))
 705
 706 (defun gnus-mail-parse-comma-list ()
 707   (let (accumulated
 708         beg)
 709     (skip-chars-forward " ")
 710     (while (not (eobp))
 711       (setq beg (point))
 712       (skip-chars-forward "^,")
 713       (while (zerop
 714               (save-excursion
 715                 (save-restriction
 716                   (let ((i 0))
 717                     (narrow-to-region beg (point))
 718                     (goto-char beg)
 719                     (logand (progn
 720                               (while (search-forward "\"" nil t)
 721                                 (incf i))
 722                               (if (zerop i) 2 i))
 723                             2)))))
 724         (skip-chars-forward ",")
 725         (skip-chars-forward "^,"))
 726       (skip-chars-backward " ")
 727       (push (buffer-substring beg (point))
 728             accumulated)
 729       (skip-chars-forward "^,")
 730       (skip-chars-forward ", "))
 731     accumulated))
 732
 733 (defun gnus-inews-add-to-address (group)
 734   (let ((to-address (mail-fetch-field "to")))
 735     (when (and to-address
 736                (gnus-alive-p))
 737       ;; This mail group doesn't have a `to-list', so we add one
 738       ;; here.  Magic!
 739       (when (gnus-y-or-n-p
 740              (format "Do you want to add this as `to-list': %s " to-address))
 741         (gnus-group-add-parameter group (cons 'to-list to-address))))))
 742
 743 (defun gnus-put-message ()
 744   "Put the current message in some group and return to Gnus."
 745   (interactive)
 746   (let ((reply gnus-article-reply)
 747         (winconf gnus-prev-winconf)
 748         (group gnus-newsgroup-name))
 749
 750     (or (and group (not (gnus-group-read-only-p group)))
 751         (setq group (read-string "Put in group: " nil
 752                                  (gnus-writable-groups))))
 753     (when (gnus-gethash group gnus-newsrc-hashtb)
 754       (error "No such group: %s" group))
 755
 756     (save-excursion
 757       (save-restriction
 758         (widen)
 759         (message-narrow-to-headers)
 760         (let (gnus-deletable-headers)
 761           (if (message-news-p)
 762               (message-generate-headers message-required-news-headers)
 763             (message-generate-headers message-required-mail-headers)))
 764         (goto-char (point-max))
 765         (insert "Gcc: " group "\n")
 766         (widen)))
 767
 768     (gnus-inews-do-gcc)
 769
 770     (when (get-buffer gnus-group-buffer)
 771       (when (gnus-buffer-exists-p (car-safe reply))
 772         (set-buffer (car reply))
 773         (and (cdr reply)
 774              (gnus-summary-mark-article-as-replied
 775               (cdr reply))))
 776       (when winconf
 777         (set-window-configuration winconf)))))
 778
 779 (defun gnus-article-mail (yank)
 780   "Send a reply to the address near point.
 781 If YANK is non-nil, include the original article."
 782   (interactive "P")
 783   (let ((address
 784          (buffer-substring
 785           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
 786           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
 787     (when address
 788       (message-reply address)
 789       (when yank
 790         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
 791
 792 (defvar nntp-server-type)
 793 (defun gnus-bug ()
 794   "Send a bug report to the Gnus maintainers."
 795   (interactive)
 796   (unless (gnus-alive-p)
 797     (error "Gnus has been shut down"))
 798   (gnus-setup-message 'bug
 799     (delete-other-windows)
 800     (when gnus-bug-create-help-buffer
 801       (switch-to-buffer "*Gnus Help Bug*")
 802       (erase-buffer)
 803       (insert gnus-bug-message)
 804       (goto-char (point-min)))
 805     (message-pop-to-buffer "*Gnus Bug*")
 806     (message-setup `((To . ,gnus-maintainer) (Subject . "")))
 807     (when gnus-bug-create-help-buffer
 808       (push `(gnus-bug-kill-buffer) message-send-actions))
 809     (goto-char (point-min))
 810     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
 811     (forward-line 1)
 812     (insert (gnus-version) "\n"
 813             (emacs-version) "\n")
 814     (when (and (boundp 'nntp-server-type)
 815                (stringp nntp-server-type))
 816       (insert nntp-server-type))
 817     (insert "\n\n\n\n\n")
 818     (gnus-debug)
 819     (goto-char (point-min))
 820     (search-forward "Subject: " nil t)
 821     (message "")))
 822
 823 (defun gnus-bug-kill-buffer ()
 824   (when (get-buffer "*Gnus Help Bug*")
 825     (kill-buffer "*Gnus Help Bug*")))
 826
 827 (defun gnus-debug ()
 828   "Attempts to go through the Gnus source file and report what variables have been changed.
 829 The source file has to be in the Emacs load path."
 830   (interactive)
 831   (let ((files '("gnus.el" "gnus-sum.el" "gnus-group.el"
 832                  "gnus-art.el" "gnus-start.el" "gnus-async.el"
 833                  "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
 834                  "nnmail.el" "message.el"))
 835         (point (point))
 836         file expr olist sym)
 837     (gnus-message 4 "Please wait while we snoop your variables...")
 838     (sit-for 0)
 839     ;; Go through all the files looking for non-default values for variables.
 840     (save-excursion
 841       (set-buffer (gnus-get-buffer-create " *gnus bug info*"))
 842       (buffer-disable-undo (current-buffer))
 843       (while files
 844         (erase-buffer)
 845         (when (and (setq file (locate-library (pop files)))
 846                    (file-exists-p file))
 847           (insert-file-contents file)
 848           (goto-char (point-min))
 849           (if (not (re-search-forward "^;;* *Internal variables" nil t))
 850               (gnus-message 4 "Malformed sources in file %s" file)
 851             (narrow-to-region (point-min) (point))
 852             (goto-char (point-min))
 853             (while (setq expr (ignore-errors (read (current-buffer))))
 854               (ignore-errors
 855                 (and (or (eq (car expr) 'defvar)
 856                          (eq (car expr) 'defcustom))
 857                      (stringp (nth 3 expr))
 858                      (or (not (boundp (nth 1 expr)))
 859                          (not (equal (eval (nth 2 expr))
 860                                      (symbol-value (nth 1 expr)))))
 861                      (push (nth 1 expr) olist)))))))
 862       (kill-buffer (current-buffer)))
 863     (when (setq olist (nreverse olist))
 864       (insert "------------------ Environment follows ------------------\n\n"))
 865     (while olist
 866       (if (boundp (car olist))
 867           (condition-case ()
 868               (pp `(setq ,(car olist)
 869                          ,(if (or (consp (setq sym (symbol-value (car olist))))
 870                                   (and (symbolp sym)
 871                                        (not (or (eq sym nil)
 872                                                 (eq sym t)))))
 873                               (list 'quote (symbol-value (car olist)))
 874                             (symbol-value (car olist))))
 875                   (current-buffer))
 876             (error
 877              (format "(setq %s 'whatever)\n" (car olist))))
 878         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
 879       (setq olist (cdr olist)))
 880     (insert "\n\n")
 881     ;; Remove any control chars - they seem to cause trouble for some
 882     ;; mailers.  (Byte-compiled output from the stuff above.)
 883     (goto-char point)
 884     (while (re-search-forward "[\000-\010\013-\037\200-\237]" nil t)
 885       (replace-match (format "\\%03o" (string-to-char (match-string 0)))
 886                      t t))))
 887
 888 ;;; Treatment of rejected articles.
 889 ;;; Bounced mail.
 890
 891 (defun gnus-summary-resend-bounced-mail (&optional fetch)
 892   "Re-mail the current message.
 893 This only makes sense if the current message is a bounce message than
 894 contains some mail you have written which has been bounced back to
 895 you.
 896 If FETCH, try to fetch the article that this is a reply to, if indeed
 897 this is a reply."
 898   (interactive "P")
 899   (gnus-summary-select-article t)
 900   (set-buffer gnus-original-article-buffer)
 901   (gnus-setup-message 'compose-bounce
 902     (let* ((references (mail-fetch-field "references"))
 903            (parent (and references (gnus-parent-id references))))
 904       (message-bounce)
 905       ;; If there are references, we fetch the article we answered to.
 906       (and fetch parent
 907            (gnus-summary-refer-article parent)
 908            (gnus-summary-show-all-headers)))))
 909
 910 ;;; Gcc handling.
 911
 912 ;; Do Gcc handling, which copied the message over to some group.
 913 (defun gnus-inews-do-gcc (&optional gcc)
 914   (interactive)
 915   (when (gnus-alive-p)
 916     (save-excursion
 917       (save-restriction
 918         (message-narrow-to-headers)
 919         (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
 920               (cur (current-buffer))
 921               groups group method)
 922           (when gcc
 923             (message-remove-header "gcc")
 924             (widen)
 925             (setq groups (message-tokenize-header gcc " ,"))
 926             ;; Copy the article over to some group(s).
 927             (while (setq group (pop groups))
 928               (gnus-check-server
 929                (setq method
 930                      (cond ((and (null (gnus-get-info group))
 931                                  (eq (car gnus-message-archive-method)
 932                                      (car
 933                                       (gnus-server-to-method
 934                                        (gnus-group-method group)))))
 935                             ;; If the group doesn't exist, we assume
 936                             ;; it's an archive group...
 937                             gnus-message-archive-method)
 938                            ;; Use the method.
 939                            ((gnus-info-method (gnus-get-info group))
 940                             (gnus-info-method (gnus-get-info group)))
 941                            ;; Find the method.
 942                            (t (gnus-group-method group)))))
 943               (gnus-check-server method)
 944               (unless (gnus-request-group group t method)
 945                 (gnus-request-create-group group method))
 946               (save-excursion
 947                 (nnheader-set-temp-buffer " *acc*")
 948                 (insert-buffer-substring cur)
 949                 (goto-char (point-min))
 950                 (when (re-search-forward
 951                        (concat "^" (regexp-quote mail-header-separator) "$")
 952                        nil t)
 953                   (replace-match "" t t ))
 954                 (unless (gnus-request-accept-article group method t)
 955                   (gnus-message 1 "Couldn't store article in group %s: %s"
 956                                 group (gnus-status-message method))
 957                   (sit-for 2))
 958                 (kill-buffer (current-buffer))))))))))
 959
 960 (defun gnus-inews-insert-gcc ()
 961   "Insert Gcc headers based on `gnus-outgoing-message-group'."
 962   (save-excursion
 963     (save-restriction
 964       (message-narrow-to-headers)
 965       (let* ((group gnus-outgoing-message-group)
 966              (gcc (cond
 967                    ((gnus-functionp group)
 968                     (funcall group))
 969                    ((or (stringp group) (list group))
 970                     group))))
 971         (when gcc
 972           (insert "Gcc: "
 973                   (if (stringp gcc) gcc
 974                     (mapconcat 'identity gcc " "))
 975                   "\n"))))))
 976
 977 (defun gnus-inews-insert-archive-gcc (&optional group)
 978   "Insert the Gcc to say where the article is to be archived."
 979   (let* ((var gnus-message-archive-group)
 980          (group (or group gnus-newsgroup-name ""))
 981          (gcc-self-val
 982           (and gnus-newsgroup-name
 983                (gnus-group-find-parameter
 984                 gnus-newsgroup-name 'gcc-self)))
 985          result
 986          (groups
 987           (cond
 988            ((null gnus-message-archive-method)
 989             ;; Ignore.
 990             nil)
 991            ((stringp var)
 992             ;; Just a single group.
 993             (list var))
 994            ((null var)
 995             ;; We don't want this.
 996             nil)
 997            ((and (listp var) (stringp (car var)))
 998             ;; A list of groups.
 999             var)
1000            ((gnus-functionp var)
1001             ;; A function.
1002             (funcall var group))
1003            (t
1004             ;; An alist of regexps/functions/forms.
1005             (while (and var
1006                         (not
1007                          (setq result
1008                                (cond
1009                                 ((stringp (caar var))
1010                                  ;; Regexp.
1011                                  (when (string-match (caar var) group)
1012                                    (cdar var)))
1013                                 ((gnus-functionp (car var))
1014                                  ;; Function.
1015                                  (funcall (car var) group))
1016                                 (t
1017                                  (eval (car var)))))))
1018               (setq var (cdr var)))
1019             result)))
1020          name)
1021     (when (or groups gcc-self-val)
1022       (when (stringp groups)
1023         (setq groups (list groups)))
1024       (save-excursion
1025         (save-restriction
1026           (message-narrow-to-headers)
1027           (goto-char (point-max))
1028           (insert "Gcc: ")
1029           (if gcc-self-val
1030               ;; Use the `gcc-self' param value instead.
1031               (progn
1032                 (insert
1033                  (if (stringp gcc-self-val)
1034                      gcc-self-val
1035                    group))
1036                 (if (not (eq gcc-self-val 'none))
1037                     (insert "\n")
1038                   (progn
1039                     (beginning-of-line)
1040                     (kill-line))))
1041             ;; Use the list of groups.
1042             (while (setq name (pop groups))
1043               (insert (if (string-match ":" name)
1044                           name
1045                         (gnus-group-prefixed-name
1046                          name gnus-message-archive-method)))
1047               (when groups
1048                 (insert " ")))
1049             (insert "\n")))))))
1050
1051 ;;; Posting styles.
1052
1053 (defvar gnus-message-style-insertions nil)
1054
1055 (defun gnus-configure-posting-styles ()
1056   "Configure posting styles according to `gnus-posting-styles'."
1057   (unless gnus-inhibit-posting-styles
1058     (let ((styles gnus-posting-styles)
1059           (gnus-newsgroup-name (or gnus-newsgroup-name ""))
1060           style match variable attribute value value-value)
1061       (make-local-variable 'gnus-message-style-insertions)
1062       ;; Go through all styles and look for matches.
1063       (while styles
1064         (setq style (pop styles)
1065               match (pop style))
1066         (when (cond ((stringp match)
1067                      ;; Regexp string match on the group name.
1068                      (string-match match gnus-newsgroup-name))
1069                     ((or (symbolp match)
1070                          (gnus-functionp match))
1071                      (cond ((gnus-functionp match)
1072                             ;; Function to be called.
1073                             (funcall match))
1074                            ((boundp match)
1075                             ;; Variable to be checked.
1076                             (symbol-value match))))
1077                     ((listp match)
1078                      ;; This is a form to be evaled.
1079                      (eval match)))
1080           ;; We have a match, so we set the variables.
1081           (while style
1082             (setq attribute (pop style)
1083                   value (cadr attribute)
1084                   variable nil)
1085             ;; We find the variable that is to be modified.
1086             (if (and (not (stringp (car attribute)))
1087                      (not (eq 'body (car attribute)))
1088                      (not (setq variable
1089                                 (cdr (assq (car attribute)
1090                                            gnus-posting-style-alist)))))
1091                 (message "Couldn't find attribute %s" (car attribute))
1092               ;; We get the value.
1093               (setq value-value
1094                     (cond ((stringp value)
1095                            value)
1096                           ((or (symbolp value)
1097                                (gnus-functionp value))
1098                            (cond ((gnus-functionp value)
1099                                   (funcall value))
1100                                  ((boundp value)
1101                                   (symbol-value value))))
1102                           ((listp value)
1103                            (eval value))))
1104               (if variable
1105                   ;; This is an ordinary variable.
1106                   (set (make-local-variable variable) value-value)
1107                 ;; This is either a body or a header to be inserted in the
1108                 ;; message.
1109                 (when value-value
1110                   (let ((attr (car attribute)))
1111                     (make-local-variable 'message-setup-hook)
1112                     (if (eq 'body attr)
1113                         (add-hook 'message-setup-hook
1114                                   `(lambda ()
1115                                      (save-excursion
1116                                        (message-goto-body)
1117                                        (insert ,value-value))))
1118                       (add-hook 'message-setup-hook
1119                                 'gnus-message-insert-stylings)
1120                       (push (cons (if (stringp attr) attr
1121                                     (symbol-name attr))
1122                                   value-value)
1123                             gnus-message-style-insertions))))))))))))
1124
1125 (defun gnus-message-insert-stylings ()
1126   (let (val)
1127     (save-excursion
1128       (message-goto-eoh)
1129       (while (setq val (pop gnus-message-style-insertions))
1130         (when (cdr val)
1131           (insert (car val) ": " (cdr val) "\n"))
1132         (gnus-pull (car val) gnus-message-style-insertions)))))
1133
1134 ;;; Allow redefinition of functions.
1135
1136 (gnus-ems-redefine)
1137
1138 (provide 'gnus-msg)
1139
1140 ;;; gnus-msg.el ends here