cgit.sxemacs.org Git - gnus/blob - lisp/gnus-fun.el

   1 ;;; gnus-fun.el --- various frivoluos extension functions to Gnus
   2 ;; Copyright (C) 2002 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (defcustom gnus-x-face-directory (expand-file-name "x-faces" gnus-directory)
  29   "*Directory where X-Face PBM files are stored."
  30   :group 'gnus-fun
  31   :type 'directory)
  32
  33 (defcustom gnus-convert-pbm-to-x-face-command "pbmtoxbm %s | compface"
  34   "Command for converting a PBM to an X-Face."
  35   :group 'gnus-fun
  36   :type 'string)
  37
  38 (defcustom gnus-convert-image-to-x-face-command "giftopnm %s | ppmnorm | pnmscale -width 48 -height 48 | ppmtopgm | pgmtopbm | pbmtoxbm | compface"
  39   "Command for converting a GIF to an X-Face."
  40   :group 'gnus-fun
  41   :type 'string)
  42
  43 (defcustom gnus-convert-image-to-face-command "djpeg %s | ppmnorm | pnmscale -width 48 -height 48 | ppmquant %d | pnmtopng"
  44   "Command for converting a GIF to an X-Face."
  45   :group 'gnus-fun
  46   :type 'string)
  47
  48 (defun gnus-shell-command-to-string (command)
  49   "Like `shell-command-to-string' except not mingling ERROR."
  50   (with-output-to-string
  51     (call-process shell-file-name nil (list standard-output nil)
  52                   nil shell-command-switch command)))
  53
  54 (defun gnus-shell-command-on-region (start end command)
  55   "A simplified `shell-command-on-region'.
  56 Output to the current buffer, replace text, and don't mingle error."
  57   (call-process-region start end shell-file-name t
  58                        (list (current-buffer) nil)
  59                        nil shell-command-switch command))
  60
  61 ;;;###autoload
  62 (defun gnus-random-x-face ()
  63   "Insert a random X-Face header from `gnus-x-face-directory'."
  64   (interactive)
  65   (when (file-exists-p gnus-x-face-directory)
  66     (let* ((files (directory-files gnus-x-face-directory t "\\.pbm$"))
  67            (file (nth (random (length files)) files)))
  68       (when file
  69         (gnus-shell-command-to-string
  70          (format gnus-convert-pbm-to-x-face-command
  71                  (shell-quote-argument file)))))))
  72
  73 ;;;###autoload
  74 (defun gnus-x-face-from-file (file)
  75   "Insert an X-Face header based on an image file."
  76   (interactive "fImage file name:" )
  77   (when (file-exists-p file)
  78     (gnus-shell-command-to-string
  79      (format gnus-convert-image-to-x-face-command
  80              (shell-quote-argument file)))))
  81
  82 (defun gnus-face-from-file (file)
  83   "Return an Face header based on an image file."
  84   (interactive "fImage file name:" )
  85   (when (file-exists-p file)
  86     (let ((done nil)
  87           (attempt "")
  88           (quant 4))
  89       (while (and (not done)
  90                   (> quant 1))
  91         (setq attempt
  92               (gnus-shell-command-to-string
  93                (format gnus-convert-image-to-face-command
  94                        (shell-quote-argument file)
  95                        quant)))
  96         (if (> (length attempt) 740)
  97             (setq quant (/ quant 2))
  98           (setq done t)))
  99       (if done
 100           (mm-with-unibyte-buffer
 101             (insert attempt)
 102             (base64-encode-region (point-min) (point-max))
 103             (goto-char (point-min))
 104             (forward-line 1)
 105             (while (not (eobp))
 106               (insert " ")
 107               (forward-line 1))
 108             (buffer-string))
 109         nil))))
 110
 111 ;;;###autoload
 112 (defun gnus-convert-face-to-png (face)
 113   (mm-with-unibyte-buffer
 114     (insert face)
 115     (base64-decode-region (point-min) (point-max))
 116     (buffer-string)))
 117
 118 (defun gnus-convert-image-to-gray-x-face (file depth)
 119   (let* ((mapfile (mm-make-temp-file (expand-file-name "gnus."
 120                                                        mm-tmp-directory)))
 121          (levels (expt 2 depth))
 122          (step (/ 255 (1- levels)))
 123          color-alist bits bits-list mask pixel x-faces)
 124     (with-temp-file mapfile
 125       (insert "P3\n")
 126       (insert (format "%d 1\n" levels))
 127       (insert "255\n")
 128       (dotimes (i levels)
 129         (insert (format "%d %d %d\n"
 130                         (* step i) (* step i) (* step i)))
 131         (push (cons (* step i) i) color-alist)))
 132     (when (file-exists-p file)
 133       (with-temp-buffer
 134         (insert (gnus-shell-command-to-string
 135                  (format "giftopnm %s | ppmnorm | pnmscale -width 48 -height 48 | ppmquant -fs -map %s | ppmtopgm | pnmnoraw"
 136                          (shell-quote-argument file)
 137                          mapfile)))
 138         (goto-char (point-min))
 139         (forward-line 3)
 140         (while (setq pixel (ignore-errors (read (current-buffer))))
 141           (push (cdr (assq pixel color-alist)) bits-list))
 142         (setq bits-list (nreverse bits-list))
 143         (dotimes (bit-number depth)
 144           (setq mask (expt 2 bit-number))
 145           (with-temp-buffer
 146             (insert "P1\n48 48\n")
 147             (dolist (bits bits-list)
 148               (insert (if (zerop (logand bits mask)) "0 " "1 ")))
 149             (gnus-shell-command-on-region
 150              (point-min) (point-max)
 151              ;; the following is taken from xbmtoikon:
 152              "pbmtoicon | sed '/^[      ]*[*\\\\/]/d; s/[       ]//g; s/,$//' | tr , '\\012' | sed 's/^0x//; s/^/0x/' | pr -l1 -t -w22 -3 -s, | sed 's/,*$/,/' | compface")
 153             (push (buffer-string) x-faces))))
 154       (dotimes (i (length x-faces))
 155         (insert (if (zerop i) "X-Face:" (format "X-Face-%s:" i))
 156                 (nth i x-faces))))
 157     (delete-file mapfile)))
 158
 159 ;;;###autoload
 160 (defun gnus-convert-gray-x-face-to-xpm (faces)
 161   (let* ((depth (length faces))
 162          (scale (/ 255 (1- (expt 2 depth))))
 163          (ok-p t)
 164          (coding-system-for-read 'binary)
 165          (coding-system-for-write 'binary)
 166          default-enable-multibyte-characters
 167          start bit-array bit-arrays pixel)
 168     (with-temp-buffer
 169       (dolist (face faces)
 170         (erase-buffer)
 171         (insert (uncompface face))
 172         (gnus-shell-command-on-region
 173          (point-min) (point-max)
 174          "pnmnoraw")
 175         (goto-char (point-min))
 176         (forward-line 2)
 177         (setq start (point))
 178         (insert "[")
 179         (while (not (eobp))
 180           (forward-char 1)
 181           (insert " "))
 182         (insert "]")
 183         (goto-char start)
 184         (setq bit-array (read (current-buffer)))
 185         (unless (= (length bit-array) (* 48 48))
 186           (setq ok-p nil))
 187         (push bit-array bit-arrays))
 188       (when ok-p
 189         (erase-buffer)
 190         (insert "P2\n48 48\n255\n")
 191         (dotimes (i (* 48 48))
 192           (setq pixel 0)
 193           (dotimes (plane depth)
 194             (setq pixel (+ (* pixel 2) (aref (nth plane bit-arrays) i))))
 195           (insert (number-to-string (* scale pixel)) " "))
 196         (gnus-shell-command-on-region
 197          (point-min) (point-max)
 198          "ppmtoxpm")
 199         (buffer-string)))))
 200
 201 ;;;###autoload
 202 (defun gnus-convert-gray-x-face-region (beg end)
 203   "Convert the X-Faces in region to a PPM file."
 204   (interactive "r")
 205   (let ((input (buffer-substring beg end))
 206         faces)
 207     (with-temp-buffer
 208       (insert input)
 209       (goto-char (point-min))
 210       (while (not (eobp))
 211         (save-restriction
 212           (mail-header-narrow-to-field)
 213           (push (mail-header-field-value) faces)
 214           (goto-char (point-max)))))
 215     (gnus-convert-gray-x-face-to-xpm faces)))
 216
 217 (defface gnus-x-face '((t (:foreground "black" :background "white")))
 218   "Face to show X-Face.
 219 The colors from this face are used as the foreground and background
 220 colors of the displayed X-Faces."
 221   :group 'gnus-article-headers)
 222
 223 (defun gnus-display-x-face-in-from (data)
 224   "Display the X-Face DATA in the From header."
 225   (let ((default-enable-multibyte-characters nil)
 226         pbm)
 227     (when (or (gnus-image-type-available-p 'xface)
 228               (and (gnus-image-type-available-p 'pbm)
 229                    (setq pbm (uncompface data))))
 230       (save-excursion
 231         (save-restriction
 232           (article-narrow-to-head)
 233           (gnus-article-goto-header "from")
 234           (when (bobp)
 235             (insert "From: [no `from' set]\n")
 236             (forward-char -17))
 237           (gnus-add-image
 238            'xface
 239            (gnus-put-image
 240             (if (gnus-image-type-available-p 'xface)
 241                 (gnus-create-image
 242                  (concat "X-Face: " data)
 243                  'xface t :ascent 'center :face 'gnus-x-face)
 244               (gnus-create-image
 245                pbm 'pbm t :ascent 'center :face 'gnus-x-face))))
 246           (gnus-add-wash-type 'xface))))))
 247
 248 (defun gnus-grab-cam-x-face ()
 249   "Grab a picture off the camera and make it into an X-Face."
 250   (interactive)
 251   (shell-command "xawtv-remote snap ppm")
 252   (let ((file nil))
 253     (while (null (setq file (directory-files "/tftpboot/sparky/tmp"
 254                                              t "snap.*ppm")))
 255       (sleep-for 1))
 256     (setq file (car file))
 257     (with-temp-buffer
 258       (shell-command
 259        (format "pnmcut -left 110 -top 30 -width 144 -height 144 '%s' | ppmnorm 2>/dev/null | pnmscale -width 48 | ppmtopgm | pgmtopbm -threshold -value 0.92 | pbmtoxbm | compface"
 260                file)
 261        (current-buffer))
 262       ;;(sleep-for 3)
 263       (delete-file file)
 264       (buffer-string))))
 265
 266 (defun gnus-grab-gray-x-face ()
 267   "Grab a picture off the camera and make it into an X-Face."
 268   (interactive)
 269   (shell-command "xawtv-remote snap ppm")
 270   (let ((file nil))
 271     (while (null (setq file (directory-files "/tftpboot/sparky/tmp"
 272                                              t "snap.*ppm")))
 273       (sleep-for 1))
 274     (setq file (car file))
 275     (with-temp-buffer
 276       (shell-command
 277        (format "pnmcut -left 70 -top 100 -width 144 -height 144 '%s' | ppmquant 256 2>/dev/null | ppmtogif > '%s.gif'"
 278                file file)
 279        (current-buffer))
 280       (delete-file file))
 281     (gnus-convert-image-to-gray-x-face (concat file ".gif") 3)
 282     (delete-file (concat file ".gif"))))
 283
 284 (provide 'gnus-fun)
 285
 286 ;;; gnus-fun.el ends here