cgit.sxemacs.org Git - gnus/blob - lisp/gnus-mh.el

   1 ;;; gnus-mh.el --- mh-e interface for Gnus
   2 ;; Copyright (C) 1994,95 Free Software Foundation, Inc.
   3
   4 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   5 ;;      Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Send mail using mh-e.
  27
  28 ;; The following mh-e interface is all cooperative works of
  29 ;; tanaka@flab.fujitsu.CO.JP (TANAKA Hiroshi), kawabe@sra.CO.JP
  30 ;; (Yoshikatsu Kawabe), and shingu@casund.cpr.canon.co.jp (Toshiaki
  31 ;; SHINGU).
  32
  33 ;;; Code:
  34
  35 (require 'mh-e)
  36 (require 'mh-comp)
  37 (require 'gnus)
  38 (require 'gnus-msg)
  39
  40 (defun gnus-summary-save-article-folder (arg)
  41   "Append the current article to an mh folder.
  42 If N is a positive number, save the N next articles.
  43 If N is a negative number, save the N previous articles.
  44 If N is nil and any articles have been marked with the process mark,
  45 save those articles instead."
  46   (interactive "P")
  47   (let ((gnus-default-article-saver 'gnus-summary-save-in-folder))
  48     (gnus-summary-save-article arg)))
  49
  50 (defun gnus-summary-save-in-folder (&optional folder)
  51   "Save this article to MH folder (using `rcvstore' in MH library).
  52 Optional argument FOLDER specifies folder name."
  53   ;; Thanks to yuki@flab.Fujitsu.JUNET and ohm@kaba.junet.
  54   (mh-find-path)
  55   (let ((folder
  56          (or folder
  57              (mh-prompt-for-folder
  58               "Save article in"
  59               (funcall gnus-folder-save-name gnus-newsgroup-name
  60                        gnus-current-headers gnus-newsgroup-last-folder)
  61               t)))
  62         (errbuf (get-buffer-create " *Gnus rcvstore*")))
  63     (gnus-eval-in-buffer-window
  64      gnus-article-buffer
  65      (save-restriction
  66        (widen)
  67        (unwind-protect
  68            (call-process-region (point-min) (point-max)
  69                                 (expand-file-name "rcvstore" mh-lib)
  70                                 nil errbuf nil folder)
  71          (set-buffer errbuf)
  72          (if (zerop (buffer-size))
  73              (message "Article saved in folder: %s" folder)
  74            (message "%s" (buffer-string)))
  75          (kill-buffer errbuf))))
  76     (setq gnus-newsgroup-last-folder folder)))
  77
  78 (defun gnus-mail-reply-using-mhe (&optional yank)
  79   "Compose reply mail using mh-e.
  80 Optional argument YANK means yank original article.
  81 The command \\[mh-yank-cur-msg] yank the original message into current buffer."
  82   (let (from cc subject date to reply-to to-userid orig-to
  83              (config (current-window-configuration))
  84              buffer)
  85     (pop-to-buffer gnus-article-buffer)
  86     (setq buffer (current-buffer))
  87     (save-excursion
  88       (save-restriction
  89         (or gnus-user-login-name        ; we need this
  90             (setq gnus-user-login-name (or (getenv "USER")
  91                                            (getenv "LOGNAME"))))
  92
  93         (gnus-article-show-all-headers);; so colors are happy
  94         ;; lots of junk to avoid mh-send deleting other windows
  95         (setq from (or (gnus-fetch-field "from") "")
  96               subject (let ((subject (or (gnus-fetch-field "subject")
  97                                          "(None)")))
  98                         (if (and subject
  99                                  (not (string-match "^[Rr][Ee]:.+$" subject)))
 100                             (concat "Re: " subject) subject))
 101               reply-to (gnus-fetch-field "reply-to")
 102               cc (gnus-fetch-field "cc")
 103               orig-to (or (gnus-fetch-field "to") "")
 104               date (gnus-fetch-field "date"))
 105         (setq to (or reply-to from))
 106         (setq to-userid (mail-strip-quoted-names orig-to))
 107         (if (or (string-match "," orig-to)
 108                 (not (string-match (substring to-userid 0
 109                                               (string-match "@" to-userid))
 110                                    gnus-user-login-name)))
 111             (setq cc (concat (if cc (concat cc ", ") "") orig-to)))
 112         ;; mh-yank-cur-msg needs to have mh-show-buffer set in the
 113         ;; *Article* buffer
 114         (setq mh-show-buffer buffer)))
 115
 116     (mh-find-path)
 117     (mh-send-sub (or to "") (or cc "")
 118                  (or subject "(None)") config);; Erik Selberg 1/23/94
 119
 120     (let ((draft (current-buffer))
 121           (gnus-mail-buffer (current-buffer))
 122           mail-buf)
 123       (if (not yank)
 124           (gnus-configure-windows 'reply)
 125         (gnus-configure-windows 'reply-yank))
 126       (setq mail-buf gnus-mail-buffer)
 127       (pop-to-buffer mail-buf);; always in the display, so won't have window probs
 128       (switch-to-buffer draft))
 129
 130     ;;    (mh-send to (or cc "") subject);; shouldn't use according to mhe
 131
 132     ;; note - current buffer is now draft!
 133     (save-excursion
 134       (mh-insert-fields
 135        "In-reply-to:"
 136        (concat
 137         (substring from 0 (string-match "  *at \\|  *@ \\| *(\\| *<" from))
 138         "'s message of " date)))
 139
 140     ;; need this for mh-yank-cur-msg
 141     (setq mh-sent-from-folder buffer)
 142     (setq mh-sent-from-msg 1)
 143     (setq mh-show-buffer buffer)
 144     (setq mh-previous-window-config config)
 145     )
 146
 147   ;; Then, yank original article if requested.
 148   (if yank
 149       (let ((last (point)))
 150         (mh-yank-cur-msg)
 151         (goto-char last))))
 152
 153 ;; gnus-mail-forward-using-mhe is contributed by Jun-ichiro Itoh
 154 ;; <itojun@ingram.mt.cs.keio.ac.jp>
 155
 156 (defun gnus-mail-forward-using-mhe (&optional buffer)
 157   "Forward the current message to another user using mh-e."
 158   ;; First of all, prepare mhe mail buffer.
 159   (let* ((to (read-string "To: "))
 160          (cc (read-string "Cc: "))
 161          (buffer (or buffer gnus-article-buffer))
 162          (config (current-window-configuration));; need to add this - erik
 163          (subject (gnus-forward-make-subject buffer)))
 164     (setq mh-show-buffer buffer)
 165     (mh-find-path)
 166     (mh-send-sub to (or cc "") (or subject "(None)") config);; Erik Selberg 1/23/94
 167     (let ((draft (current-buffer))
 168           (gnus-mail-buffer (current-buffer))
 169           mail-buf)
 170       (gnus-configure-windows 'reply-yank)
 171       (setq mail-buf (eval (cdr (assq 'mail gnus-window-to-buffer))))
 172       (pop-to-buffer mail-buf);; always in the display, so won't have window probs
 173       (switch-to-buffer draft)
 174       )
 175     (save-excursion
 176       (goto-char (point-max))
 177       (insert "\n------- Forwarded Message\n\n")
 178       (insert-buffer buffer)
 179       (goto-char (point-max))
 180       (insert "\n------- End of Forwarded Message\n")
 181       (setq mh-sent-from-folder buffer)
 182       (setq mh-sent-from-msg 1)
 183       (setq mh-previous-window-config config)
 184       )))
 185
 186 (defun gnus-mail-other-window-using-mhe ()
 187   "Compose mail other window using mh-e."
 188   (let ((to (read-string "To: "))
 189         (cc (read-string "Cc: "))
 190         (subject (read-string "Subject: ")))
 191     (gnus-article-show-all-headers)     ;I don't think this is really needed.
 192     (setq mh-show-buffer (current-buffer))
 193     (mh-find-path)
 194     (mh-send-other-window to cc subject)
 195     (setq mh-sent-from-folder (current-buffer))
 196     (setq mh-sent-from-msg 1)))
 197
 198 (defun gnus-Folder-save-name (newsgroup headers &optional last-folder)
 199   "Generate folder name from NEWSGROUP, HEADERS, and optional LAST-FOLDER.
 200 If variable `gnus-use-long-file-name' is nil, it is +News.group.
 201 Otherwise, it is like +news/group."
 202   (or last-folder
 203       (concat "+"
 204               (if gnus-use-long-file-name
 205                   (gnus-capitalize-newsgroup newsgroup)
 206                 (gnus-newsgroup-directory-form newsgroup)))))
 207
 208 (defun gnus-folder-save-name (newsgroup headers &optional last-folder)
 209   "Generate folder name from NEWSGROUP, HEADERS, and optional LAST-FOLDER.
 210 If variable `gnus-use-long-file-name' is nil, it is +news.group.
 211 Otherwise, it is like +news/group."
 212   (or last-folder
 213       (concat "+"
 214               (if gnus-use-long-file-name
 215                   newsgroup
 216                 (gnus-newsgroup-directory-form newsgroup)))))
 217
 218 ;;; gnus-mh.el ends here