cgit.sxemacs.org Git - gnus/blob - lisp/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   5 ;;      Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'gnus-load)
  30 (require 'gnus-ems)
  31 (require 'message)
  32 (require 'gnus-art)
  33 (require 'gnus)
  34
  35 ;; Added by Sudish Joseph <joseph@cis.ohio-state.edu>.
  36 (defvar gnus-post-method nil
  37   "*Preferred method for posting USENET news.
  38 If this variable is nil, Gnus will use the current method to decide
  39 which method to use when posting.  If it is non-nil, it will override
  40 the current method.  This method will not be used in mail groups and
  41 the like, only in \"real\" newsgroups.
  42
  43 The value must be a valid method as discussed in the documentation of
  44 `gnus-select-method'.  It can also be a list of methods.  If that is
  45 the case, the user will be queried for what select method to use when
  46 posting.")
  47
  48 (defvar gnus-outgoing-message-group nil
  49   "*All outgoing messages will be put in this group.
  50 If you want to store all your outgoing mail and articles in the group
  51 \"nnml:archive\", you set this variable to that value. This variable
  52 can also be a list of group names.
  53
  54 If you want to have greater control over what group to put each
  55 message in, you can set this variable to a function that checks the
  56 current newsgroup name and then returns a suitable group name (or list
  57 of names).")
  58
  59 (defvar gnus-mailing-list-groups nil
  60   "*Regexp matching groups that are really mailing lists.
  61 This is useful when you're reading a mailing list that has been
  62 gatewayed to a newsgroup, and you want to followup to an article in
  63 the group.")
  64
  65 (defvar gnus-sent-message-ids-file
  66   (nnheader-concat gnus-directory "Sent-Message-IDs")
  67   "File where Gnus saves a cache of sent message ids.")
  68
  69 (defvar gnus-sent-message-ids-length 1000
  70   "The number of sent Message-IDs to save.")
  71
  72 (defvar gnus-crosspost-complaint
  73   "Hi,
  74
  75 You posted the article below with the following Newsgroups header:
  76
  77 Newsgroups: %s
  78
  79 The %s group, at least, was an inappropriate recipient
  80 of this message.  Please trim your Newsgroups header to exclude this
  81 group before posting in the future.
  82
  83 Thank you.
  84 "
  85   "Format string to be inserted when complaining about crossposts.
  86 The first %s will be replaced by the Newsgroups header;
  87 the second with the current group name.")
  88
  89 ;;; Internal variables.
  90
  91 (defvar gnus-message-buffer "*Mail Gnus*")
  92 (defvar gnus-article-copy nil)
  93 (defvar gnus-last-posting-server nil)
  94
  95 (defconst gnus-bug-message
  96   "Sending a bug report to the Gnus Towers.
  97 ========================================
  98
  99 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 100 be sent to the Gnus Bug Exterminators.
 101
 102 At the bottom of the buffer you'll see lots of variable settings.
 103 Please do not delete those.  They will tell the Bug People what your
 104 environment is, so that it will be easier to locate the bugs.
 105
 106 If you have found a bug that makes Emacs go \"beep\", set
 107 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 108 and include the backtrace in your bug report.
 109
 110 Please describe the bug in annoying, painstaking detail.
 111
 112 Thank you for your help in stamping out bugs.
 113 ")
 114
 115 (eval-and-compile
 116   (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 117   (autoload 'news-setup "rnewspost")
 118   (autoload 'news-reply-mode "rnewspost")
 119   (autoload 'rmail-dont-reply-to "mail-utils")
 120   (autoload 'rmail-output "rmailout"))
 121
 122 \f
 123 ;;;
 124 ;;; Gnus Posting Functions
 125 ;;;
 126
 127 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 128   "p" gnus-summary-post-news
 129   "f" gnus-summary-followup
 130   "F" gnus-summary-followup-with-original
 131   "c" gnus-summary-cancel-article
 132   "s" gnus-summary-supersede-article
 133   "r" gnus-summary-reply
 134   "R" gnus-summary-reply-with-original
 135   "m" gnus-summary-mail-other-window
 136   "u" gnus-uu-post-news
 137   "\M-c" gnus-summary-mail-crosspost-complaint
 138   "om" gnus-summary-mail-forward
 139   "op" gnus-summary-post-forward
 140   "Om" gnus-uu-digest-mail-forward
 141   "Op" gnus-uu-digest-post-forward)
 142
 143 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 144   "b" gnus-summary-resend-bounced-mail
 145   ;; "c" gnus-summary-send-draft
 146   "r" gnus-summary-resend-message)
 147
 148 ;;; Internal functions.
 149
 150 (defvar gnus-article-reply nil)
 151 (defmacro gnus-setup-message (config &rest forms)
 152   (let ((winconf (make-symbol "winconf"))
 153         (buffer (make-symbol "buffer"))
 154         (article (make-symbol "article")))
 155     `(let ((,winconf (current-window-configuration))
 156            (,buffer (current-buffer))
 157            (,article (and gnus-article-reply (gnus-summary-article-number)))
 158            (message-header-setup-hook
 159             (copy-sequence message-header-setup-hook)))
 160        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 161        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 162        ,@forms
 163        (gnus-inews-add-send-actions ,winconf ,buffer ,article)
 164        (setq gnus-message-buffer (current-buffer))
 165        (make-local-variable 'gnus-newsgroup-name)
 166        (gnus-configure-windows ,config t))))
 167
 168 (defun gnus-inews-add-send-actions (winconf buffer article)
 169   (gnus-make-local-hook 'message-sent-hook)
 170   (gnus-add-hook 'message-sent-hook 'gnus-inews-do-gcc nil t)
 171   (setq message-post-method
 172         `(lambda (arg)
 173            (gnus-post-method arg ,gnus-newsgroup-name)))
 174   (setq message-newsreader (setq message-mailer (gnus-extended-version)))
 175   (message-add-action
 176    `(set-window-configuration ,winconf) 'exit 'postpone 'kill)
 177   (message-add-action
 178    `(when (buffer-name ,buffer)
 179       (save-excursion
 180         (set-buffer ,buffer)
 181         ,(when article
 182            `(gnus-summary-mark-article-as-replied ,article))))
 183    'send))
 184
 185 (put 'gnus-setup-message 'lisp-indent-function 1)
 186 (put 'gnus-setup-message 'lisp-indent-hook 1)
 187 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 188
 189 ;;; Post news commands of Gnus group mode and summary mode
 190
 191 (defun gnus-group-mail ()
 192   "Start composing a mail."
 193   (interactive)
 194   (gnus-setup-message 'message
 195     (message-mail)))
 196
 197 (defun gnus-group-post-news (&optional arg)
 198   "Start composing a news message.
 199 If ARG, post to the group under point.
 200 If ARG is 1, prompt for a group name."
 201   (interactive "P")
 202   ;; Bind this variable here to make message mode hooks
 203   ;; work ok.
 204   (let ((gnus-newsgroup-name
 205          (if arg
 206              (if (= 1 (prefix-numeric-value arg))
 207                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 208                                   (gnus-read-active-file-p))
 209                (gnus-group-group-name))
 210            "")))
 211     (gnus-post-news 'post gnus-newsgroup-name)))
 212
 213 (defun gnus-summary-post-news ()
 214   "Start composing a news message."
 215   (interactive)
 216   (gnus-set-global-variables)
 217   (gnus-post-news 'post gnus-newsgroup-name))
 218
 219 (defun gnus-summary-followup (yank &optional force-news)
 220   "Compose a followup to an article.
 221 If prefix argument YANK is non-nil, original article is yanked automatically."
 222   (interactive
 223    (list (and current-prefix-arg
 224               (gnus-summary-work-articles 1))))
 225   (gnus-set-global-variables)
 226   (when yank
 227     (gnus-summary-goto-subject (car yank)))
 228   (save-window-excursion
 229     (gnus-summary-select-article))
 230   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 231         (gnus-newsgroup-name gnus-newsgroup-name))
 232     ;; Send a followup.
 233     (gnus-post-news nil gnus-newsgroup-name
 234                     headers gnus-article-buffer
 235                     yank nil force-news)))
 236
 237 (defun gnus-summary-followup-with-original (n &optional force-news)
 238   "Compose a followup to an article and include the original article."
 239   (interactive "P")
 240   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 241
 242 (defun gnus-inews-yank-articles (articles)
 243   (let (beg article)
 244     (while (setq article (pop articles))
 245       (save-window-excursion
 246         (set-buffer gnus-summary-buffer)
 247         (gnus-summary-select-article nil nil nil article)
 248         (gnus-summary-remove-process-mark article))
 249       (gnus-copy-article-buffer)
 250       (let ((message-reply-buffer gnus-article-copy)
 251             (message-reply-headers gnus-current-headers))
 252         (message-yank-original)
 253         (setq beg (or beg (mark t))))
 254       (when articles (insert "\n")))
 255
 256     (push-mark)
 257     (goto-char beg)))
 258
 259 (defun gnus-summary-cancel-article (n)
 260   "Cancel an article you posted."
 261   (interactive "P")
 262   (gnus-set-global-variables)
 263   (let ((articles (gnus-summary-work-articles n))
 264         (message-post-method
 265          `(lambda (arg)
 266             (gnus-post-method nil ,gnus-newsgroup-name)))
 267         article)
 268     (while (setq article (pop articles))
 269       (when (gnus-summary-select-article t nil nil article)
 270         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 271                 (message-cancel-news))
 272           (gnus-summary-mark-as-read article gnus-canceled-mark)
 273           (gnus-cache-remove-article 1))
 274         (gnus-article-hide-headers-if-wanted))
 275       (gnus-summary-remove-process-mark article))))
 276
 277 (defun gnus-summary-supersede-article ()
 278   "Compose an article that will supersede a previous article.
 279 This is done simply by taking the old article and adding a Supersedes
 280 header line with the old Message-ID."
 281   (interactive)
 282   (gnus-set-global-variables)
 283   (let ((article (gnus-summary-article-number)))
 284     (gnus-setup-message 'reply-yank
 285       (gnus-summary-select-article t)
 286       (set-buffer gnus-original-article-buffer)
 287       (message-supersede)
 288       (push
 289        `((lambda ()
 290            (gnus-cache-possibly-remove-article ,article nil nil nil t)))
 291        message-send-actions))))
 292
 293 \f
 294
 295 (defun gnus-copy-article-buffer (&optional article-buffer)
 296   ;; make a copy of the article buffer with all text properties removed
 297   ;; this copy is in the buffer gnus-article-copy.
 298   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 299   ;; this buffer should be passed to all mail/news reply/post routines.
 300   (setq gnus-article-copy (get-buffer-create " *gnus article copy*"))
 301   (buffer-disable-undo gnus-article-copy)
 302   (or (memq gnus-article-copy gnus-buffer-list)
 303       (setq gnus-buffer-list (cons gnus-article-copy gnus-buffer-list)))
 304   (let ((article-buffer (or article-buffer gnus-article-buffer))
 305         end beg contents)
 306     (when (and (get-buffer article-buffer)
 307                (buffer-name (get-buffer article-buffer)))
 308       (save-excursion
 309         (set-buffer article-buffer)
 310         (save-restriction
 311           ;; Copy over the (displayed) article buffer, delete
 312           ;; hidden text and remove text properties.
 313           (widen)
 314           (copy-to-buffer gnus-article-copy (point-min) (point-max))
 315           (set-buffer gnus-article-copy)
 316           (article-delete-text-of-type 'annotation)
 317           (insert
 318            (prog1
 319                (format "%s" (buffer-string))
 320              (erase-buffer)))
 321           ;; Find the original headers.
 322           (set-buffer gnus-original-article-buffer)
 323           (goto-char (point-min))
 324           (while (looking-at message-unix-mail-delimiter)
 325             (forward-line 1))
 326           (setq beg (point))
 327           (setq end (or (search-forward "\n\n" nil t) (point)))
 328           ;; Delete the headers from the displayed articles.
 329           (set-buffer gnus-article-copy)
 330           (delete-region (goto-char (point-min))
 331                          (or (search-forward "\n\n" nil t) (point)))
 332           ;; Insert the original article headers.
 333           (insert-buffer-substring gnus-original-article-buffer beg end)))
 334       gnus-article-copy)))
 335
 336 (defun gnus-post-news (post &optional group header article-buffer yank subject
 337                             force-news)
 338   (when article-buffer
 339     (gnus-copy-article-buffer))
 340   (let ((gnus-article-reply article-buffer))
 341     (gnus-setup-message (cond (yank 'reply-yank)
 342                               (article-buffer 'reply)
 343                               (t 'message))
 344       (let* ((group (or group gnus-newsgroup-name))
 345              (pgroup group)
 346              to-address to-group mailing-list to-list)
 347         (when group
 348           (setq to-address (gnus-group-find-parameter group 'to-address)
 349                 to-group (gnus-group-find-parameter group 'to-group)
 350                 to-list (gnus-group-find-parameter group 'to-list)
 351                 mailing-list (when gnus-mailing-list-groups
 352                                (string-match gnus-mailing-list-groups group))
 353                 group (gnus-group-real-name group)))
 354         (if (or (and to-group
 355                      (gnus-news-group-p to-group))
 356                 force-news
 357                 (and (gnus-news-group-p
 358                       (or pgroup gnus-newsgroup-name)
 359                       (if header (mail-header-number header)
 360                         gnus-current-article))
 361                      (not mailing-list)
 362                      (not to-list)
 363                      (not to-address)))
 364             ;; This is news.
 365             (if post
 366                 (message-news (or to-group group))
 367               (set-buffer gnus-article-copy)
 368               (message-followup to-group))
 369           ;; The is mail.
 370           (if post
 371               (progn
 372                 (message-mail (or to-address to-list))
 373                 ;; Arrange for mail groups that have no `to-address' to
 374                 ;; get that when the user sends off the mail.
 375                 (push (list 'gnus-inews-add-to-address group)
 376                       message-send-actions))
 377             (set-buffer gnus-article-copy)
 378             (message-wide-reply to-address)))
 379         (when yank
 380           (gnus-inews-yank-articles yank))))))
 381
 382 (defun gnus-post-method (arg group &optional silent)
 383   "Return the posting method based on GROUP and ARG.
 384 If SILENT, don't prompt the user."
 385   (let ((group-method (gnus-find-method-for-group group)))
 386     (cond
 387      ;; If the group-method is nil (which shouldn't happen) we use
 388      ;; the default method.
 389      ((null group-method)
 390       (or gnus-post-method gnus-select-method message-post-method))
 391      ;; We want this group's method.
 392      ((and arg (not (eq arg 0)))
 393       group-method)
 394      ;; We query the user for a post method.
 395      ((or arg
 396           (and gnus-post-method
 397                (listp (car gnus-post-method))))
 398       (let* ((methods
 399               ;; Collect all methods we know about.
 400               (append
 401                (when gnus-post-method
 402                  (if (listp (car gnus-post-method))
 403                      gnus-post-method
 404                    (list gnus-post-method)))
 405                gnus-secondary-select-methods
 406                (list gnus-select-method)
 407                (list group-method)))
 408              method-alist post-methods method)
 409         ;; Weed out all mail methods.
 410         (while methods
 411           (setq method (gnus-server-get-method "" (pop methods)))
 412           (when (or (gnus-method-option-p method 'post)
 413                     (gnus-method-option-p method 'post-mail))
 414             (push method post-methods)))
 415         ;; Create a name-method alist.
 416         (setq method-alist
 417               (mapcar
 418                (lambda (m)
 419                  (list (concat (cadr m) " (" (symbol-name (car m)) ")") m))
 420                post-methods))
 421         ;; Query the user.
 422         (cadr
 423          (assoc
 424           (setq gnus-last-posting-server
 425                 (if (and silent
 426                          gnus-last-posting-server)
 427                     ;; Just use the last value.
 428                     gnus-last-posting-server
 429                   (completing-read
 430                    "Posting method: " method-alist nil t
 431                    (cons (or gnus-last-posting-server "") 0))))
 432           method-alist))))
 433      ;; Override normal method.
 434      ((and gnus-post-method
 435            (or (gnus-method-option-p group-method 'post)
 436                (gnus-method-option-p group-method 'post-mail)))
 437       gnus-post-method)
 438      ;; Perhaps this is a mail group?
 439      ((and (not (gnus-member-of-valid 'post group))
 440            (not (gnus-method-option-p group-method 'post-mail)))
 441       group-method)
 442      ;; Use the normal select method.
 443      (t gnus-select-method))))
 444
 445 (defun gnus-inews-narrow-to-headers ()
 446   (widen)
 447   (narrow-to-region
 448    (goto-char (point-min))
 449    (or (and (re-search-forward
 450              (concat "^" (regexp-quote mail-header-separator) "$") nil t)
 451             (match-beginning 0))
 452        (point-max)))
 453   (goto-char (point-min)))
 454
 455 ;;;
 456 ;;; Check whether the message has been sent already.
 457 ;;;
 458
 459 (defvar gnus-inews-sent-ids nil)
 460
 461 (defun gnus-inews-reject-message ()
 462   "Check whether this message has already been sent."
 463   (when gnus-sent-message-ids-file
 464     (let ((message-id (save-restriction (gnus-inews-narrow-to-headers)
 465                                         (mail-fetch-field "message-id")))
 466           end)
 467       (when message-id
 468         (unless gnus-inews-sent-ids
 469           (condition-case ()
 470               (load  t t t)
 471             (error nil)))
 472         (if (member message-id gnus-inews-sent-ids)
 473             ;; Reject this message.
 474             (not (gnus-yes-or-no-p
 475                   (format "Message %s already sent.  Send anyway? "
 476                           message-id)))
 477           (push message-id gnus-inews-sent-ids)
 478           ;; Chop off the last Message-IDs.
 479           (when (setq end (nthcdr gnus-sent-message-ids-length
 480                                   gnus-inews-sent-ids))
 481             (setcdr end nil))
 482           (nnheader-temp-write gnus-sent-message-ids-file
 483             (gnus-prin1 `(setq gnus-inews-sent-ids ',gnus-inews-sent-ids)))
 484           nil)))))
 485
 486 \f
 487
 488 ;; Dummy to avoid byte-compile warning.
 489 (defvar nnspool-rejected-article-hook)
 490
 491 ;;; Since the X-Newsreader/X-Mailer are ``vanity'' headers, they might
 492 ;;; as well include the Emacs version as well.
 493 ;;; The following function works with later GNU Emacs, and XEmacs.
 494 (defun gnus-extended-version ()
 495   "Stringified Gnus version and Emacs version"
 496   (interactive)
 497   (concat
 498    gnus-version
 499    "/"
 500    (cond
 501     ((string-match "^\\([0-9]+\\.[0-9]+\\)\\.[.0-9]+$" emacs-version)
 502      (concat "Emacs " (substring emacs-version
 503                                  (match-beginning 1)
 504                                  (match-end 1))))
 505     ((string-match "\\([A-Z]*[Mm][Aa][Cc][Ss]\\)" emacs-version)
 506      (concat (substring emacs-version
 507                         (match-beginning 1)
 508                         (match-end 1))
 509              (format " %d.%d" emacs-major-version emacs-minor-version)))
 510     (t emacs-version))))
 511
 512 ;; Written by "Mr. Per Persson" <pp@gnu.ai.mit.edu>.
 513 (defun gnus-inews-insert-mime-headers ()
 514   (goto-char (point-min))
 515   (let ((mail-header-separator
 516          (progn
 517            (goto-char (point-min))
 518            (if (and (search-forward (concat "\n" mail-header-separator "\n")
 519                                     nil t)
 520                     (not (search-backward "\n\n" nil t)))
 521                mail-header-separator
 522              ""))))
 523     (or (mail-position-on-field "Mime-Version")
 524         (insert "1.0")
 525         (cond ((save-restriction
 526                  (widen)
 527                  (goto-char (point-min))
 528                  (re-search-forward "[\200-\377]" nil t))
 529                (or (mail-position-on-field "Content-Type")
 530                    (insert "text/plain; charset=ISO-8859-1"))
 531                (or (mail-position-on-field "Content-Transfer-Encoding")
 532                    (insert "8bit")))
 533               (t (or (mail-position-on-field "Content-Type")
 534                      (insert "text/plain; charset=US-ASCII"))
 535                  (or (mail-position-on-field "Content-Transfer-Encoding")
 536                      (insert "7bit")))))))
 537
 538 \f
 539 ;;;
 540 ;;; Gnus Mail Functions
 541 ;;;
 542
 543 ;;; Mail reply commands of Gnus summary mode
 544
 545 (defun gnus-summary-reply (&optional yank)
 546   "Reply mail to news author.
 547 If prefix argument YANK is non-nil, original article is yanked automatically."
 548   (interactive
 549    (list (and current-prefix-arg
 550               (gnus-summary-work-articles 1))))
 551   ;; Bug fix by jbw@bigbird.bu.edu (Joe Wells)
 552   ;; Stripping headers should be specified with mail-yank-ignored-headers.
 553   (gnus-set-global-variables)
 554   (when yank
 555     (gnus-summary-goto-subject (car yank)))
 556   (let ((gnus-article-reply t))
 557     (gnus-setup-message (if yank 'reply-yank 'reply)
 558       (gnus-summary-select-article)
 559       (set-buffer (gnus-copy-article-buffer))
 560       (message-reply nil nil (gnus-group-find-parameter
 561                               gnus-newsgroup-name 'broken-reply-to))
 562       (when yank
 563         (gnus-inews-yank-articles yank)))))
 564
 565 (defun gnus-summary-reply-with-original (n)
 566   "Reply mail to news author with original article."
 567   (interactive "P")
 568   (gnus-summary-reply (gnus-summary-work-articles n)))
 569
 570 (defun gnus-summary-mail-forward (&optional post)
 571   "Forward the current message to another user."
 572   (interactive "P")
 573   (gnus-set-global-variables)
 574   (gnus-setup-message 'forward
 575     (gnus-summary-select-article)
 576     (set-buffer gnus-original-article-buffer)
 577     (message-forward post)))
 578
 579 (defun gnus-summary-resend-message (address)
 580   "Resend the current article to ADDRESS."
 581   (interactive "sResend message to: ")
 582   (gnus-summary-select-article)
 583   (save-excursion
 584     (set-buffer gnus-original-article-buffer)
 585     (message-resend address)))
 586
 587 (defun gnus-summary-post-forward ()
 588   "Forward the current article to a newsgroup."
 589   (interactive)
 590   (gnus-summary-mail-forward t))
 591
 592 (defvar gnus-nastygram-message
 593   "The following article was inappropriately posted to %s.\n"
 594   "Format string to insert in nastygrams.
 595 The current group name will be inserted at \"%s\".")
 596
 597 (defun gnus-summary-mail-nastygram (n)
 598   "Send a nastygram to the author of the current article."
 599   (interactive "P")
 600   (if (or gnus-expert-user
 601           (gnus-y-or-n-p
 602            "Really send a nastygram to the author of the current article? "))
 603       (let ((group gnus-newsgroup-name))
 604         (gnus-summary-reply-with-original n)
 605         (set-buffer gnus-message-buffer)
 606         (insert (format gnus-nastygram-message group))
 607         (message-send-and-exit))))
 608
 609 (defun gnus-summary-mail-crosspost-complaint (n)
 610   "Send a complaint about crossposting to the current article(s)."
 611   (interactive "P")
 612   (let ((articles (gnus-summary-work-articles n))
 613         article)
 614     (while (setq article (pop articles))
 615       (set-buffer gnus-summary-buffer)
 616       (gnus-summary-goto-subject article)
 617       (let ((group (gnus-group-real-name gnus-newsgroup-name))
 618             newsgroups followup-to)
 619         (gnus-summary-select-article)
 620         (set-buffer gnus-original-article-buffer)
 621         (if (and (<= (length (message-tokenize-header
 622                               (setq newsgroups (mail-fetch-field "newsgroups"))
 623                               ", "))
 624                      1)
 625                  (or (not (setq followup-to (mail-fetch-field "followup-to")))
 626                      (not (member group (message-tokenize-header
 627                                          followup-to ", ")))))
 628             (if followup-to
 629                 (gnus-message 1 "Followup-to restricted")
 630               (gnus-message 1 "Not a crossposted article"))
 631           (set-buffer gnus-summary-buffer)
 632           (gnus-summary-reply-with-original 1)
 633           (set-buffer gnus-message-buffer)
 634           (insert (format gnus-crosspost-complaint newsgroups group))
 635           (when (gnus-y-or-n-p "Send this complaint? ")
 636             (message-send-and-exit)))))))
 637
 638 (defun gnus-summary-mail-other-window ()
 639   "Compose mail in other window."
 640   (interactive)
 641   (gnus-setup-message 'message
 642     (message-mail)))
 643
 644 (defun gnus-mail-parse-comma-list ()
 645   (let (accumulated
 646         beg)
 647     (skip-chars-forward " ")
 648     (while (not (eobp))
 649       (setq beg (point))
 650       (skip-chars-forward "^,")
 651       (while (zerop
 652               (save-excursion
 653                 (save-restriction
 654                   (let ((i 0))
 655                     (narrow-to-region beg (point))
 656                     (goto-char beg)
 657                     (logand (progn
 658                               (while (search-forward "\"" nil t)
 659                                 (incf i))
 660                               (if (zerop i) 2 i)) 2)))))
 661         (skip-chars-forward ",")
 662         (skip-chars-forward "^,"))
 663       (skip-chars-backward " ")
 664       (setq accumulated
 665             (cons (buffer-substring beg (point))
 666                   accumulated))
 667       (skip-chars-forward "^,")
 668       (skip-chars-forward ", "))
 669     accumulated))
 670
 671 (defun gnus-mail-yank-original ()
 672   (interactive)
 673   (save-excursion
 674     (mail-yank-original nil))
 675   (or mail-yank-hooks mail-citation-hook
 676       (run-hooks 'news-reply-header-hook)))
 677
 678 (defun gnus-inews-add-to-address (group)
 679   (let ((to-address (mail-fetch-field "to")))
 680     (when (and to-address
 681                (gnus-alive-p))
 682       ;; This mail group doesn't have a `to-list', so we add one
 683       ;; here.  Magic!
 684       (gnus-group-add-parameter group (cons 'to-list to-address)))))
 685
 686 (defun gnus-put-message ()
 687   "Put the current message in some group and return to Gnus."
 688   (interactive)
 689   (let ((reply gnus-article-reply)
 690         (winconf gnus-prev-winconf)
 691         (group gnus-newsgroup-name))
 692
 693     (or (and group (not (gnus-group-read-only-p group)))
 694         (setq group (read-string "Put in group: " nil
 695                                  (gnus-writable-groups))))
 696     (and (gnus-gethash group gnus-newsrc-hashtb)
 697          (error "No such group: %s" group))
 698
 699     (save-excursion
 700       (save-restriction
 701         (widen)
 702         (gnus-inews-narrow-to-headers)
 703         (let (gnus-deletable-headers)
 704           (if (message-news-p)
 705               (message-generate-headers message-required-news-headers)
 706             (message-generate-headers message-required-mail-headers)))
 707         (goto-char (point-max))
 708         (insert "Gcc: " group "\n")
 709         (widen)))
 710
 711     (gnus-inews-do-gcc)
 712
 713     (if (get-buffer gnus-group-buffer)
 714         (progn
 715           (if (gnus-buffer-exists-p (car-safe reply))
 716               (progn
 717                 (set-buffer (car reply))
 718                 (and (cdr reply)
 719                      (gnus-summary-mark-article-as-replied
 720                       (cdr reply)))))
 721           (and winconf (set-window-configuration winconf))))))
 722
 723 (defun gnus-article-mail (yank)
 724   "Send a reply to the address near point.
 725 If YANK is non-nil, include the original article."
 726   (interactive "P")
 727   (let ((address
 728          (buffer-substring
 729           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
 730           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
 731     (when address
 732       (message-reply address)
 733       (when yank
 734         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
 735
 736 (defun gnus-bug ()
 737   "Send a bug report to the Gnus maintainers."
 738   (interactive)
 739   (unless (gnus-alive-p)
 740     (error "Gnus has been shut down"))
 741   (gnus-setup-message 'bug
 742     (delete-other-windows)
 743     (switch-to-buffer "*Gnus Help Bug*")
 744     (erase-buffer)
 745     (insert gnus-bug-message)
 746     (goto-char (point-min))
 747     (message-pop-to-buffer "*Gnus Bug*")
 748     (message-setup `((To . ,gnus-maintainer) (Subject . "")))
 749     (push `(gnus-bug-kill-buffer) message-send-actions)
 750     (goto-char (point-min))
 751     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
 752     (forward-line 1)
 753     (insert (gnus-version) "\n")
 754     (insert (emacs-version))
 755     (insert "\n\n\n\n\n")
 756     (gnus-debug)
 757     (goto-char (point-min))
 758     (search-forward "Subject: " nil t)
 759     (message "")))
 760
 761 (defun gnus-bug-kill-buffer ()
 762   (and (get-buffer "*Gnus Help Bug*")
 763        (kill-buffer "*Gnus Help Bug*")))
 764
 765 (defun gnus-debug ()
 766   "Attemps to go through the Gnus source file and report what variables have been changed.
 767 The source file has to be in the Emacs load path."
 768   (interactive)
 769   (let ((files '("gnus-load.el" "gnus-sum.el" "gnus-group.el"
 770                  "gnus-art.el" "gnus-start.el"
 771                  "gnus-msg.el" "gnus-score.el" "gnus-win.el"
 772                  "nnmail.el" "message.el"))
 773         file expr olist sym)
 774     (gnus-message 4 "Please wait while we snoop your variables...")
 775     (sit-for 0)
 776     ;; Go through all the files looking for non-default values for variables.
 777     (save-excursion
 778       (set-buffer (get-buffer-create " *gnus bug info*"))
 779       (buffer-disable-undo (current-buffer))
 780       (while files
 781         (erase-buffer)
 782         (when (file-exists-p (setq file (locate-library (pop files))))
 783           (insert-file-contents file)
 784           (goto-char (point-min))
 785           (if (not (re-search-forward "^;;* *Internal variables" nil t))
 786               (gnus-message 4 "Malformed sources in file %s" file)
 787             (narrow-to-region (point-min) (point))
 788             (goto-char (point-min))
 789             (while (setq expr (condition-case ()
 790                                   (read (current-buffer)) (error nil)))
 791               (condition-case ()
 792                   (and (eq (car expr) 'defvar)
 793                        (stringp (nth 3 expr))
 794                        (or (not (boundp (nth 1 expr)))
 795                            (not (equal (eval (nth 2 expr))
 796                                        (symbol-value (nth 1 expr)))))
 797                        (push (nth 1 expr) olist))
 798                 (error nil))))))
 799       (kill-buffer (current-buffer)))
 800     (when (setq olist (nreverse olist))
 801       (insert "------------------ Environment follows ------------------\n\n"))
 802     (while olist
 803       (if (boundp (car olist))
 804           (condition-case ()
 805               (pp `(setq ,(car olist)
 806                          ,(if (or (consp (setq sym (symbol-value (car olist))))
 807                                   (and (symbolp sym)
 808                                        (not (or (eq sym nil)
 809                                                 (eq sym t)))))
 810                               (list 'quote (symbol-value (car olist)))
 811                             (symbol-value (car olist))))
 812                   (current-buffer))
 813             (error
 814              (format "(setq %s 'whatever)\n" (car olist))))
 815         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
 816       (setq olist (cdr olist)))
 817     (insert "\n\n")
 818     ;; Remove any null chars - they seem to cause trouble for some
 819     ;; mailers. (Byte-compiled output from the stuff above.)
 820     (goto-char (point-min))
 821     (while (re-search-forward "[\000\200]" nil t)
 822       (replace-match "" t t))))
 823
 824 ;;; Treatment of rejected articles.
 825 ;;; Bounced mail.
 826
 827 (defun gnus-summary-resend-bounced-mail (&optional fetch)
 828   "Re-mail the current message.
 829 This only makes sense if the current message is a bounce message than
 830 contains some mail you have written which has been bounced back to
 831 you.
 832 If FETCH, try to fetch the article that this is a reply to, if indeed
 833 this is a reply."
 834   (interactive "P")
 835   (gnus-summary-select-article t)
 836   (set-buffer gnus-original-article-buffer)
 837   (gnus-setup-message 'compose-bounce
 838     (let* ((references (mail-fetch-field "references"))
 839            (parent (and references (gnus-parent-id references))))
 840       (message-bounce)
 841       ;; If there are references, we fetch the article we answered to.
 842       (and fetch parent
 843            (gnus-summary-refer-article parent)
 844            (gnus-summary-show-all-headers)))))
 845
 846 ;;; Gcc handling.
 847
 848 ;; Do Gcc handling, which copied the message over to some group.
 849 (defun gnus-inews-do-gcc (&optional gcc)
 850   (when (gnus-alive-p)
 851     (save-excursion
 852       (save-restriction
 853         (message-narrow-to-headers)
 854         (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
 855               (cur (current-buffer))
 856               groups group method)
 857           (when gcc
 858             (message-remove-header "gcc")
 859             (widen)
 860             (setq groups (message-tokenize-header gcc " ,"))
 861             ;; Copy the article over to some group(s).
 862             (while (setq group (pop groups))
 863               (gnus-check-server
 864                (setq method
 865                      (cond ((and (null (gnus-get-info group))
 866                                  (eq (car gnus-message-archive-method)
 867                                      (car
 868                                       (gnus-server-to-method
 869                                        (gnus-group-method group)))))
 870                             ;; If the group doesn't exist, we assume
 871                             ;; it's an archive group...
 872                             gnus-message-archive-method)
 873                            ;; Use the method.
 874                            ((gnus-info-method (gnus-get-info group))
 875                             (gnus-info-method (gnus-get-info group)))
 876                            ;; Find the method.
 877                            (t (gnus-group-method group)))))
 878               (gnus-check-server method)
 879               (unless (gnus-request-group group t method)
 880                 (gnus-request-create-group group method))
 881               (save-excursion
 882                 (nnheader-set-temp-buffer " *acc*")
 883                 (insert-buffer-substring cur)
 884                 (goto-char (point-min))
 885                 (when (re-search-forward
 886                        (concat "^" (regexp-quote mail-header-separator) "$")
 887                        nil t)
 888                   (replace-match "" t t ))
 889                 (unless (gnus-request-accept-article group method t)
 890                   (gnus-message 1 "Couldn't store article in group %s: %s"
 891                                 group (gnus-status-message method))
 892                   (sit-for 2))
 893                 (kill-buffer (current-buffer))))))))))
 894
 895 (defun gnus-inews-insert-gcc ()
 896   "Insert Gcc headers based on `gnus-outgoing-message-group'."
 897   (save-excursion
 898     (save-restriction
 899       (gnus-inews-narrow-to-headers)
 900       (let* ((group gnus-outgoing-message-group)
 901              (gcc (cond
 902                    ((gnus-functionp group)
 903                     (funcall group))
 904                    ((or (stringp group) (list group))
 905                     group))))
 906         (when gcc
 907           (insert "Gcc: "
 908                   (if (stringp gcc) gcc
 909                     (mapconcat 'identity gcc " "))
 910                   "\n"))))))
 911
 912 (defun gnus-inews-insert-archive-gcc (&optional group)
 913   "Insert the Gcc to say where the article is to be archived."
 914   (let* ((var gnus-message-archive-group)
 915          (group (or group gnus-newsgroup-name ""))
 916          result
 917          gcc-self-val
 918          (groups
 919           (cond
 920            ((null gnus-message-archive-method)
 921             ;; Ignore.
 922             nil)
 923            ((stringp var)
 924             ;; Just a single group.
 925             (list var))
 926            ((null var)
 927             ;; We don't want this.
 928             nil)
 929            ((and (listp var) (stringp (car var)))
 930             ;; A list of groups.
 931             var)
 932            ((gnus-functionp var)
 933             ;; A function.
 934             (funcall var group))
 935            (t
 936             ;; An alist of regexps/functions/forms.
 937             (while (and var
 938                         (not
 939                          (setq result
 940                                (cond
 941                                 ((stringp (caar var))
 942                                  ;; Regexp.
 943                                  (when (string-match (caar var) group)
 944                                    (cdar var)))
 945                                 ((gnus-functionp (car var))
 946                                  ;; Function.
 947                                  (funcall (car var) group))
 948                                 (t
 949                                  (eval (car var)))))))
 950               (setq var (cdr var)))
 951             result)))
 952          name)
 953     (when groups
 954       (when (stringp groups)
 955         (setq groups (list groups)))
 956       (save-excursion
 957         (save-restriction
 958           (gnus-inews-narrow-to-headers)
 959           (goto-char (point-max))
 960           (insert "Gcc: ")
 961           (if (and gnus-newsgroup-name
 962                    (setq gcc-self-val
 963                          (gnus-group-find-parameter
 964                           gnus-newsgroup-name 'gcc-self)))
 965               (progn
 966                 (insert
 967                  (if (stringp gcc-self-val)
 968                      gcc-self-val
 969                    group))
 970                 (if (not (eq gcc-self-val 'none))
 971                     (insert "\n")
 972                   (progn
 973                     (beginning-of-line)
 974                     (kill-line))))
 975             (while (setq name (pop groups))
 976               (insert (if (string-match ":" name)
 977                           name
 978                         (gnus-group-prefixed-name
 979                          name gnus-message-archive-method)))
 980               (if groups (insert " ")))
 981             (insert "\n")))))))
 982
 983 (defun gnus-summary-send-draft ()
 984   "Enter a mail/post buffer to edit and send the draft."
 985   (interactive)
 986   (gnus-set-global-variables)
 987   (let (buf)
 988     (if (not (setq buf (gnus-request-restore-buffer
 989                         (gnus-summary-article-number) gnus-newsgroup-name)))
 990         (error "Couldn't restore the article")
 991       (switch-to-buffer buf)
 992       (when (eq major-mode 'news-reply-mode)
 993         (local-set-key "\C-c\C-c" 'gnus-inews-news))
 994       ;; Insert the separator.
 995       (goto-char (point-min))
 996       (search-forward "\n\n")
 997       (forward-char -1)
 998       (insert mail-header-separator)
 999       ;; Configure windows.
1000       (let ((gnus-draft-buffer (current-buffer)))
1001         (gnus-configure-windows 'draft t)
1002         (goto-char (point))))))
1003
1004 (gnus-add-shutdown 'gnus-inews-close 'gnus)
1005
1006 (defun gnus-inews-close ()
1007   (setq gnus-inews-sent-ids nil))
1008
1009 ;;; Allow redefinition of functions.
1010
1011 (gnus-ems-redefine)
1012
1013 (provide 'gnus-msg)
1014
1015 ;;; gnus-msg.el ends here