cgit.sxemacs.org Git - gnus/blob - lisp/gnus-html.el

   1 ;;; gnus-html.el --- Quoted-Printable functions
   2
   3 ;; Copyright (C) 2010  Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: html, web
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; The idea is to provide a simple, fast and pretty minimal way to
  26 ;; render HTML (including links and images) in a buffer, based on an
  27 ;; external HTML renderer (i.e., w3m).
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'cl))
  32 (eval-when-compile (require 'mm-decode))
  33 (require 'mm-url)
  34
  35 (defcustom gnus-html-cache-directory (nnheader-concat gnus-directory "html-cache/")
  36   "Where Gnus will cache images it downloads from the web."
  37   :version "24.1"
  38   :group 'gnus-art
  39   :type 'directory)
  40
  41 (defcustom gnus-html-cache-size 500000000
  42   "The size of the Gnus image cache."
  43   :version "24.1"
  44   :group 'gnus-art
  45   :type 'integer)
  46
  47 (defcustom gnus-html-frame-width 70
  48   "What width to use when rendering HTML."
  49   :version "24.1"
  50   :group 'gnus-art
  51   :type 'integer)
  52
  53 (defcustom gnus-blocked-images "."
  54   "Images that have URLs matching this regexp will be blocked."
  55   :version "24.1"
  56   :group 'gnus-art
  57   :type 'regexp)
  58
  59 (defcustom gnus-max-image-proportion 0.7
  60   "How big pictures displayed are in relation to the window they're in.
  61 A value of 0.7 means that they are allowed to take up 70% of the
  62 width and height of the window.  If they are larger than this,
  63 and Emacs supports it, then the images will be rescaled down to
  64 fit these criteria."
  65   :version "24.1"
  66   :group 'gnus-art
  67   :type 'float)
  68
  69 ;;;###autoload
  70 (defun gnus-article-html (handle)
  71   (let ((article-buffer (current-buffer)))
  72     (save-restriction
  73       (narrow-to-region (point) (point))
  74       (save-excursion
  75         (mm-with-part handle
  76           (let* ((coding-system-for-read 'utf-8)
  77                  (coding-system-for-write 'utf-8)
  78                  (default-process-coding-system
  79                    (cons coding-system-for-read coding-system-for-write))
  80                  (charset (mail-content-type-get (mm-handle-type handle)
  81                                                  'charset)))
  82             (when (and charset
  83                        (setq charset (mm-charset-to-coding-system charset))
  84                        (not (eq charset 'ascii)))
  85               (mm-decode-coding-region (point-min) (point-max) charset))
  86             (call-process-region (point-min) (point-max)
  87                                  "w3m"
  88                                  nil article-buffer nil
  89                                  "-halfdump"
  90                                  "-no-cookie"
  91                                  "-I" "UTF-8"
  92                                  "-O" "UTF-8"
  93                                  "-o" "ext_halfdump=1"
  94                                  "-o" "pre_conv=1"
  95                                  "-t" (format "%s" tab-width)
  96                                  "-cols" (format "%s" gnus-html-frame-width)
  97                                  "-o" "display_image=off"
  98                                  "-T" "text/html"))))
  99       (gnus-html-wash-tags))))
 100
 101 (defvar gnus-article-mouse-face)
 102
 103 (defun gnus-html-wash-tags ()
 104   (let (tag parameters string start end images url)
 105     (mm-url-decode-entities)
 106     (goto-char (point-min))
 107     (while (re-search-forward "<\\([^ />]+\\)\\([^>]*\\)>" nil t)
 108       (setq tag (match-string 1)
 109             parameters (match-string 2)
 110             start (match-beginning 0))
 111       (when (plusp (length parameters))
 112         (set-text-properties 0 (1- (length parameters)) nil parameters))
 113       (delete-region start (point))
 114       (when (search-forward (concat "</" tag ">") nil t)
 115         (delete-region (match-beginning 0) (match-end 0)))
 116       (setq end (point))
 117       (cond
 118        ;; Fetch and insert a picture.
 119        ((equal tag "img_alt")
 120         (when (string-match "src=\"\\([^\"]+\\)" parameters)
 121           (setq url (match-string 1 parameters))
 122           (gnus-message 8 "Fetching image URL %s" url)
 123           (if (string-match "^cid:\\(.*\\)" url)
 124               ;; URLs with cid: have their content stashed in other
 125               ;; parts of the MIME structure, so just insert them
 126               ;; immediately.
 127               (let ((handle (mm-get-content-id
 128                              (setq url (match-string 1 url))))
 129                     image)
 130                 (when handle
 131                   (mm-with-part handle
 132                     (setq image (gnus-create-image (buffer-string)
 133                                                    nil t))))
 134                 (when image
 135                   (let ((string (buffer-substring start end)))
 136                     (delete-region start end)
 137                     (gnus-put-image image (gnus-string-or string "*")))))
 138             ;; Normal, external URL.
 139             (unless (gnus-html-image-url-blocked-p
 140                      url
 141                      (if (buffer-live-p gnus-summary-buffer)
 142                          (with-current-buffer gnus-summary-buffer
 143                            gnus-blocked-images)
 144                        gnus-blocked-images))
 145               (let ((file (gnus-html-image-id url)))
 146                 (if (file-exists-p file)
 147                     ;; It's already cached, so just insert it.
 148                     (let ((string (buffer-substring start end)))
 149                       ;; Delete the ALT text.
 150                       (delete-region start end)
 151                       (gnus-html-put-image file (point) string))
 152                   ;; We don't have it, so schedule it for fetching
 153                   ;; asynchronously.
 154                   (push (list url
 155                               (set-marker (make-marker) start)
 156                               (point-marker))
 157                         images)))))))
 158        ;; Add a link.
 159        ((or (equal tag "a")
 160             (equal tag "A"))
 161         (when (string-match "href=\"\\([^\"]+\\)" parameters)
 162           (setq url (match-string 1 parameters))
 163           (gnus-message 8 "Fetching link URL %s" url)
 164           (gnus-article-add-button start end
 165                                    'browse-url url
 166                                    url)
 167           (let ((overlay (gnus-make-overlay start end)))
 168             (gnus-overlay-put overlay 'evaporate t)
 169             (gnus-overlay-put overlay 'gnus-button-url url)
 170             (when gnus-article-mouse-face
 171               (gnus-overlay-put overlay 'mouse-face gnus-article-mouse-face)))))
 172        ;; The upper-case IMG_ALT is apparently just an artifact that
 173        ;; should be deleted.
 174        ((equal tag "IMG_ALT")
 175         (delete-region start end))
 176        ;; Whatever.  Just ignore the tag.
 177        (t
 178         ))
 179       (goto-char start))
 180     (goto-char (point-min))
 181     ;; The output from -halfdump isn't totally regular, so strip
 182     ;; off any </pre_int>s that were left over.
 183     (while (re-search-forward "</pre_int>" nil t)
 184       (replace-match "" t t))
 185     (when images
 186       (gnus-html-schedule-image-fetching (current-buffer) (nreverse images)))))
 187
 188 (defun gnus-html-schedule-image-fetching (buffer images)
 189   (gnus-message 8 "Scheduling image fetching in buffer %s, images %s" buffer images)
 190   (let* ((url (caar images))
 191          (process (start-process
 192                    "images" nil "curl"
 193                    "-s" "--create-dirs"
 194                    "--location"
 195                    "--max-time" "60"
 196                    "-o" (gnus-html-image-id url)
 197                    url)))
 198     (process-kill-without-query process)
 199     (set-process-sentinel process 'gnus-html-curl-sentinel)
 200     (gnus-set-process-plist process (list 'images images
 201                                           'buffer buffer))))
 202
 203 (defun gnus-html-image-id (url)
 204   (expand-file-name (sha1 url) gnus-html-cache-directory))
 205
 206 (defun gnus-html-curl-sentinel (process event)
 207   (when (string-match "finished" event)
 208     (let* ((images (gnus-process-get process 'images))
 209            (buffer (gnus-process-get process 'buffer))
 210            (spec (pop images))
 211            (file (gnus-html-image-id (car spec))))
 212       (when (and (buffer-live-p buffer)
 213                  ;; If the position of the marker is 1, then that
 214                  ;; means that the text it was in has been deleted;
 215                  ;; i.e., that the user has selected a different
 216                  ;; article before the image arrived.
 217                  (not (= (marker-position (cadr spec)) (point-min))))
 218         (with-current-buffer buffer
 219           (let ((inhibit-read-only t)
 220                 (string (buffer-substring (cadr spec) (caddr spec))))
 221             (delete-region (cadr spec) (caddr spec))
 222             (gnus-html-put-image file (cadr spec) string))))
 223       (when images
 224         (gnus-html-schedule-image-fetching buffer images)))))
 225
 226 (defun gnus-html-put-image (file point string)
 227   (when (display-graphic-p)
 228     (let ((image (ignore-errors
 229                    (gnus-create-image file))))
 230       (save-excursion
 231         (goto-char point)
 232         (if (and image
 233                  ;; Kludge to avoid displaying 30x30 gif images, which
 234                  ;; seems to be a signal of a broken image.
 235                  (not (and (listp image)
 236                            (eq (plist-get (cdr image) :type) 'gif)
 237                            (= (car (image-size image t)) 30)
 238                            (= (cdr (image-size image t)) 30))))
 239             (progn
 240               (gnus-put-image (gnus-html-rescale-image image)
 241                               (gnus-string-or string "*"))
 242               t)
 243           (insert string)
 244           (when (fboundp 'find-image)
 245             (gnus-put-image (find-image
 246                              '((:type xpm :file "lock-broken.xpm")))
 247                             (gnus-string-or string "*")))
 248           nil)))))
 249
 250 (defun gnus-html-rescale-image (image)
 251   (if (or (not (fboundp 'imagemagick-types))
 252           (not (get-buffer-window (current-buffer))))
 253       image
 254     (let* ((width (car (image-size image t)))
 255            (height (cdr (image-size image t)))
 256            (edges (window-pixel-edges (get-buffer-window (current-buffer))))
 257            (window-width (truncate (* gnus-max-image-proportion
 258                                       (- (nth 2 edges) (nth 0 edges)))))
 259            (window-height (truncate (* gnus-max-image-proportion
 260                                        (- (nth 3 edges) (nth 1 edges)))))
 261            scaled-image)
 262       (or
 263        (cond ((> height window-height)
 264               (create-image file 'imagemagick nil
 265                             :height window-height))
 266              ((> width window-width)
 267               (create-image file 'imagemagick nil
 268                             :width window-width)))
 269        image))))
 270
 271 (defun gnus-html-prune-cache ()
 272   (let ((total-size 0)
 273         files)
 274     (dolist (file (directory-files gnus-html-cache-directory t nil t))
 275       (let ((attributes (file-attributes file)))
 276         (unless (nth 0 attributes)
 277           (incf total-size (nth 7 attributes))
 278           (push (list (time-to-seconds (nth 5 attributes))
 279                       (nth 7 attributes) file)
 280                 files))))
 281     (when (> total-size gnus-html-cache-size)
 282       (setq files (sort files (lambda (f1 f2)
 283                                 (< (car f1) (car f2)))))
 284       (dolist (file files)
 285         (when (> total-size gnus-html-cache-size)
 286           (decf total-size (cadr file))
 287           (delete-file (nth 2 file)))))))
 288
 289
 290 (defun gnus-html-image-url-blocked-p (url blocked-images)
 291 "Find out if URL is blocked by BLOCKED-IMAGES."
 292   (let ((ret (and blocked-images
 293                   (string-match blocked-images url))))
 294     (when ret
 295       (gnus-message 8 "Image URL %s is blocked by gnus-blocked-images regex %s" url blocked-images))
 296     ret))
 297
 298 ;;;###autoload
 299 (defun gnus-html-prefetch-images (summary)
 300   (let (blocked-images urls)
 301     (when (buffer-live-p summary)
 302       (with-current-buffer summary
 303         (setq blocked-images gnus-blocked-images))
 304       (save-match-data
 305         (while (re-search-forward "<img.*src=[\"']\\([^\"']+\\)" nil t)
 306           (let ((url (match-string 1)))
 307             (unless (gnus-html-image-url-blocked-p url blocked-images)
 308               (unless (file-exists-p (gnus-html-image-id url))
 309                 (push url urls)
 310                 (push (gnus-html-image-id url) urls)
 311                 (push "-o" urls)))))
 312         (let ((process
 313                (apply 'start-process
 314                       "images" nil "curl"
 315                       "-s" "--create-dirs"
 316                       "--location"
 317                       "--max-time" "60"
 318                       urls)))
 319           (process-kill-without-query process))))))
 320
 321 (provide 'gnus-html)
 322
 323 ;;; gnus-html.el ends here