cgit.sxemacs.org Git - gnus/blob - lisp/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Gnus
   2 ;; Copyright (C) 1997, 1998, 1999, 2000
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'gnus)
  30 (require 'gnus-sum)
  31 (require 'message)
  32 (require 'gnus-msg)
  33 (require 'nndraft)
  34 (require 'gnus-agent)
  35 (eval-when-compile (require 'cl))
  36
  37 ;;; Draft minor mode
  38
  39 (defvar gnus-draft-mode nil
  40   "Minor mode for providing a draft summary buffers.")
  41
  42 (defvar gnus-draft-mode-map nil)
  43
  44 (unless gnus-draft-mode-map
  45   (setq gnus-draft-mode-map (make-sparse-keymap))
  46
  47   (gnus-define-keys gnus-draft-mode-map
  48     "Dt" gnus-draft-toggle-sending
  49     "De" gnus-draft-edit-message
  50     "Ds" gnus-draft-send-message
  51     "DS" gnus-draft-send-all-messages))
  52
  53 (defun gnus-draft-make-menu-bar ()
  54   (unless (boundp 'gnus-draft-menu)
  55     (easy-menu-define
  56      gnus-draft-menu gnus-draft-mode-map ""
  57      '("Drafts"
  58        ["Toggle whether to send" gnus-draft-toggle-sending t]
  59        ["Edit" gnus-draft-edit-message t]
  60        ["Send selected message(s)" gnus-draft-send-message t]
  61        ["Send all messages" gnus-draft-send-all-messages t]
  62        ["Delete draft" gnus-summary-delete-article t]))))
  63
  64 (defun gnus-draft-mode (&optional arg)
  65   "Minor mode for providing a draft summary buffers.
  66
  67 \\{gnus-draft-mode-map}"
  68   (interactive "P")
  69   (when (eq major-mode 'gnus-summary-mode)
  70     (when (set (make-local-variable 'gnus-draft-mode)
  71                (if (null arg) (not gnus-draft-mode)
  72                  (> (prefix-numeric-value arg) 0)))
  73       ;; Set up the menu.
  74       (when (gnus-visual-p 'draft-menu 'menu)
  75         (gnus-draft-make-menu-bar))
  76       (gnus-add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  77       (mml-mode)
  78       (gnus-run-hooks 'gnus-draft-mode-hook))))
  79
  80 ;;; Commands
  81
  82 (defun gnus-draft-toggle-sending (article)
  83   "Toggle whether to send an article or not."
  84   (interactive (list (gnus-summary-article-number)))
  85   (if (gnus-draft-article-sendable-p article)
  86       (progn
  87         (push article gnus-newsgroup-unsendable)
  88         (gnus-summary-mark-article article gnus-unsendable-mark))
  89     (setq gnus-newsgroup-unsendable
  90           (delq article gnus-newsgroup-unsendable))
  91     (gnus-summary-mark-article article gnus-unread-mark))
  92   (gnus-summary-position-point))
  93
  94 (defun gnus-draft-edit-message ()
  95   "Enter a mail/post buffer to edit and send the draft."
  96   (interactive)
  97   (let ((article (gnus-summary-article-number)))
  98     (gnus-summary-mark-as-read article gnus-canceled-mark)
  99     (gnus-draft-setup article gnus-newsgroup-name t)
 100     (set-buffer-modified-p t)
 101     (save-excursion
 102       (save-restriction
 103         (message-narrow-to-headers)
 104         (message-remove-header "date")))
 105     (save-buffer)
 106     (let ((gnus-verbose-backends nil))
 107       (gnus-request-expire-articles (list article) gnus-newsgroup-name t))
 108     (push
 109      `((lambda ()
 110          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 111            (save-excursion
 112              (set-buffer ,gnus-summary-buffer)
 113              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 114      message-send-actions)))
 115
 116 (defun gnus-draft-send-message (&optional n)
 117   "Send the current draft."
 118   (interactive "P")
 119   (let* ((articles (gnus-summary-work-articles n))
 120          (total (length articles))
 121          article)
 122     (while (setq article (pop articles))
 123       (gnus-summary-remove-process-mark article)
 124       (unless (memq article gnus-newsgroup-unsendable)
 125         (let ((message-sending-message
 126                (format "Sending message %d of %d..."
 127                        (- total (length articles)) total)))
 128           (gnus-draft-send article gnus-newsgroup-name t))
 129         (gnus-summary-mark-article article gnus-canceled-mark)))))
 130
 131 (defun gnus-draft-send (article &optional group interactive)
 132   "Send message ARTICLE."
 133   (let ((message-syntax-checks (if interactive nil
 134                                  'dont-check-for-anything-just-trust-me))
 135         (message-inhibit-body-encoding (or (not group)
 136                                            (equal group "nndraft:queue")
 137                                            message-inhibit-body-encoding))
 138         (message-send-hook (and group (not (equal group "nndraft:queue"))
 139                                 message-send-hook))
 140         (message-setup-hook (and group (not (equal group "nndraft:queue"))
 141                                  message-setup-hook))
 142         type method)
 143     (gnus-draft-setup article (or group "nndraft:queue"))
 144     ;; We read the meta-information that says how and where
 145     ;; this message is to be sent.
 146     (save-restriction
 147       (message-narrow-to-head)
 148       (when (re-search-forward
 149              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 150              nil t)
 151         (setq type (ignore-errors (read (current-buffer)))
 152               method (ignore-errors (read (current-buffer))))
 153         (message-remove-header gnus-agent-meta-information-header)))
 154     ;; Let Agent restore any GCC lines and have message.el perform them.
 155     (gnus-agent-restore-gcc)
 156     ;; Then we send it.  If we have no meta-information, we just send
 157     ;; it and let Message figure out how.
 158     (when (and (or (null method)
 159                    (gnus-server-opened method)
 160                    (gnus-open-server method))
 161                (if type
 162                    (let ((message-this-is-news (eq type 'news))
 163                          (message-this-is-mail (eq type 'mail))
 164                          (gnus-post-method method)
 165                          (message-post-method method))
 166                      (message-send-and-exit))
 167                  (message-send-and-exit)))
 168       (let ((gnus-verbose-backends nil))
 169         (gnus-request-expire-articles
 170          (list article) (or group "nndraft:queue") t)))))
 171
 172 (defun gnus-draft-send-all-messages ()
 173   "Send all the sendable drafts."
 174   (interactive)
 175   (gnus-uu-mark-buffer)
 176   (gnus-draft-send-message))
 177
 178 (defun gnus-group-send-drafts ()
 179   "Send all sendable articles from the queue group."
 180   (interactive)
 181   (gnus-activate-group "nndraft:queue")
 182   (save-excursion
 183     (let* ((articles (nndraft-articles))
 184            (unsendable (gnus-uncompress-range
 185                         (cdr (assq 'unsend
 186                                    (gnus-info-marks
 187                                     (gnus-get-info "nndraft:queue"))))))
 188            (total (length articles))
 189            article)
 190       (while (setq article (pop articles))
 191         (unless (memq article unsendable)
 192           (let ((message-sending-message
 193                  (format "Sending message %d of %d..."
 194                          (- total (length articles)) total)))
 195             (gnus-draft-send article)))))))
 196
 197 ;;;###autoload
 198 (defun gnus-draft-reminder ()
 199   "Reminder user if there are unsent drafts."
 200   (interactive)
 201   (if (gnus-alive-p)
 202       (let (active)
 203         (catch 'continue
 204           (dolist (group '("nndraft:drafts" "nndraft:queue"))
 205             (setq active (gnus-activate-group group))
 206             (if (and active (>= (cdr active) (car active)))
 207                 (if (y-or-n-p "There are unsent drafts. Confirm to exit?")
 208                     (throw 'continue t)
 209                   (error "Stop!"))))))))
 210
 211 ;;; Utility functions
 212
 213 ;;;!!!If this is byte-compiled, it fails miserably.
 214 ;;;!!!This is because `gnus-setup-message' uses uninterned symbols.
 215 ;;;!!!This has been fixed in recent versions of Emacs and XEmacs,
 216 ;;;!!!but for the time being, we'll just run this tiny function uncompiled.
 217
 218 (progn
 219   (defun gnus-draft-setup (narticle group &optional restore)
 220     (let (ga)
 221       (gnus-setup-message 'forward
 222         (let ((article narticle))
 223           (message-mail)
 224           (erase-buffer)
 225           (if (not (gnus-request-restore-buffer article group))
 226               (error "Couldn't restore the article")
 227             (when (and restore
 228                        (equal group "nndraft:queue"))
 229               (mime-to-mml))
 230             ;; Insert the separator.
 231             (goto-char (point-min))
 232             (search-forward "\n\n")
 233             (forward-char -1)
 234             (insert mail-header-separator)
 235             (forward-line 1)
 236             (setq ga (message-fetch-field gnus-draft-meta-information-header))
 237             (message-set-auto-save-file-name))))
 238       (gnus-backlog-remove-article group narticle)
 239       (when (and ga
 240                  (ignore-errors (setq ga (car (read-from-string ga)))))
 241         (setq message-post-method
 242               `(lambda (arg)
 243                  (gnus-post-method arg ,(car ga))))
 244         (message-add-action
 245          `(gnus-add-mark ,(car ga) 'replied ,(cadr ga))
 246          'send)))))
 247
 248 (defun gnus-draft-article-sendable-p (article)
 249   "Say whether ARTICLE is sendable."
 250   (not (memq article gnus-newsgroup-unsendable)))
 251
 252 (provide 'gnus-draft)
 253
 254 ;;; gnus-draft.el ends here