cgit.sxemacs.org Git - gnus/blob - lisp/gnus-cache.el

   1 ;;; gnus-cache.el --- cache interface for Gnus
   2 ;; Copyright (C) 1995 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'gnus)
  28
  29 (defvar gnus-cache-directory (concat gnus-article-save-directory "cache/")
  30   "*The directory where cached articles will be stored.")
  31
  32 (defvar gnus-cache-enter-articles '(ticked dormant)
  33   "*Classes of articles to enter into the cache.")
  34
  35 (defvar gnus-cache-remove-articles '(read)
  36   "*Classes of articles to remove from the cache.")
  37
  38 \f
  39
  40 (defvar gnus-cache-buffer nil)
  41
  42 \f
  43
  44 (defun gnus-cache-change-buffer (group)
  45   (and gnus-cache-buffer
  46        ;; see if the current group's overview cache has been loaded
  47        (or (string= group (car gnus-cache-buffer))
  48            ;; another overview cache is current, save it
  49            (gnus-cache-save-buffers)))
  50   ;; if gnus-cache buffer is nil, create it
  51   (or gnus-cache-buffer
  52       ;; create cache buffer
  53       (save-excursion
  54         (setq gnus-cache-buffer
  55               (cons group
  56                     (set-buffer (get-buffer-create " *gnus-cache-overview*"))))
  57         (buffer-disable-undo (current-buffer))
  58         ;; insert the contents of this groups cache overview
  59         (erase-buffer)
  60         (let ((file (gnus-cache-file-name group ".overview")))
  61           (and (file-exists-p file)
  62                (insert-file-contents file)))
  63         ;; we have a fresh (empty/just loaded) buffer,
  64         ;; mark it as unmodified to save a redundant write later.
  65         (set-buffer-modified-p nil))))
  66
  67
  68 (defun gnus-cache-save-buffers ()
  69   ;; save the overview buffer if it exists and has been modified
  70   ;; delete empty cache subdirectories
  71   (if (null gnus-cache-buffer)
  72       ()
  73     (let ((buffer (cdr gnus-cache-buffer))
  74           (overview-file (gnus-cache-file-name
  75                           (car gnus-cache-buffer) ".overview")))
  76       ;; write the overview only if it was modified
  77       (if (buffer-modified-p buffer)
  78           (save-excursion
  79             (set-buffer buffer)
  80             (if (> (buffer-size) 0)
  81                 ;; non-empty overview, write it out
  82                 (gnus-make-directory (file-name-directory overview-file))
  83                 (write-region (point-min) (point-max)
  84                               overview-file nil 'quietly)
  85               ;; empty overview file, remove it
  86               (and (file-exists-p overview-file)
  87                    (delete-file overview-file))
  88               ;; if possible, remove group's cache subdirectory
  89               (condition-case nil
  90                   ;; FIXME: we can detect the error type and warn the user
  91                   ;; of any inconsistencies (articles w/o nov entries?).
  92                   ;; for now, just be conservative...delete only if safe -- sj
  93                   (delete-directory (file-name-directory overview-file))
  94                 (error nil)))))
  95       ;; kill the buffer, it's either unmodified or saved
  96       (gnus-kill-buffer buffer)
  97       (setq gnus-cache-buffer nil))))
  98
  99
 100 ;; Return whether an article is a member of a class.
 101 (defun gnus-cache-member-of-class (class ticked dormant unread)
 102   (or (and ticked (memq 'ticked class))
 103       (and dormant (memq 'dormant class))
 104       (and unread (memq 'unread class))
 105       (and (not unread) (memq 'read class))))
 106
 107 (defun gnus-cache-file-name (group article)
 108   (concat (file-name-as-directory gnus-cache-directory)
 109           (if (gnus-use-long-file-name 'not-cache)
 110               group (gnus-replace-chars-in-string group ?. ?/))
 111           "/" (if (stringp article) article (int-to-string article))))
 112
 113 (defun gnus-cache-possibly-enter-article
 114   (group article headers ticked dormant unread)
 115   (let ((number (header-number headers))
 116         file dir)
 117     (if (or (not (vectorp headers)) ; This might be a dummy article.
 118             (not (gnus-cache-member-of-class
 119                   gnus-cache-enter-articles ticked dormant unread))
 120             (file-exists-p (setq file (gnus-cache-file-name group article))))
 121         () ; Do nothing.
 122       ;; Possibly create the cache directory.
 123       (or (file-exists-p (setq dir (file-name-directory file)))
 124           (gnus-make-directory dir))
 125       ;; Save the article in the cache.
 126       (if (file-exists-p file)
 127           t ; The article already is saved, so we end here.
 128         (gnus-summary-select-article)
 129         (save-excursion
 130           (set-buffer gnus-article-buffer)
 131           (save-restriction
 132             (widen)
 133             (write-region (point-min) (point-max) file nil 'quiet))
 134           (gnus-cache-change-buffer group)
 135           (set-buffer (cdr gnus-cache-buffer))
 136           (goto-char (point-max))
 137           (forward-line -1)
 138           (while (and (not (bobp))
 139                       (> (read (current-buffer)) number))
 140             (forward-line -1))
 141           (if (bobp)
 142               (if (not (eobp))
 143                   (progn
 144                     (beginning-of-line)
 145                     (if (< (read (current-buffer)) number)
 146                         (forward-line 1)))
 147                 (beginning-of-line))
 148             (forward-line 1))
 149           (beginning-of-line)
 150           ;; [number subject from date id references chars lines xref]
 151           (insert (format "%s\t%s\t%s\t%s\t%s\t%s\t%s\t%s\t%s\t\n"
 152                           (header-number headers)
 153                           (header-subject headers)
 154                           (header-from headers)
 155                           (header-date headers)
 156                           (header-id headers)
 157                           (or (header-references headers) "")
 158                           (or (header-chars headers) "")
 159                           (or (header-lines headers) "")
 160                           (or (header-xref headers) ""))))
 161         t))))
 162
 163 (defun gnus-cache-enter-remove-article (article)
 164   (setq gnus-cache-removeable-articles
 165         (cons article gnus-cache-removeable-articles)))
 166
 167 (defsubst gnus-cache-possibly-remove-article
 168   (article ticked dormant unread)
 169   (let ((file (gnus-cache-file-name gnus-newsgroup-name article)))
 170     (if (or (not (file-exists-p file))
 171             (not (gnus-cache-member-of-class
 172                   gnus-cache-remove-articles ticked dormant unread)))
 173         nil
 174       (save-excursion
 175         (delete-file file)
 176         (set-buffer (cdr gnus-cache-buffer))
 177         (goto-char (point-min))
 178         (if (or (looking-at (concat (int-to-string article) "\t"))
 179                 (search-forward (concat "\n" (int-to-string article) "\t")
 180                                 (point-max) t))
 181             (delete-region (progn (beginning-of-line) (point))
 182                            (progn (forward-line 1) (point))))))))
 183
 184 (defun gnus-cache-possibly-remove-articles ()
 185   (let ((articles gnus-cache-removeable-articles)
 186         (cache-articles (gnus-cache-articles-in-group gnus-newsgroup-name))
 187         article)
 188     (gnus-cache-change-buffer gnus-newsgroup-name)
 189     (while articles
 190       (setq article (car articles)
 191             articles (cdr articles))
 192       (if (memq article cache-articles)
 193           ;; The article was in the cache, so we see whether we are
 194           ;; supposed to remove it from the cache.
 195           (gnus-cache-possibly-remove-article
 196            article (memq article gnus-newsgroup-marked)
 197            (memq article gnus-newsgroup-dormant)
 198            (or (memq article gnus-newsgroup-unreads)
 199                (memq article gnus-newsgroup-unselected))))))
 200   ;; the overview file might have been modified, save it
 201   ;; safe because we're only called at group exit anyway
 202   (gnus-cache-save-buffers))
 203
 204
 205 (defun gnus-cache-request-article (article group)
 206   (let ((file (gnus-cache-file-name group article)))
 207     (if (not (file-exists-p file))
 208         ()
 209       (erase-buffer)
 210       (insert-file-contents file)
 211       t)))
 212
 213 (defun gnus-cache-articles-in-group (group)
 214   (let ((dir (file-name-directory (gnus-cache-file-name group 1)))
 215         articles)
 216     (if (not (file-exists-p dir))
 217         nil
 218       (setq articles (directory-files dir nil "^[0-9]+$" t))
 219       (if (not articles)
 220           nil
 221         (sort (mapcar (function (lambda (name)
 222                                   (string-to-int name)))
 223                       articles)
 224               '<)))))
 225
 226 (defun gnus-cache-active-articles (group)
 227   (let ((articles (gnus-cache-articles-in-group group)))
 228     (and articles
 229          (cons (car articles) (gnus-last-element articles)))))
 230
 231 (defun gnus-cache-possibly-alter-active (group active)
 232   (let ((cache-active (gnus-cache-active-articles group)))
 233     (and cache-active (< (car cache-active) (car active))
 234          (setcar active (car cache-active)))
 235     (and cache-active (> (cdr cache-active) (cdr active))
 236          (setcdr active (cdr cache-active)))))
 237
 238 (defun gnus-cache-retrieve-headers (articles group)
 239   (let* ((cached (gnus-cache-articles-in-group group))
 240          (articles (gnus-sorted-complement articles cached))
 241          (cache-file (gnus-cache-file-name group ".overview"))
 242          type)
 243     (let ((gnus-use-cache nil))
 244       (setq type (and articles (gnus-retrieve-headers articles group))))
 245     (gnus-cache-save-buffers)
 246     (save-excursion
 247       (cond ((not (file-exists-p cache-file))
 248              type)
 249             ((null type)
 250              (set-buffer nntp-server-buffer)
 251              (erase-buffer)
 252              (insert-file-contents cache-file)
 253              'nov)
 254             ((eq type 'nov)
 255              (gnus-cache-braid-nov group cached)
 256              type)
 257             (t
 258              (gnus-cache-braid-heads group cached)
 259              type)))))
 260
 261 (defun gnus-cache-braid-nov (group cached)
 262   (let ((cache-buf (get-buffer-create " *gnus-cache*"))
 263         beg end)
 264     (gnus-cache-save-buffers)
 265     (save-excursion
 266       (set-buffer cache-buf)
 267       (buffer-disable-undo (current-buffer))
 268       (erase-buffer)
 269       (insert-file-contents (gnus-cache-file-name group ".overview"))
 270       (goto-char (point-min))
 271       (insert "\n")
 272       (goto-char (point-min)))
 273     (set-buffer nntp-server-buffer)
 274     (goto-char (point-min))
 275     (while cached
 276       (while (and (not (eobp))
 277                   (< (read (current-buffer)) (car cached)))
 278         (forward-line 1))
 279       (beginning-of-line)
 280       (save-excursion
 281         (set-buffer cache-buf)
 282         (if (search-forward (concat "\n" (int-to-string (car cached)) "\t")
 283                             nil t)
 284             (setq beg (progn (beginning-of-line) (point))
 285                   end (progn (forward-line 1) (point)))
 286           (setq beg nil)))
 287       (and beg (insert-buffer-substring cache-buf beg end))
 288       (setq cached (cdr cached)))
 289     (kill-buffer cache-buf)))
 290
 291 (defun gnus-cache-braid-heads (group cached)
 292   (let ((cache-buf (get-buffer-create " *gnus-cache*")))
 293     (save-excursion
 294       (set-buffer cache-buf)
 295       (buffer-disable-undo (current-buffer))
 296       (erase-buffer))
 297     (set-buffer nntp-server-buffer)
 298     (goto-char (point-min))
 299     (while cached
 300       (while (and (not (eobp))
 301                   (looking-at "2.. +\\([0-9]+\\) ")
 302                   (< (progn (goto-char (match-beginning 1))
 303                             (read (current-buffer)))
 304                      (car cached)))
 305         (search-forward "\n.\n" nil 'move))
 306       (beginning-of-line)
 307       (save-excursion
 308         (set-buffer cache-buf)
 309         (erase-buffer)
 310         (insert-file-contents (gnus-cache-file-name group (car cached)))
 311         (goto-char (point-min))
 312         (insert "220 " (int-to-string (car cached)) " Article retrieved.\n")
 313         (search-forward "\n\n" nil 'move)
 314         (delete-region (point) (point-max))
 315         (forward-char -1)
 316         (insert "."))
 317       (insert-buffer-substring cache-buf)
 318       (setq cached (cdr cached)))
 319     (kill-buffer cache-buf)))
 320
 321 (defun gnus-jog-cache ()
 322   "Go through all groups and put the articles into the cache."
 323   (interactive)
 324   (let ((newsrc (cdr gnus-newsrc-alist))
 325         (gnus-cache-enter-articles '(unread))
 326         (gnus-mark-article-hook nil)
 327         (gnus-expert-user t)
 328         (gnus-large-newsgroup nil))
 329     (while newsrc
 330       (gnus-summary-read-group (car (car newsrc)))
 331       (if (not (eq major-mode 'gnus-summary-mode))
 332           ()
 333         (while gnus-newsgroup-unreads
 334           (gnus-summary-select-article t t nil (car gnus-newsgroup-unreads))
 335           (setq gnus-newsgroup-unreads (cdr gnus-newsgroup-unreads)))
 336         (kill-buffer (current-buffer)))
 337       (setq newsrc (cdr newsrc)))))
 338
 339 (provide 'gnus-cache)
 340
 341 ;;; gnus-cache.el ends here