cgit.sxemacs.org Git - gnus/blob - lisp/gnus-gravatar.el

   1 ;;; gnus-gravatar.el --- Gnus Gravatar support
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Julien Danjou <julien@danjou.info>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'gravatar)
  28 (require 'gnus-art)
  29
  30 (defgroup gnus-gravatar nil
  31   "Gnus Gravatar."
  32   :group 'gnus-visual)
  33
  34 (defcustom gnus-gravatar-size 32
  35   "How big should gravatars be displayed."
  36   :type 'integer
  37   :version "24.1"
  38   :group 'gnus-gravatar)
  39
  40 (defcustom gnus-gravatar-properties '(:ascent center :relief 1)
  41   "List of image properties applied to Gravatar images."
  42   :type 'list
  43   :version "24.1"
  44   :group 'gnus-gravatar)
  45
  46 (defcustom gnus-gravatar-too-ugly (if (boundp 'gnus-article-x-face-too-ugly)
  47                                       gnus-article-x-face-too-ugly)
  48   "Regexp matching posters whose avatar shouldn't be shown automatically."
  49   :type '(choice regexp (const nil))
  50   :version "24.1"
  51   :group 'gnus-gravatar)
  52
  53 (defun gnus-gravatar-transform-address (header category)
  54   (gnus-with-article-headers
  55     (let ((addresses
  56            (mail-header-parse-addresses
  57             ;; mail-header-parse-addresses does not work (reliably) on
  58             ;; decoded headers.
  59             (or
  60              (ignore-errors
  61                (mail-encode-encoded-word-string
  62                 (or (mail-fetch-field header) "")))
  63              (mail-fetch-field header)))))
  64       (let ((gravatar-size gnus-gravatar-size))
  65         (dolist (address addresses)
  66           (unless (and gnus-gravatar-too-ugly
  67                        (or (string-match gnus-gravatar-too-ugly
  68                                          (car address))
  69                            (and (cdr address)
  70                                 (string-match gnus-gravatar-too-ugly
  71                                               (cdr address)))))
  72             (ignore-errors
  73               (gravatar-retrieve
  74                (car address)
  75                'gnus-gravatar-insert
  76                (list header address category)))))))))
  77
  78 (defun gnus-gravatar-insert (gravatar header address category)
  79   "Insert GRAVATAR for ADDRESS in HEADER in current article buffer.
  80 Set image category to CATEGORY."
  81   (unless (eq gravatar 'error)
  82     (gnus-with-article-headers
  83       (gnus-article-goto-header header)
  84       (mail-header-narrow-to-field)
  85       (let ((real-name (cdr address))
  86             (mail-address (car address)))
  87         (when (if real-name             ; have a realname, go for it!
  88                   (and (search-forward real-name nil t)
  89                        (search-backward real-name nil t))
  90                 (and (search-forward mail-address nil t)
  91                      (search-backward mail-address nil t)))
  92           (goto-char (1- (point)))
  93           ;; If we're on the " quoting the name, go backward
  94           (when (looking-at "[\"<]")
  95             (goto-char (1- (point))))
  96           ;; Do not do anything if there's already a gravatar. This can
  97           ;; happens if the buffer has been regenerated in the mean time, for
  98           ;; example we were fetching someaddress, and then we change to
  99           ;; another mail with the same someaddress.
 100           (unless (memq 'gnus-gravatar (text-properties-at (point)))
 101             (let ((inhibit-read-only t)
 102                   (point (point)))
 103               (unless (featurep 'xemacs)
 104                 (setq gravatar (append gravatar gnus-gravatar-properties)))
 105               (gnus-put-image gravatar nil category)
 106               (put-text-property point (point) 'gnus-gravatar address)
 107               (gnus-add-wash-type category)
 108               (gnus-add-image category gravatar))))))))
 109
 110 ;;;###autoload
 111 (defun gnus-treat-from-gravatar ()
 112   "Display gravatar in the From header.
 113 If gravatar is already displayed, remove it."
 114   (interactive)
 115   (gnus-with-article-buffer
 116     (if (memq 'from-gravatar gnus-article-wash-types)
 117         (gnus-delete-images 'from-gravatar)
 118       (let ((gnus-gravatar-too-ugly
 119              (unless buffer-read-only ;; When type `W D g'
 120                gnus-gravatar-too-ugly)))
 121         (gnus-gravatar-transform-address "from" 'from-gravatar)))))
 122
 123 ;;;###autoload
 124 (defun gnus-treat-mail-gravatar ()
 125   "Display gravatars in the Cc and To headers.
 126 If gravatars are already displayed, remove them."
 127   (interactive)
 128     (gnus-with-article-buffer
 129       (if (memq 'mail-gravatar gnus-article-wash-types)
 130           (gnus-delete-images 'mail-gravatar)
 131         (let ((gnus-gravatar-too-ugly
 132                (unless buffer-read-only ;; When type `W D h'
 133                  gnus-gravatar-too-ugly)))
 134           (gnus-gravatar-transform-address "cc" 'mail-gravatar)
 135           (gnus-gravatar-transform-address "to" 'mail-gravatar)))))
 136
 137 (provide 'gnus-gravatar)
 138
 139 ;;; gnus-gravatar.el ends here