cgit.sxemacs.org Git - gnus/blob - lisp/gnus-cache.el

   1 ;;; gnus-cache.el --- cache interface for Gnus
   2 ;; Copyright (C) 1995 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'gnus)
  28
  29 (defvar gnus-cache-directory (concat gnus-article-save-directory "cache/")
  30   "*The directory where cached articles will be stored.")
  31
  32 (defvar gnus-cache-enter-articles '(ticked dormant)
  33   "*Classes of articles to enter into the cache.")
  34
  35 (defvar gnus-cache-remove-articles '(read)
  36   "*Classes of articles to remove from the cache.")
  37
  38 \f
  39
  40 (defvar gnus-cache-buffer nil)
  41
  42 \f
  43
  44 (defun gnus-cache-change-buffer (group)
  45   (save-excursion
  46     (cond ((null gnus-cache-buffer)
  47            ;; No current cache, so we create and init the buffer.
  48            (setq gnus-cache-buffer
  49                  (cons group (get-buffer-create " *gnus-cache-overview*")))
  50            (set-buffer (cdr gnus-cache-buffer))
  51            (buffer-disable-undo (current-buffer))
  52            (erase-buffer)
  53            (gnus-add-current-to-buffer-list)
  54            (let ((file (gnus-cache-file-name group ".overview")))
  55              (and (file-exists-p file)
  56                   (insert-file-contents file))))
  57           ((not (string= group (car gnus-cache-buffer)))
  58            ;; If a different overview cache is the current, we
  59            ;; (possibly) save it and change to this groups.
  60            (set-buffer (cdr gnus-cache-buffer))
  61            (and (buffer-modified-p)
  62                 (write-region (point-min) (point-max)
  63                               (gnus-cache-file-name
  64                                (car gnus-cache-buffer) ".overview")
  65                               nil 'quiet))
  66            (erase-buffer)
  67            (setcar gnus-cache-buffer group)
  68            (let ((file (gnus-cache-file-name group ".overview")))
  69              (and (file-exists-p file)
  70                   (insert-file-contents file)))))))
  71
  72
  73 ;; Just save the overview buffer.
  74 (defun gnus-cache-save-buffers ()
  75   (and gnus-cache-buffer
  76        (save-excursion
  77          (set-buffer (cdr gnus-cache-buffer))
  78          (and (buffer-modified-p)
  79               (write-region (point-min) (point-max)
  80                             (gnus-cache-file-name (car gnus-cache-buffer)
  81                                                   ".overview")
  82                             nil 'quiet))))
  83   (setq gnus-cache-buffer nil))
  84
  85 ;; Return whether an article is a member of a class.
  86 (defun gnus-cache-member-of-class (class ticked dormant unread)
  87   (or (and ticked (memq 'ticked class))
  88       (and dormant (memq 'dormant class))
  89       (and unread (memq 'unread class))
  90       (and (not unread) (memq 'read class))))
  91
  92 (defun gnus-cache-file-name (group article)
  93   (concat (file-name-as-directory gnus-cache-directory)
  94           (if (gnus-use-long-file-name 'not-cache)
  95               group (gnus-replace-chars-in-string group ?. ?/))
  96           "/" (if (stringp article) article (int-to-string article))))
  97
  98 (defun gnus-cache-possibly-enter-article
  99   (group article headers ticked dormant unread)
 100   (let ((number (header-number headers))
 101         file dir)
 102     (if (or (not (gnus-cache-member-of-class
 103                   gnus-cache-enter-articles ticked dormant unread))
 104             (file-exists-p (setq file (gnus-cache-file-name group article))))
 105         ()
 106       ;; Possibly create the cache directory.
 107       (or (file-exists-p (setq dir (file-name-directory file)))
 108           (gnus-make-directory dir))
 109       ;; Save the article in the cache.
 110       (if (file-exists-p file)
 111           t ; The article already is saved, so we end here.
 112         (gnus-summary-select-article)
 113         (save-excursion
 114           (set-buffer gnus-article-buffer)
 115           (write-region (point-min) (point-max) file nil 'quiet)
 116           (gnus-cache-change-buffer group)
 117           (set-buffer (cdr gnus-cache-buffer))
 118           (goto-char (point-max))
 119           (forward-line -1)
 120           (while (and (not (bobp))
 121                       (> (read (current-buffer)) number))
 122             (forward-line -1))
 123           (if (bobp)
 124               (if (not (eobp))
 125                   (progn
 126                     (beginning-of-line)
 127                     (if (< (read (current-buffer)) number)
 128                         (forward-line 1)))
 129                 (beginning-of-line))
 130             (forward-line 1))
 131           (beginning-of-line)
 132           ;; [number subject from date id references chars lines xref]
 133           (insert (format "%s\t%s\t%s\t%s\t%s\t%s\t%s\t%s\t%s\t\n"
 134                           (header-number headers)
 135                           (header-subject headers)
 136                           (header-from headers)
 137                           (header-date headers)
 138                           (header-id headers)
 139                           (or (header-references headers) "")
 140                           (or (header-chars headers) "")
 141                           (or (header-lines headers) "")
 142                           (or (header-xref headers) ""))))
 143         t))))
 144
 145 (defvar gnus-cache-removeable-articles nil)
 146
 147 (defun gnus-cache-enter-remove-article (article)
 148   (setq gnus-cache-removeable-articles
 149         (cons article gnus-cache-removeable-articles)))
 150
 151 (defun gnus-cache-possibly-remove-articles ()
 152   (let ((articles gnus-cache-removeable-articles)
 153         article)
 154     (while articles
 155       (setq article (car articles)
 156             articles (cdr articles))
 157       (gnus-cache-possibly-remove-article
 158        gnus-newsgroup-name article
 159        (memq article gnus-newsgroup-marked)
 160        (memq article gnus-newsgroup-dormant)
 161        (or (memq article gnus-newsgroup-unreads)
 162            (memq article gnus-newsgroup-unselected))))))
 163
 164 (defun gnus-cache-possibly-remove-article
 165   (group article ticked dormant unread)
 166   (let ((file (gnus-cache-file-name group article)))
 167     (if (or (not (file-exists-p file))
 168             (not (gnus-cache-member-of-class
 169                   gnus-cache-remove-articles ticked dormant unread)))
 170         nil
 171       (save-excursion
 172         (delete-file file)
 173         (gnus-cache-change-buffer group)
 174         (set-buffer (cdr gnus-cache-buffer))
 175         (goto-char (point-min))
 176         (if (or (looking-at (concat (int-to-string article) "\t"))
 177                 (search-forward (concat "\n" (int-to-string article) "\t")))
 178             (delete-region (progn (beginning-of-line) (point))
 179                            (progn (forward-line 1) (point))))))))
 180
 181 (defun gnus-cache-request-article (article group)
 182   (let ((file (gnus-cache-file-name group article)))
 183     (if (not (file-exists-p file))
 184         ()
 185       (erase-buffer)
 186       (insert-file-contents file)
 187       t)))
 188
 189 (defun gnus-cache-articles-in-group (group)
 190   (let ((dir (file-name-directory (gnus-cache-file-name group 1)))
 191         articles)
 192     (if (not (file-exists-p dir))
 193         nil
 194       (setq articles (directory-files dir nil "^[0-9]+$" t))
 195       (if (not articles)
 196           nil
 197         (sort (mapcar (function (lambda (name)
 198                                   (string-to-int name)))
 199                       articles)
 200               '<)))))
 201
 202 (defun gnus-cache-active-articles (group)
 203   (let ((articles (gnus-cache-articles-in-group group)))
 204     (and articles
 205          (cons (car articles) (gnus-last-element articles)))))
 206
 207 (defun gnus-cache-possibly-alter-active (group active)
 208   (let ((cache-active (gnus-cache-active-articles group)))
 209     (and cache-active (< (car cache-active) (car active))
 210          (setcar active (car cache-active)))
 211     (and cache-active (> (cdr cache-active) (cdr active))
 212          (setcdr active (cdr cache-active)))))
 213
 214 (defun gnus-cache-retrieve-headers (articles group)
 215   (let* ((cached (gnus-cache-articles-in-group group))
 216          (articles (gnus-sorted-complement articles cached))
 217          (cache-file (gnus-cache-file-name group ".overview"))
 218          type)
 219     (let ((gnus-use-cache nil))
 220       (setq type (and articles (gnus-retrieve-headers articles group))))
 221     (gnus-cache-save-buffers)
 222     (save-excursion
 223       (cond ((not (file-exists-p cache-file))
 224              type)
 225             ((null type)
 226              (set-buffer nntp-server-buffer)
 227              (erase-buffer)
 228              (insert-file-contents cache-file)
 229              'nov)
 230             ((eq type 'nov)
 231              (gnus-cache-braid-nov group cached)
 232              type)
 233             (t
 234              (gnus-cache-braid-heads group cached)
 235              type)))))
 236
 237 (defun gnus-cache-braid-nov (group cached)
 238   (let ((cache-buf (get-buffer-create " *gnus-cache*"))
 239         beg end)
 240     (gnus-cache-save-buffers)
 241     (save-excursion
 242       (set-buffer cache-buf)
 243       (buffer-disable-undo (current-buffer))
 244       (erase-buffer)
 245       (insert-file-contents (gnus-cache-file-name group ".overview"))
 246       (goto-char (point-min))
 247       (insert "\n")
 248       (goto-char (point-min)))
 249     (set-buffer nntp-server-buffer)
 250     (goto-char (point-min))
 251     (while cached
 252       (while (and (not (eobp))
 253                   (< (read (current-buffer)) (car cached)))
 254         (forward-line 1))
 255       (beginning-of-line)
 256       (save-excursion
 257         (set-buffer cache-buf)
 258         (if (search-forward (concat "\n" (int-to-string (car cached)) "\t")
 259                             nil t)
 260             (setq beg (progn (beginning-of-line) (point))
 261                   end (progn (forward-line 1) (point)))
 262           (setq beg nil)))
 263       (and beg (insert-buffer-substring cache-buf beg end))
 264       (setq cached (cdr cached)))
 265     (kill-buffer cache-buf)))
 266
 267 (defun gnus-cache-braid-heads (group cached)
 268   (let ((cache-buf (get-buffer-create " *gnus-cache*")))
 269     (save-excursion
 270       (set-buffer cache-buf)
 271       (buffer-disable-undo (current-buffer))
 272       (erase-buffer))
 273     (set-buffer nntp-server-buffer)
 274     (goto-char (point-min))
 275     (while cached
 276       (while (and (not (eobp))
 277                   (looking-at "2.. +\\([0-9]+\\) ")
 278                   (< (progn (goto-char (match-beginning 1))
 279                             (read (current-buffer)))
 280                      (car cached)))
 281         (search-forward "\n.\n" nil 'move))
 282       (beginning-of-line)
 283       (save-excursion
 284         (set-buffer cache-buf)
 285         (erase-buffer)
 286         (insert-file-contents (gnus-cache-file-name group (car cached)))
 287         (goto-char (point-min))
 288         (insert "220 " (int-to-string (car cached)) " Article retrieved.\n")
 289         (search-forward "\n\n" nil 'move)
 290         (delete-region (point) (point-max))
 291         (forward-char -1)
 292         (insert "."))
 293       (insert-buffer-substring cache-buf)
 294       (setq cached (cdr cached)))
 295     (kill-buffer cache-buf)))
 296
 297 (defun gnus-jog-cache ()
 298   "Go through all groups and put the articles into the cache."
 299   (interactive)
 300   (let ((newsrc (cdr gnus-newsrc-alist))
 301         (gnus-cache-enter-articles '(unread))
 302         (gnus-mark-article-hook nil)
 303         (gnus-expert-user t)
 304         (gnus-large-newsgroup nil))
 305     (while newsrc
 306       (gnus-summary-read-group (car (car newsrc)))
 307       (if (not (eq major-mode 'gnus-summary-mode))
 308           ()
 309         (while gnus-newsgroup-unreads
 310           (gnus-summary-select-article t t nil (car gnus-newsgroup-unreads))
 311           (setq gnus-newsgroup-unreads (cdr gnus-newsgroup-unreads)))
 312         (kill-buffer (current-buffer)))
 313       (setq newsrc (cdr newsrc)))))
 314
 315 (provide 'gnus-cache)
 316
 317 ;;; gnus-cache.el ends here