cgit.sxemacs.org Git - gnus/blob - lisp/gnus-cus.el

   1 ;;; gnus-cus.el --- customization commands for Gnus
   2 ;;
   3 ;; Copyright (C) 1996, 1999, 2000, 2001, 2002, 2003
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (require 'wid-edit)
  31 (require 'gnus)
  32 (require 'gnus-agent)
  33 (require 'gnus-score)
  34 (require 'gnus-topic)
  35 (require 'gnus-art)
  36
  37 ;;; Widgets:
  38
  39 (defun gnus-custom-mode ()
  40   "Major mode for editing Gnus customization buffers.
  41
  42 The following commands are available:
  43
  44 \\[widget-forward]              Move to next button or editable field.
  45 \\[widget-backward]             Move to previous button or editable field.
  46 \\[widget-button-click]         Activate button under the mouse pointer.
  47 \\[widget-button-press]         Activate button under point.
  48
  49 Entry to this mode calls the value of `gnus-custom-mode-hook'
  50 if that value is non-nil."
  51   (kill-all-local-variables)
  52   (setq major-mode 'gnus-custom-mode
  53         mode-name "Gnus Customize")
  54   (use-local-map widget-keymap)
  55   ;; Emacs 21 stuff:
  56   (when (and (facep 'custom-button-face)
  57              (facep 'custom-button-pressed-face))
  58     (set (make-local-variable 'widget-button-face)
  59          'custom-button-face)
  60     (set (make-local-variable 'widget-button-pressed-face)
  61          'custom-button-pressed-face)
  62     (set (make-local-variable 'widget-mouse-face)
  63          'custom-button-pressed-face))
  64   (when (and (boundp 'custom-raised-buttons)
  65              (symbol-value 'custom-raised-buttons))
  66     (set (make-local-variable 'widget-push-button-prefix) "")
  67     (set (make-local-variable 'widget-push-button-suffix) "")
  68     (set (make-local-variable 'widget-link-prefix) "")
  69     (set (make-local-variable 'widget-link-suffix) ""))
  70   (gnus-run-hooks 'gnus-custom-mode-hook))
  71
  72 ;;; Group Customization:
  73
  74 (defconst gnus-group-parameters
  75   '((extra-aliases (choice
  76                     :tag "Extra Aliases"
  77                     (list
  78                      :tag "List"
  79                      (editable-list
  80                       :inline t
  81                       (gnus-email-address :tag "Address")))
  82                     (gnus-email-address :tag "Address")) "\
  83 Store messages posted from or to this address in this group.
  84
  85 You must be using gnus-group-split for this to work.  The VALUE of the
  86 nnmail-split-fancy SPLIT generated for this group will match these
  87 addresses.")
  88
  89     (split-regexp (regexp :tag "gnus-group-split Regular Expression") "\
  90 Like gnus-group-split Address, but expects a regular expression.")
  91
  92     (split-exclude (list :tag "gnus-group-split Restricts"
  93                          (editable-list
  94                           :inline t (regexp :tag "Restrict"))) "\
  95 Regular expression that cancels gnus-group-split matches.
  96
  97 Each entry is added to the nnmail-split-fancy SPLIT as a separate
  98 RESTRICT clause.")
  99
 100     (split-spec (choice :tag "gnus-group-split Overrider"
 101                         (sexp :tag "Fancy Split")
 102                         (const :tag "Catch All" catch-all)
 103                         (const :tag "Ignore" nil)) "\
 104 Override all other gnus-group-split fields.
 105
 106 In `Fancy Split', you can enter any nnmail-split-fancy SPLIT.  Note
 107 that the name of this group won't be automatically assumed, you have
 108 to add it to the SPLITs yourself.  This means you can use such splits
 109 to split messages to other groups too.
 110
 111 If you select `Catch All', this group will get postings for any
 112 messages not matched in any other group.  It overrides the variable
 113 gnus-group-split-default-catch-all-group.
 114
 115 Selecting `Ignore' forces no SPLIT to be generated for this group,
 116 disabling all other gnus-group-split fields.")
 117
 118     (broken-reply-to (const :tag "Broken Reply To" t) "\
 119 Ignore `Reply-To' headers in this group.
 120
 121 That can be useful if you're reading a mailing list group where the
 122 listserv has inserted `Reply-To' headers that point back to the
 123 listserv itself.  This is broken behavior.  So there!")
 124
 125     (to-group (string :tag "To Group") "\
 126 All posts will be sent to the specified group.")
 127
 128     (gcc-self (choice :tag  "GCC"
 129                       :value t
 130                       (const :tag "To current group" t)
 131                       (const none)
 132                       (string :format "%v" :hide-front-space t)) "\
 133 Specify default value for GCC header.
 134
 135 If this symbol is present in the group parameter list and set to t,
 136 new composed messages will be `Gcc''d to the current group.  If it is
 137 present and set to `none', no `Gcc:' header will be generated, if it
 138 is present and a string, this string will be inserted literally as a
 139 `gcc' header (this symbol takes precedence over any default `Gcc'
 140 rules as described later).")
 141
 142     (expiry-wait (choice :tag  "Expire Wait"
 143                          :value never
 144                          (const never)
 145                          (const immediate)
 146                          (number :hide-front-space t
 147                                  :format "%v")) "\
 148 When to expire.
 149
 150 Overrides any `nnmail-expiry-wait' and `nnmail-expiry-wait-function'
 151 when expiring expirable messages.  The value can either be a number of
 152 days (not necessarily an integer) or the symbols `never' or
 153 `immediate'.")
 154
 155     (expiry-target (choice :tag "Expiry Target"
 156                            :value delete
 157                            (const delete)
 158                            (function :format "%v" nnmail-)
 159                            string) "\
 160 Where expired messages end up.
 161
 162 Overrides `nnmail-expiry-target', which see.")
 163
 164     (score-file (file :tag "Score File") "\
 165 Make the specified file into the current score file.
 166 This means that all score commands you issue will end up in this file.")
 167
 168     (adapt-file (file :tag "Adapt File") "\
 169 Make the specified file into the current adaptive file.
 170 All adaptive score entries will be put into this file.")
 171
 172     (admin-address (gnus-email-address :tag "Admin Address") "\
 173 Administration address for a mailing list.
 174
 175 When unsubscribing to a mailing list you should never send the
 176 unsubscription notice to the mailing list itself.  Instead, you'd
 177 send messages to the administrative address.  This parameter allows
 178 you to put the admin address somewhere convenient.")
 179
 180     (display (choice :tag "Display"
 181                      :value default
 182                      (const all)
 183                      (integer)
 184                      (const default)
 185                      (sexp  :tag "Other")) "\
 186 Which articles to display on entering the group.
 187
 188 `all'
 189      Display all articles, both read and unread.
 190
 191 `integer'
 192      Display the last NUMBER articles in the group.  This is the same as
 193      entering the group with C-u NUMBER.
 194
 195 `default'
 196      Display the default visible articles, which normally includes
 197      unread and ticked articles.
 198
 199 `Other'
 200      Display the articles that satisfy the S-expression. The S-expression
 201      should be in an array form.")
 202
 203     (comment (string :tag  "Comment") "\
 204 An arbitrary comment on the group.")
 205
 206     (visible (const :tag "Permanently visible" t) "\
 207 Always display this group, even when there are no unread articles
 208 in it..")
 209
 210     (highlight-words
 211      (choice :tag "Highlight words"
 212              :value nil
 213              (repeat (list (regexp :tag "Highlight regexp")
 214                            (number :tag "Group for entire word" 0)
 215                            (number :tag "Group for displayed part" 0)
 216                            (symbol :tag "Face"
 217                                    gnus-emphasis-highlight-words))))
 218      "highlight regexps.
 219 See `gnus-emphasis-alist'.")
 220
 221     (posting-style
 222      (choice :tag "Posting style"
 223              :value nil
 224              (repeat (list
 225                       (choice :tag "Type"
 226                               :value nil
 227                               (const signature)
 228                               (const signature-file)
 229                               (const organization)
 230                               (const address)
 231                               (const name)
 232                               (const body))
 233                       (string :format "%v"))))
 234      "post style.
 235 See `gnus-posting-styles'."))
 236   "Alist of valid group or topic parameters.
 237
 238 Each entry has the form (NAME TYPE DOC), where NAME is the parameter
 239 itself (a symbol), TYPE is the parameters type (a sexp widget), and
 240 DOC is a documentation string for the parameter.")
 241
 242 (defconst gnus-extra-topic-parameters
 243   '((subscribe (regexp :tag "Subscribe") "\
 244 If `gnus-subscribe-newsgroup-method' or
 245 `gnus-subscribe-options-newsgroup-method' is set to
 246 `gnus-subscribe-topics', new groups that matches this regexp will
 247 automatically be subscribed to this topic")
 248     (subscribe-level (integer :tag "Subscribe Level" :value 1) "\
 249 If this topic parameter is set, when new groups are subscribed
 250 automatically under this topic (via the `subscribe' topic parameter)
 251 assign this level to the group, rather than the default level
 252 set in `gnus-level-default-subscribed'"))
 253   "Alist of topic parameters that are not also group parameters.
 254
 255 Each entry has the form (NAME TYPE DOC), where NAME is the parameter
 256 itself (a symbol), TYPE is the parameters type (a sexp widget), and
 257 DOC is a documentation string for the parameter.")
 258
 259 (defconst gnus-extra-group-parameters
 260   '((uidvalidity (string :tag "IMAP uidvalidity") "\
 261 Server-assigned value attached to IMAP groups, used to maintain consistency."))
 262   "Alist of group parameters that are not also topic parameters.
 263
 264 Each entry has the form (NAME TYPE DOC), where NAME is the parameter
 265 itself (a symbol), TYPE is the parameters type (a sexp widget), and
 266 DOC is a documentation string for the parameter.")
 267
 268 (eval-and-compile
 269   (defconst gnus-agent-parameters
 270     '((agent-predicate
 271        (sexp :tag "Selection Predicate" :value false)
 272        "Predicate used to automatically select articles for downloading."
 273        gnus-agent-cat-predicate)
 274       (agent-score
 275        (choice :tag "Score File" :value nil
 276                (const file :tag "Use group's score files")
 277                (repeat (list (string :format "%v" :tag "File name"))))
 278        "Which score files to use when using score to select articles to fetch.
 279
 280     `nil'
 281          All articles will be scored to zero (0).
 282
 283     `file'
 284          The group's score files will be used to score the articles.
 285
 286     `List'
 287          A list of score file names."
 288        gnus-agent-cat-score-file)
 289       (agent-short-article
 290        (integer :tag "Max Length of Short Article" :value "")
 291        "The SHORT predicate will evaluate to true when the article is
 292 shorter than this length."  gnus-agent-cat-length-when-short)
 293       (agent-long-article
 294        (integer :tag "Min Length of Long Article" :value "")
 295        "The LONG predicate will evaluate to true when the article is
 296 longer than this length."  gnus-agent-cat-length-when-long)
 297       (agent-low-score
 298        (integer :tag "Low Score Limit" :value "")
 299        "The LOW predicate will evaluate to true when the article scores
 300 lower than this limit."  gnus-agent-cat-low-score)
 301       (agent-high-score
 302        (integer :tag "High Score Limit" :value "")
 303        "The HIGH predicate will evaluate to true when the article scores
 304 higher than this limit."  gnus-agent-cat-high-score)
 305       (agent-days-until-old
 306        (integer :tag "Days Until Old" :value "")
 307        "The OLD predicate will evaluate to true when the fetched article
 308 has been stored locally for at least this many days."
 309        gnus-agent-cat-days-until-old)
 310       (agent-enable-expiration
 311        (radio :tag "Expire in this Group or Topic" :value nil
 312 ;              (const :format "Inherit " nil)
 313               (const :format "Enable " ENABLE)
 314               (const :format "Disable " DISABLE))
 315        "\nEnable, or disable, agent expiration in this group or topic."
 316        gnus-agent-cat-enable-expiration) )
 317     "Alist of group parameters that are not also topic parameters.
 318
 319 Each entry has the form (NAME TYPE DOC), where NAME is the parameter
 320 itself (a symbol), TYPE is the parameters type (a sexp widget), and
 321 DOC is a documentation string for the parameter."))
 322
 323 (defvar gnus-custom-params)
 324 (defvar gnus-custom-method)
 325 (defvar gnus-custom-group)
 326 (defvar gnus-custom-topic)
 327
 328 (defun gnus-group-customize (group &optional topic)
 329   "Edit the group or topic on the current line."
 330   (interactive (list (gnus-group-group-name) (gnus-group-topic-name)))
 331   (let (info
 332         (types (mapcar (lambda (entry)
 333                          `(cons :format "%v%h\n"
 334                                 :doc ,(nth 2 entry)
 335                                 (const :format "" ,(nth 0 entry))
 336                                 ,(nth 1 entry)))
 337                        (append (reverse gnus-group-parameters-more)
 338                                gnus-group-parameters
 339                                (if group
 340                                    gnus-extra-group-parameters
 341                                  gnus-extra-topic-parameters))))
 342         (agent (mapcar (lambda (entry)
 343                          (let ((type (nth 1 entry))
 344                                vcons)
 345                            (if (listp type)
 346                                (setq type (copy-sequence type)))
 347
 348                            (setq vcons (cdr (memq :value type)))
 349
 350                            (if (symbolp (car vcons))
 351                                (condition-case nil
 352                                    (setcar vcons (symbol-value (car vcons)))
 353                                  (error)))
 354                            `(cons :format "%v%h\n"
 355                                   :doc ,(nth 2 entry)
 356                                   (const :format "" ,(nth 0 entry))
 357                                   ,type)))
 358                        (if gnus-agent
 359                            gnus-agent-parameters))))
 360     (unless (or group topic)
 361       (error "No group on current line"))
 362     (when (and group topic)
 363       (error "Both a group an topic on current line"))
 364     (unless (or topic (setq info (gnus-get-info group)))
 365       (error "Killed group; can't be edited"))
 366     ;; Ready.
 367     (gnus-kill-buffer (gnus-get-buffer-create "*Gnus Customize*"))
 368     (switch-to-buffer (gnus-get-buffer-create "*Gnus Customize*"))
 369     (gnus-custom-mode)
 370     (make-local-variable 'gnus-custom-group)
 371     (setq gnus-custom-group group)
 372     (make-local-variable 'gnus-custom-topic)
 373     (setq gnus-custom-topic topic)
 374     (buffer-disable-undo)
 375     (widget-insert "Customize the ")
 376     (if group
 377         (widget-create 'info-link
 378                        :help-echo "Push me to learn more."
 379                        :tag "group parameters"
 380                        "(gnus)Group Parameters")
 381       (widget-create 'info-link
 382                      :help-echo "Push me to learn more."
 383                      :tag  "topic parameters"
 384                      "(gnus)Topic Parameters"))
 385     (widget-insert " for <")
 386     (widget-insert (gnus-group-decoded-name (or group topic)))
 387     (widget-insert "> and press ")
 388     (widget-create 'push-button
 389                    :tag "done"
 390                    :help-echo "Push me when done customizing."
 391                    :action 'gnus-group-customize-done)
 392     (widget-insert ".\n\n")
 393     (make-local-variable 'gnus-custom-params)
 394
 395     (let* ((values (if group
 396                            (gnus-info-params info)
 397                          (gnus-topic-parameters topic))))
 398
 399       ;; The parameters in values may contain duplicates.  This is
 400       ;; normally OK as assq returns the first. However, right here
 401       ;; every duplicate ends up being displayed.  So, rather than
 402       ;; display them, remove them from the list.
 403
 404       (let (tmp)
 405         (setq values (gnus-copy-sequence values)
 406               tmp values)
 407
 408         (while tmp
 409           (setcdr tmp (delete-if (lambda (testing) (eq (caar tmp)
 410                                                        (car testing)))
 411                                  (cdr tmp)))
 412           (setq tmp (cdr tmp))))
 413
 414       (setq gnus-custom-params
 415             (apply 'widget-create 'group
 416                    :value values
 417                    (delq nil
 418                          (list `(set :inline t
 419                                      :greedy t
 420                                      :tag "Parameters"
 421                                      :format "%t:\n%h%v"
 422                                      :doc "\
 423 These special parameters are recognized by Gnus.
 424 Check the [ ] for the parameters you want to apply to this group or
 425 to the groups in this topic, then edit the value to suit your taste."
 426                                      ,@types)
 427                                (when gnus-agent
 428                                  `(set :inline t
 429                                        :greedy t
 430                                        :tag "Agent Parameters"
 431                                        :format "%t:\n%h%v"
 432                                        :doc "\ These agent parameters are
 433 recognized by Gnus.  They control article selection and expiration for
 434 use in the unplugged cache.  Check the [ ] for the parameters you want
 435 to apply to this group or to the groups in this topic, then edit the
 436 value to suit your taste.
 437
 438 For those interested, group parameters override topic parameters while
 439 topic parameters override agent category parameters.  Underlying
 440 category parameters are the customizable variables."  ,@agent))
 441                                '(repeat :inline t
 442                                         :tag "Variables"
 443                                         :format "%t:\n%h%v%i\n\n"
 444                                         :doc "\
 445 Set variables local to the group you are entering.
 446
 447 If you want to turn threading off in `news.answers', you could put
 448 `(gnus-show-threads nil)' in the group parameters of that group.
 449 `gnus-show-threads' will be made into a local variable in the summary
 450 buffer you enter, and the form nil will be `eval'ed there.
 451
 452 This can also be used as a group-specific hook function, if you'd
 453 like.  If you want to hear a beep when you enter a group, you could
 454 put something like `(dummy-variable (ding))' in the parameters of that
 455 group.  `dummy-variable' will be set to the result of the `(ding)'
 456 form, but who cares?"
 457                                         (list :format "%v" :value (nil nil)
 458                                               (symbol :tag "Variable")
 459                                               (sexp :tag
 460                                                     "Value")))
 461
 462                                '(repeat :inline t
 463                                         :tag "Unknown entries"
 464                                         sexp))))))
 465     (when group
 466       (widget-insert "\n\nYou can also edit the ")
 467       (widget-create 'info-link
 468                      :tag "select method"
 469                      :help-echo "Push me to learn more about select methods."
 470                      "(gnus)Select Methods")
 471       (widget-insert " for the group.\n")
 472       (setq gnus-custom-method
 473             (widget-create 'sexp
 474                            :tag "Method"
 475                            :value (gnus-info-method info))))
 476     (use-local-map widget-keymap)
 477     (widget-setup)
 478     (buffer-enable-undo)
 479     (goto-char (point-min))))
 480
 481 (defun gnus-group-customize-done (&rest ignore)
 482   "Apply changes and bury the buffer."
 483   (interactive)
 484   (if gnus-custom-topic
 485       (gnus-topic-set-parameters gnus-custom-topic
 486                                  (widget-value gnus-custom-params))
 487     (gnus-group-edit-group-done 'params gnus-custom-group
 488                                 (widget-value gnus-custom-params))
 489     (gnus-group-edit-group-done 'method gnus-custom-group
 490                                 (widget-value gnus-custom-method)))
 491   (bury-buffer))
 492
 493 ;;; Score Customization:
 494
 495 (defconst gnus-score-parameters
 496   '((mark (number :tag "Mark") "\
 497 The value of this entry should be a number.
 498 Any articles with a score lower than this number will be marked as read.")
 499
 500     (expunge (number :tag "Expunge") "\
 501 The value of this entry should be a number.
 502 Any articles with a score lower than this number will be removed from
 503 the summary buffer.")
 504
 505     (mark-and-expunge (number :tag "Mark-and-expunge") "\
 506 The value of this entry should be a number.
 507 Any articles with a score lower than this number will be marked as
 508 read and removed from the summary buffer.")
 509
 510     (thread-mark-and-expunge (number :tag "Thread-mark-and-expunge") "\
 511 The value of this entry should be a number.
 512 All articles that belong to a thread that has a total score below this
 513 number will be marked as read and removed from the summary buffer.
 514 `gnus-thread-score-function' says how to compute the total score
 515 for a thread.")
 516
 517     (files (repeat :inline t :tag "Files" file) "\
 518 The value of this entry should be any number of file names.
 519 These files are assumed to be score files as well, and will be loaded
 520 the same way this one was.")
 521
 522     (exclude-files (repeat :inline t :tag "Exclude-files" file) "\
 523 The clue of this entry should be any number of files.
 524 These files will not be loaded, even though they would normally be so,
 525 for some reason or other.")
 526
 527     (eval (sexp :tag "Eval" :value nil) "\
 528 The value of this entry will be `eval'el.
 529 This element will be ignored when handling global score files.")
 530
 531     (read-only (boolean :tag "Read-only" :value t) "\
 532 Read-only score files will not be updated or saved.
 533 Global score files should feature this atom.")
 534
 535     (orphan (number :tag "Orphan") "\
 536 The value of this entry should be a number.
 537 Articles that do not have parents will get this number added to their
 538 scores.  Imagine you follow some high-volume newsgroup, like
 539 `comp.lang.c'.  Most likely you will only follow a few of the threads,
 540 also want to see any new threads.
 541
 542 You can do this with the following two score file entries:
 543
 544      (orphan -500)
 545      (mark-and-expunge -100)
 546
 547 When you enter the group the first time, you will only see the new
 548 threads.  You then raise the score of the threads that you find
 549 interesting (with `I T' or `I S'), and ignore (`C y') the rest.
 550 Next time you enter the group, you will see new articles in the
 551 interesting threads, plus any new threads.
 552
 553 I.e.---the orphan score atom is for high-volume groups where there
 554 exist a few interesting threads which can't be found automatically
 555 by ordinary scoring rules.")
 556
 557     (adapt (choice :tag "Adapt"
 558                    (const t)
 559                    (const ignore)
 560                    (sexp :format "%v"
 561                          :hide-front-space t)) "\
 562 This entry controls the adaptive scoring.
 563 If it is t, the default adaptive scoring rules will be used.  If it
 564 is `ignore', no adaptive scoring will be performed on this group.  If
 565 it is a list, this list will be used as the adaptive scoring rules.
 566 If it isn't present, or is something other than t or `ignore', the
 567 default adaptive scoring rules will be used.  If you want to use
 568 adaptive scoring on most groups, you'd set `gnus-use-adaptive-scoring'
 569 to t, and insert an `(adapt ignore)' in the groups where you do not
 570 want adaptive scoring.  If you only want adaptive scoring in a few
 571 groups, you'd set `gnus-use-adaptive-scoring' to nil, and insert
 572 `(adapt t)' in the score files of the groups where you want it.")
 573
 574     (adapt-file (file :tag "Adapt-file") "\
 575 All adaptive score entries will go to the file named by this entry.
 576 It will also be applied when entering the group.  This atom might
 577 be handy if you want to adapt on several groups at once, using the
 578 same adaptive file for a number of groups.")
 579
 580     (local (repeat :tag "Local"
 581                    (group :value (nil nil)
 582                           (symbol :tag "Variable")
 583                           (sexp :tag "Value"))) "\
 584 The value of this entry should be a list of `(VAR VALUE)' pairs.
 585 Each VAR will be made buffer-local to the current summary buffer,
 586 and set to the value specified.  This is a convenient, if somewhat
 587 strange, way of setting variables in some groups if you don't like
 588 hooks much.")
 589     (touched (sexp :format "Touched\n") "Internal variable."))
 590   "Alist of valid symbolic score parameters.
 591
 592 Each entry has the form (NAME TYPE DOC), where NAME is the parameter
 593 itself (a symbol), TYPE is the parameters type (a sexp widget), and DOC is a
 594 documentation string for the parameter.")
 595
 596 (define-widget 'gnus-score-string 'group
 597   "Edit score entries for string-valued headers."
 598   :convert-widget 'gnus-score-string-convert)
 599
 600 (defun gnus-score-string-convert (widget)
 601   ;; Set args appropriately.
 602   (let* ((tag (widget-get widget :tag))
 603          (item `(const :format "" :value ,(downcase tag)))
 604          (match '(string :tag "Match"))
 605          (score '(choice :tag "Score"
 606                          (const :tag "default" nil)
 607                          (integer :format "%v"
 608                                   :hide-front-space t)))
 609          (expire '(choice :tag "Expire"
 610                           (const :tag "off" nil)
 611                           (integer :format "%v"
 612                                    :hide-front-space t)))
 613          (type '(choice :tag "Type"
 614                         :value s
 615                         ;; I should really create a forgiving :match
 616                         ;; function for each type below, that only
 617                         ;; looked at the first letter.
 618                         (const :tag "Regexp" r)
 619                         (const :tag "Regexp (fixed case)" R)
 620                         (const :tag "Substring" s)
 621                         (const :tag "Substring (fixed case)" S)
 622                         (const :tag "Exact" e)
 623                         (const :tag "Exact (fixed case)" E)
 624                         (const :tag "Word" w)
 625                         (const :tag "Word (fixed case)" W)
 626                         (const :tag "default" nil)))
 627          (group `(group ,match ,score ,expire ,type))
 628          (doc (concat (or (widget-get widget :doc)
 629                           (concat "Change score based on the " tag
 630                                   " header.\n"))
 631                       "
 632 You can have an arbitrary number of score entries for this header,
 633 each score entry has four elements:
 634
 635 1. The \"match element\".  This should be the string to look for in the
 636    header.
 637
 638 2. The \"score element\".  This number should be an integer in the
 639    neginf to posinf interval.  This number is added to the score
 640    of the article if the match is successful.  If this element is
 641    not present, the `gnus-score-interactive-default-score' number
 642    will be used instead.  This is 1000 by default.
 643
 644 3. The \"date element\".  This date says when the last time this score
 645    entry matched, which provides a mechanism for expiring the
 646    score entries.  It this element is not present, the score
 647    entry is permanent.  The date is represented by the number of
 648    days since December 31, 1 ce.
 649
 650 4. The \"type element\".  This element specifies what function should
 651    be used to see whether this score entry matches the article.
 652
 653    There are the regexp, as well as substring types, and exact match,
 654    and word match types.  If this element is not present, Gnus will
 655    assume that substring matching should be used.  There is case
 656    sensitive variants of all match types.")))
 657     (widget-put widget :args `(,item
 658                                (repeat :inline t
 659                                        :indent 0
 660                                        :tag ,tag
 661                                        :doc ,doc
 662                                        :format "%t:\n%h%v%i\n\n"
 663                                        (choice :format "%v"
 664                                                :value ("" nil nil s)
 665                                                ,group
 666                                                sexp)))))
 667   widget)
 668
 669 (define-widget 'gnus-score-integer 'group
 670   "Edit score entries for integer-valued headers."
 671   :convert-widget 'gnus-score-integer-convert)
 672
 673 (defun gnus-score-integer-convert (widget)
 674   ;; Set args appropriately.
 675   (let* ((tag (widget-get widget :tag))
 676          (item `(const :format "" :value ,(downcase tag)))
 677          (match '(integer :tag "Match"))
 678          (score '(choice :tag "Score"
 679                          (const :tag "default" nil)
 680                          (integer :format "%v"
 681                                   :hide-front-space t)))
 682          (expire '(choice :tag "Expire"
 683                           (const :tag "off" nil)
 684                           (integer :format "%v"
 685                                    :hide-front-space t)))
 686          (type '(choice :tag "Type"
 687                         :value <
 688                         (const <)
 689                         (const >)
 690                         (const =)
 691                         (const >=)
 692                         (const <=)))
 693          (group `(group ,match ,score ,expire ,type))
 694          (doc (concat (or (widget-get widget :doc)
 695                           (concat "Change score based on the " tag
 696                                   " header.")))))
 697     (widget-put widget :args `(,item
 698                                (repeat :inline t
 699                                        :indent 0
 700                                        :tag ,tag
 701                                        :doc ,doc
 702                                        :format "%t:\n%h%v%i\n\n"
 703                                        ,group))))
 704   widget)
 705
 706 (define-widget 'gnus-score-date 'group
 707   "Edit score entries for date-valued headers."
 708   :convert-widget 'gnus-score-date-convert)
 709
 710 (defun gnus-score-date-convert (widget)
 711   ;; Set args appropriately.
 712   (let* ((tag (widget-get widget :tag))
 713          (item `(const :format "" :value ,(downcase tag)))
 714          (match '(string :tag "Match"))
 715          (score '(choice :tag "Score"
 716                          (const :tag "default" nil)
 717                          (integer :format "%v"
 718                                   :hide-front-space t)))
 719          (expire '(choice :tag "Expire"
 720                           (const :tag "off" nil)
 721                           (integer :format "%v"
 722                                    :hide-front-space t)))
 723          (type '(choice :tag "Type"
 724                         :value regexp
 725                         (const regexp)
 726                         (const before)
 727                         (const at)
 728                         (const after)))
 729          (group `(group ,match ,score ,expire ,type))
 730          (doc (concat (or (widget-get widget :doc)
 731                           (concat "Change score based on the " tag
 732                                   " header."))
 733                       "
 734 For the Date header we have three kinda silly match types: `before',
 735 `at' and `after'.  I can't really imagine this ever being useful, but,
 736 like, it would feel kinda silly not to provide this function.  Just in
 737 case.  You never know.  Better safe than sorry.  Once burnt, twice
 738 shy.  Don't judge a book by its cover.  Never not have sex on a first
 739 date.  (I have been told that at least one person, and I quote,
 740 \"found this function indispensable\", however.)
 741
 742 A more useful match type is `regexp'.  With it, you can match the date
 743 string using a regular expression.  The date is normalized to ISO8601
 744 compact format first---`YYYYMMDDTHHMMSS'.  If you want to match all
 745 articles that have been posted on April 1st in every year, you could
 746 use `....0401.........' as a match string, for instance.  (Note that
 747 the date is kept in its original time zone, so this will match
 748 articles that were posted when it was April 1st where the article was
 749 posted from.  Time zones are such wholesome fun for the whole family,
 750 eh?")))
 751     (widget-put widget :args `(,item
 752                                (repeat :inline t
 753                                        :indent 0
 754                                        :tag ,tag
 755                                        :doc ,doc
 756                                        :format "%t:\n%h%v%i\n\n"
 757                                        ,group))))
 758   widget)
 759
 760 (defvar gnus-custom-scores)
 761 (defvar gnus-custom-score-alist)
 762
 763 (defun gnus-score-customize (file)
 764   "Customize score file FILE.
 765 When called interactively, FILE defaults to the current score file.
 766 This can be changed using the `\\[gnus-score-change-score-file]' command."
 767   (interactive (list gnus-current-score-file))
 768   (unless file
 769     (error (format "No score file for %s"
 770                    (gnus-group-decoded-name gnus-newsgroup-name))))
 771   (let ((scores (gnus-score-load file))
 772         (types (mapcar (lambda (entry)
 773                          `(group :format "%v%h\n"
 774                                  :doc ,(nth 2 entry)
 775                                  (const :format "" ,(nth 0 entry))
 776                                  ,(nth 1 entry)))
 777                        gnus-score-parameters)))
 778     ;; Ready.
 779     (kill-buffer (gnus-get-buffer-create "*Gnus Customize*"))
 780     (switch-to-buffer (gnus-get-buffer-create "*Gnus Customize*"))
 781     (gnus-custom-mode)
 782     (make-local-variable 'gnus-custom-score-alist)
 783     (setq gnus-custom-score-alist scores)
 784     (widget-insert "Customize the ")
 785     (widget-create 'info-link
 786                    :help-echo "Push me to learn more."
 787                    :tag "score entries"
 788                    "(gnus)Score File Format")
 789     (widget-insert " for\n\t")
 790     (widget-insert file)
 791     (widget-insert "\nand press ")
 792     (widget-create 'push-button
 793                    :tag "done"
 794                    :help-echo "Push me when done customizing."
 795                    :action 'gnus-score-customize-done)
 796     (widget-insert ".\n
 797 Check the [ ] for the entries you want to apply to this score file, then
 798 edit the value to suit your taste.  Don't forget to mark the checkbox,
 799 if you do all your changes will be lost.  ")
 800     (widget-create 'push-button
 801                    :action (lambda (&rest ignore)
 802                              (require 'gnus-audio)
 803                              (gnus-audio-play "Evil_Laugh.au"))
 804                    "Bhahahah!")
 805     (widget-insert "\n\n")
 806     (make-local-variable 'gnus-custom-scores)
 807     (setq gnus-custom-scores
 808           (widget-create 'group
 809                          :value scores
 810                          `(checklist :inline t
 811                                      :greedy t
 812                                      (gnus-score-string :tag "From")
 813                                      (gnus-score-string :tag "Subject")
 814                                      (gnus-score-string :tag "References")
 815                                      (gnus-score-string :tag "Xref")
 816                                      (gnus-score-string :tag "Extra")
 817                                      (gnus-score-string :tag "Message-ID")
 818                                      (gnus-score-integer :tag "Lines")
 819                                      (gnus-score-integer :tag "Chars")
 820                                      (gnus-score-date :tag "Date")
 821                                      (gnus-score-string :tag "Head"
 822                                                         :doc "\
 823 Match all headers in the article.
 824
 825 Using one of `Head', `Body', `All' will slow down scoring considerable.
 826 ")
 827                                      (gnus-score-string :tag "Body"
 828                                                         :doc "\
 829 Match the body sans header of the article.
 830
 831 Using one of `Head', `Body', `All' will slow down scoring considerable.
 832 ")
 833                                      (gnus-score-string :tag "All"
 834                                                         :doc "\
 835 Match the entire article, including both headers and body.
 836
 837 Using one of `Head', `Body', `All' will slow down scoring
 838 considerable.
 839 ")
 840                                      (gnus-score-string :tag
 841                                                         "Followup"
 842                                                         :doc "\
 843 Score all followups to the specified authors.
 844
 845 This entry is somewhat special, in that it will match the `From:'
 846 header, and affect the score of not only the matching articles, but
 847 also all followups to the matching articles.  This allows you
 848 e.g. increase the score of followups to your own articles, or decrease
 849 the score of followups to the articles of some known trouble-maker.
 850 ")
 851                                      (gnus-score-string :tag "Thread"
 852                                                         :doc "\
 853 Add a score entry on all articles that are part of a thread.
 854
 855 This match key works along the same lines as the `Followup' match key.
 856 If you say that you want to score on a (sub-)thread that is started by
 857 an article with a `Message-ID' X, then you add a `thread' match.  This
 858 will add a new `thread' match for each article that has X in its
 859 `References' header.  (These new `thread' matches will use the
 860 `Message-ID's of these matching articles.)  This will ensure that you
 861 can raise/lower the score of an entire thread, even though some
 862 articles in the thread may not have complete `References' headers.
 863 Note that using this may lead to undeterministic scores of the
 864 articles in the thread.
 865 ")
 866                                      ,@types)
 867                          '(repeat :inline t
 868                                   :tag "Unknown entries"
 869                                   sexp)))
 870     (use-local-map widget-keymap)
 871     (widget-setup)))
 872
 873 (defun gnus-score-customize-done (&rest ignore)
 874   "Reset the score alist with the present value."
 875   (let ((alist gnus-custom-score-alist)
 876         (value (widget-value gnus-custom-scores)))
 877     (setcar alist (car value))
 878     (setcdr alist (cdr value))
 879     (gnus-score-set 'touched '(t) alist))
 880   (bury-buffer))
 881
 882 (eval-when-compile
 883   (defvar category-fields nil)
 884   (defvar gnus-agent-cat-predicate nil)
 885   (defvar gnus-agent-cat-score-file nil)
 886   (defvar gnus-agent-cat-length-when-short nil)
 887   (defvar gnus-agent-cat-length-when-long nil)
 888   (defvar gnus-agent-cat-low-score nil)
 889   (defvar gnus-agent-cat-high-score nil)
 890   (defvar gnus-agent-cat-groups nil)
 891   (defvar gnus-agent-cat-enable-expiration nil)
 892   (defvar gnus-agent-cat-days-until-old nil)
 893   (defvar gnus-agent-cat-name nil)
 894 )
 895
 896 (defun gnus-trim-whitespace (s)
 897   (when (string-match "\\`[ \n\t]+" s)
 898     (setq s (substring s (match-end 0))))
 899   (when (string-match "[ \n\t]+\\'" s)
 900     (setq s (substring s 0 (match-beginning 0))))
 901   s)
 902
 903 (defmacro gnus-agent-cat-prepare-category-field (parameter)
 904   (let* ((entry (assq parameter gnus-agent-parameters))
 905          (field (nth 3 entry)))
 906     `(let* ((type (copy-sequence
 907                    (nth 1 (assq ',parameter gnus-agent-parameters))))
 908             (val (,field info))
 909             (deflt (if (,field defaults)
 910                        (concat " [" (gnus-trim-whitespace
 911                                      (pp-to-string (,field defaults))) "]"))))
 912
 913        (if (eq (car type) 'radio)
 914            (let* ((rtype (nreverse type))
 915                   (rt rtype))
 916              (while (listp (or (cadr rt) 'not-list))
 917                (setq rt (cdr rt)))
 918
 919              (setcdr rt (cons '(const :format "Inherit " nil) (cdr rt)))
 920              (setq type (nreverse rtype))))
 921
 922        (if deflt
 923            (let ((tag (cdr (memq :tag type))))
 924              (if (string-match "\n" deflt)
 925                  (progn (while (progn (setq deflt (replace-match "\n " t t
 926                                                                  deflt))
 927                                       (string-match "\n" deflt (match-end 0))))
 928                         (setq deflt (concat "\n" deflt))))
 929
 930              (setcar tag (concat (car tag) deflt))))
 931
 932        (widget-insert "\n")
 933
 934        (set (make-local-variable ',field)
 935             (if val
 936                 (widget-create type :value val)
 937               (widget-create type)))
 938        (widget-put ,field :default val)
 939        (widget-put ,field :accessor ',field)
 940        (push ,field category-fields))))
 941
 942 (defun gnus-agent-customize-category (category)
 943   "Edit the CATEGORY."
 944   (interactive (list (gnus-category-name)))
 945   (let ((info (assq category gnus-category-alist))
 946         (defaults (list nil '(agent-predicate . false)
 947                         (cons 'agent-enable-expiration
 948                               gnus-agent-enable-expiration)
 949                         '(agent-days-until-old . 7)
 950                         (cons 'agent-length-when-short
 951                               gnus-agent-short-article)
 952                         (cons 'agent-length-when-long gnus-agent-long-article)
 953                         (cons 'agent-low-score gnus-agent-low-score)
 954                         (cons 'agent-high-score gnus-agent-high-score))))
 955
 956     (let ((old (get-buffer "*Gnus Agent Category Customize*")))
 957       (when old
 958         (gnus-kill-buffer old)))
 959     (switch-to-buffer (gnus-get-buffer-create
 960                        "*Gnus Agent Category Customize*"))
 961
 962     (let ((inhibit-read-only t))
 963       (gnus-custom-mode)
 964       (buffer-disable-undo)
 965
 966       (let* ((name (gnus-agent-cat-name info)))
 967         (widget-insert "Customize the Agent Category '")
 968         (widget-insert (symbol-name name))
 969         (widget-insert "' and press ")
 970         (widget-create
 971          'push-button
 972          :notify
 973          '(lambda (&rest ignore)
 974             (let* ((info (assq gnus-agent-cat-name gnus-category-alist))
 975                    (widgets category-fields))
 976               (while widgets
 977                 (let* ((widget (pop widgets))
 978                        (value (ignore-errors (widget-value widget))))
 979                   (eval `(setf (,(widget-get widget :accessor) ',info)
 980                                ',value)))))
 981             (gnus-category-write)
 982             (gnus-kill-buffer (current-buffer))
 983             (when (get-buffer gnus-category-buffer)
 984               (switch-to-buffer (get-buffer gnus-category-buffer))
 985               (gnus-category-list)))
 986                        "Done")
 987         (widget-insert
 988          "\n    Note: Empty fields default to the customizable global\
 989  variables.\n\n")
 990
 991         (set (make-local-variable 'gnus-agent-cat-name)
 992              name))
 993
 994       (set (make-local-variable 'category-fields) nil)
 995       (gnus-agent-cat-prepare-category-field agent-predicate)
 996
 997       (gnus-agent-cat-prepare-category-field agent-score)
 998       (gnus-agent-cat-prepare-category-field agent-short-article)
 999       (gnus-agent-cat-prepare-category-field agent-long-article)
1000       (gnus-agent-cat-prepare-category-field agent-low-score)
1001       (gnus-agent-cat-prepare-category-field agent-high-score)
1002
1003       ;; The group list is NOT handled with
1004       ;; gnus-agent-cat-prepare-category-field as I don't want the
1005       ;; group list to appear when customizing a topic.
1006       (widget-insert "\n")
1007       (set (make-local-variable 'gnus-agent-cat-groups)
1008            (widget-create
1009             `(choice
1010               :format "%[Select Member Groups%]\n%v" :value ignore
1011               (const :menu-tag "do not change" :tag "" :value ignore)
1012               (checklist :entry-format "%b %v"
1013                          :menu-tag "display group selectors"
1014                          :greedy t
1015                          :value ,(delq nil
1016                                        (mapcar
1017                                         (lambda (newsrc)
1018                                           (car (member
1019                                                 (gnus-info-group newsrc)
1020                                                 (gnus-agent-cat-groups info))))
1021                                         (cdr gnus-newsrc-alist)))
1022                          ,@(mapcar (lambda (newsrc)
1023                                      `(const ,(gnus-info-group newsrc)))
1024                                    (cdr gnus-newsrc-alist))))))
1025
1026       (widget-put gnus-agent-cat-groups :default (gnus-agent-cat-groups info))
1027       (widget-put gnus-agent-cat-groups :accessor 'gnus-agent-cat-groups)
1028       (push gnus-agent-cat-groups category-fields)
1029
1030       (widget-insert "\nExpiration Settings ")
1031
1032       (gnus-agent-cat-prepare-category-field agent-enable-expiration)
1033       (gnus-agent-cat-prepare-category-field agent-days-until-old)
1034
1035       (use-local-map widget-keymap)
1036       (widget-setup)
1037       (buffer-enable-undo))))
1038
1039 ;;; The End:
1040
1041 (provide 'gnus-cus)
1042
1043 ;;; gnus-cus.el ends here