cgit.sxemacs.org Git - gnus/blob - lisp/gnus-cache.el

   1 ;;; gnus-cache.el --- cache interface for Gnus
   2 ;; Copyright (C) 1995 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'gnus)
  28
  29 (defvar gnus-cache-directory (concat gnus-article-save-directory "cache/")
  30   "*The directory where cached articles will be stored.")
  31
  32 (defvar gnus-cache-enter-articles '(ticked dormant)
  33   "*Classes of articles to enter into the cache.")
  34
  35 (defvar gnus-cache-remove-articles '(read)
  36   "*Classes of articles to remove from the cache.")
  37
  38 \f
  39
  40 (defvar gnus-cache-buffer nil)
  41
  42 \f
  43
  44 (defun gnus-cache-change-buffer (group)
  45   (and gnus-cache-buffer
  46        ;; see if the current group's overview cache has been loaded
  47        (or (string= group (car gnus-cache-buffer))
  48            ;; another overview cache is current, save it
  49            (gnus-cache-save-buffers)))
  50   ;; if gnus-cache buffer is nil, create it
  51   (or gnus-cache-buffer
  52       ;; create cache buffer
  53       (save-excursion
  54         (setq gnus-cache-buffer
  55               (cons group
  56                     (set-buffer (get-buffer-create " *gnus-cache-overview*"))))
  57         (buffer-disable-undo (current-buffer))
  58         ;; insert the contents of this groups cache overview
  59         (erase-buffer)
  60         (let ((file (gnus-cache-file-name group ".overview")))
  61           (and (file-exists-p file)
  62                (insert-file-contents file)))
  63         ;; we have a fresh (empty/just loaded) buffer,
  64         ;; mark it as unmodified to save a redundant write later.
  65         (set-buffer-modified-p nil))))
  66
  67
  68 (defun gnus-cache-save-buffers ()
  69   ;; save the overview buffer if it exists and has been modified
  70   ;; delete empty cache subdirectories
  71   (if (null gnus-cache-buffer)
  72       ()
  73     (let ((buffer (cdr gnus-cache-buffer))
  74           (overview-file (gnus-cache-file-name
  75                           (car gnus-cache-buffer) ".overview")))
  76       ;; write the overview only if it was modified
  77       (if (buffer-modified-p buffer)
  78           (save-excursion
  79             (set-buffer buffer)
  80             (if (> (buffer-size) 0)
  81                 ;; non-empty overview, write it out
  82                 (gnus-make-directory (file-name-directory overview-file))
  83                 (write-region (point-min) (point-max)
  84                               overview-file nil 'quietly)
  85               ;; empty overview file, remove it
  86               (and (file-exists-p overview-file)
  87                    (delete-file overview-file))
  88               ;; if possible, remove group's cache subdirectory
  89               (condition-case nil
  90                   ;; FIXME: we can detect the error type and warn the user
  91                   ;; of any inconsistencies (articles w/o nov entries?).
  92                   ;; for now, just be conservative...delete only if safe -- sj
  93                   (delete-directory (file-name-directory overview-file))
  94                 (error nil)))))
  95       ;; kill the buffer, it's either unmodified or saved
  96       (gnus-kill-buffer buffer)
  97       (setq gnus-cache-buffer nil))))
  98
  99
 100 ;; Return whether an article is a member of a class.
 101 (defun gnus-cache-member-of-class (class ticked dormant unread)
 102   (or (and ticked (memq 'ticked class))
 103       (and dormant (memq 'dormant class))
 104       (and unread (memq 'unread class))
 105       (and (not unread) (memq 'read class))))
 106
 107 (defun gnus-cache-file-name (group article)
 108   (concat (file-name-as-directory gnus-cache-directory)
 109           (if (gnus-use-long-file-name 'not-cache)
 110               group
 111             (let ((group (concat group "")))
 112               (if (string-match ":" group)
 113                   (aset group (match-beginning 0) ?/))
 114               (gnus-replace-chars-in-string group ?. ?/)))
 115           "/" (if (stringp article) article (int-to-string article))))
 116
 117 (defun gnus-cache-possibly-enter-article
 118   (group article headers ticked dormant unread)
 119   (let ((number (header-number headers))
 120         file dir)
 121     (if (or (not (vectorp headers)) ; This might be a dummy article.
 122             (not (gnus-cache-member-of-class
 123                   gnus-cache-enter-articles ticked dormant unread))
 124             (file-exists-p (setq file (gnus-cache-file-name group article))))
 125         () ; Do nothing.
 126       ;; Possibly create the cache directory.
 127       (or (file-exists-p (setq dir (file-name-directory file)))
 128           (gnus-make-directory dir))
 129       ;; Save the article in the cache.
 130       (if (file-exists-p file)
 131           t ; The article already is saved, so we end here.
 132         (gnus-summary-select-article)
 133         (save-excursion
 134           (set-buffer gnus-article-buffer)
 135           (save-restriction
 136             (widen)
 137             (write-region (point-min) (point-max) file nil 'quiet))
 138           (gnus-cache-change-buffer group)
 139           (set-buffer (cdr gnus-cache-buffer))
 140           (goto-char (point-max))
 141           (forward-line -1)
 142           (while (and (not (bobp))
 143                       (> (read (current-buffer)) number))
 144             (forward-line -1))
 145           (if (bobp)
 146               (if (not (eobp))
 147                   (progn
 148                     (beginning-of-line)
 149                     (if (< (read (current-buffer)) number)
 150                         (forward-line 1)))
 151                 (beginning-of-line))
 152             (forward-line 1))
 153           (beginning-of-line)
 154           ;; [number subject from date id references chars lines xref]
 155           (insert (format "%s\t%s\t%s\t%s\t%s\t%s\t%s\t%s\t%s\t\n"
 156                           (header-number headers)
 157                           (header-subject headers)
 158                           (header-from headers)
 159                           (header-date headers)
 160                           (header-id headers)
 161                           (or (header-references headers) "")
 162                           (or (header-chars headers) "")
 163                           (or (header-lines headers) "")
 164                           (or (header-xref headers) ""))))
 165         t))))
 166
 167 (defun gnus-cache-enter-remove-article (article)
 168   (setq gnus-cache-removeable-articles
 169         (cons article gnus-cache-removeable-articles)))
 170
 171 (defsubst gnus-cache-possibly-remove-article
 172   (article ticked dormant unread)
 173   (let ((file (gnus-cache-file-name gnus-newsgroup-name article)))
 174     (if (or (not (file-exists-p file))
 175             (not (gnus-cache-member-of-class
 176                   gnus-cache-remove-articles ticked dormant unread)))
 177         nil
 178       (save-excursion
 179         (delete-file file)
 180         (set-buffer (cdr gnus-cache-buffer))
 181         (goto-char (point-min))
 182         (if (or (looking-at (concat (int-to-string article) "\t"))
 183                 (search-forward (concat "\n" (int-to-string article) "\t")
 184                                 (point-max) t))
 185             (delete-region (progn (beginning-of-line) (point))
 186                            (progn (forward-line 1) (point))))))))
 187
 188 (defun gnus-cache-possibly-remove-articles ()
 189   (let ((articles gnus-cache-removeable-articles)
 190         (cache-articles (gnus-cache-articles-in-group gnus-newsgroup-name))
 191         article)
 192     (gnus-cache-change-buffer gnus-newsgroup-name)
 193     (while articles
 194       (setq article (car articles)
 195             articles (cdr articles))
 196       (if (memq article cache-articles)
 197           ;; The article was in the cache, so we see whether we are
 198           ;; supposed to remove it from the cache.
 199           (gnus-cache-possibly-remove-article
 200            article (memq article gnus-newsgroup-marked)
 201            (memq article gnus-newsgroup-dormant)
 202            (or (memq article gnus-newsgroup-unreads)
 203                (memq article gnus-newsgroup-unselected))))))
 204   ;; the overview file might have been modified, save it
 205   ;; safe because we're only called at group exit anyway
 206   (gnus-cache-save-buffers))
 207
 208
 209 (defun gnus-cache-request-article (article group)
 210   (let ((file (gnus-cache-file-name group article)))
 211     (if (not (file-exists-p file))
 212         ()
 213       (erase-buffer)
 214       (insert-file-contents file)
 215       t)))
 216
 217 (defun gnus-cache-articles-in-group (group)
 218   (let ((dir (file-name-directory (gnus-cache-file-name group 1)))
 219         articles)
 220     (if (not (file-exists-p dir))
 221         nil
 222       (setq articles (directory-files dir nil "^[0-9]+$" t))
 223       (if (not articles)
 224           nil
 225         (sort (mapcar (function (lambda (name)
 226                                   (string-to-int name)))
 227                       articles)
 228               '<)))))
 229
 230 (defun gnus-cache-active-articles (group)
 231   (let ((articles (gnus-cache-articles-in-group group)))
 232     (and articles
 233          (cons (car articles) (gnus-last-element articles)))))
 234
 235 (defun gnus-cache-possibly-alter-active (group active)
 236   (let ((cache-active (gnus-cache-active-articles group)))
 237     (and cache-active (< (car cache-active) (car active))
 238          (setcar active (car cache-active)))
 239     (and cache-active (> (cdr cache-active) (cdr active))
 240          (setcdr active (cdr cache-active)))))
 241
 242 (defun gnus-cache-retrieve-headers (articles group)
 243   (let* ((cached (gnus-cache-articles-in-group group))
 244          (articles (gnus-sorted-complement articles cached))
 245          (cache-file (gnus-cache-file-name group ".overview"))
 246          type)
 247     (let ((gnus-use-cache nil))
 248       (setq type (and articles (gnus-retrieve-headers articles group))))
 249     (gnus-cache-save-buffers)
 250     (save-excursion
 251       (cond ((not (file-exists-p cache-file))
 252              type)
 253             ((null type)
 254              (set-buffer nntp-server-buffer)
 255              (erase-buffer)
 256              (insert-file-contents cache-file)
 257              'nov)
 258             ((eq type 'nov)
 259              (gnus-cache-braid-nov group cached)
 260              type)
 261             (t
 262              (gnus-cache-braid-heads group cached)
 263              type)))))
 264
 265 (defun gnus-cache-braid-nov (group cached)
 266   (let ((cache-buf (get-buffer-create " *gnus-cache*"))
 267         beg end)
 268     (gnus-cache-save-buffers)
 269     (save-excursion
 270       (set-buffer cache-buf)
 271       (buffer-disable-undo (current-buffer))
 272       (erase-buffer)
 273       (insert-file-contents (gnus-cache-file-name group ".overview"))
 274       (goto-char (point-min))
 275       (insert "\n")
 276       (goto-char (point-min)))
 277     (set-buffer nntp-server-buffer)
 278     (goto-char (point-min))
 279     (while cached
 280       (while (and (not (eobp))
 281                   (< (read (current-buffer)) (car cached)))
 282         (forward-line 1))
 283       (beginning-of-line)
 284       (save-excursion
 285         (set-buffer cache-buf)
 286         (if (search-forward (concat "\n" (int-to-string (car cached)) "\t")
 287                             nil t)
 288             (setq beg (progn (beginning-of-line) (point))
 289                   end (progn (forward-line 1) (point)))
 290           (setq beg nil)))
 291       (and beg (insert-buffer-substring cache-buf beg end))
 292       (setq cached (cdr cached)))
 293     (kill-buffer cache-buf)))
 294
 295 (defun gnus-cache-braid-heads (group cached)
 296   (let ((cache-buf (get-buffer-create " *gnus-cache*")))
 297     (save-excursion
 298       (set-buffer cache-buf)
 299       (buffer-disable-undo (current-buffer))
 300       (erase-buffer))
 301     (set-buffer nntp-server-buffer)
 302     (goto-char (point-min))
 303     (while cached
 304       (while (and (not (eobp))
 305                   (looking-at "2.. +\\([0-9]+\\) ")
 306                   (< (progn (goto-char (match-beginning 1))
 307                             (read (current-buffer)))
 308                      (car cached)))
 309         (search-forward "\n.\n" nil 'move))
 310       (beginning-of-line)
 311       (save-excursion
 312         (set-buffer cache-buf)
 313         (erase-buffer)
 314         (insert-file-contents (gnus-cache-file-name group (car cached)))
 315         (goto-char (point-min))
 316         (insert "220 " (int-to-string (car cached)) " Article retrieved.\n")
 317         (search-forward "\n\n" nil 'move)
 318         (delete-region (point) (point-max))
 319         (forward-char -1)
 320         (insert "."))
 321       (insert-buffer-substring cache-buf)
 322       (setq cached (cdr cached)))
 323     (kill-buffer cache-buf)))
 324
 325 (defun gnus-jog-cache ()
 326   "Go through all groups and put the articles into the cache."
 327   (interactive)
 328   (let ((newsrc (cdr gnus-newsrc-alist))
 329         (gnus-cache-enter-articles '(unread))
 330         (gnus-mark-article-hook nil)
 331         (gnus-expert-user t)
 332         (gnus-large-newsgroup nil))
 333     (while newsrc
 334       (gnus-summary-read-group (car (car newsrc)))
 335       (if (not (eq major-mode 'gnus-summary-mode))
 336           ()
 337         (while gnus-newsgroup-unreads
 338           (gnus-summary-select-article t t nil (car gnus-newsgroup-unreads))
 339           (setq gnus-newsgroup-unreads (cdr gnus-newsgroup-unreads)))
 340         (kill-buffer (current-buffer)))
 341       (setq newsrc (cdr newsrc)))))
 342
 343 (provide 'gnus-cache)
 344
 345 ;;; gnus-cache.el ends here