cgit.sxemacs.org Git - gnus/blob - lisp/gnus-async.el

   1 ;;; gnus-async.el --- asynchronous support for Gnus
   2 ;; Copyright (C) 1996 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus-load)
  29 (require 'gnus-sum)
  30 (require 'nntp)
  31
  32 (defvar gnus-asynchronous t
  33   "*If nil, inhibit all Gnus asynchronicity.
  34 If non-nil, let the other asynch variables be heeded.")
  35
  36 (defvar gnus-use-article-prefetch 30
  37   "*If non-nil, prefetch articles in groups that allow this.
  38 If a number, prefetch only that many articles forward;
  39 if t, prefetch as many articles as possible.")
  40
  41 (defvar gnus-prefetched-article-deletion-strategy '(read exit)
  42   "List of symbols that say when to remove articles from the prefetch buffer.
  43 Possible values in this list are `read', which means that
  44 articles are removed as they are read, and `exit', which means
  45 that all articles belonging to a group are removed on exit
  46 from that group.")
  47
  48 (defvar gnus-use-header-prefetch nil
  49   "*If non-nil, prefetch the headers to the next group.")
  50
  51 ;;; Internal variables.
  52
  53 (defvar gnus-async-prefetch-article-buffer " *Async Prefetch Article*")
  54 (defvar gnus-async-article-alist nil)
  55 (defvar gnus-async-article-semaphore '(nil))
  56 (defvar gnus-async-fetch-list nil)
  57
  58 (defvar gnus-async-prefetch-headers-buffer " *Async Prefetch Headers*")
  59 (defvar gnus-async-header-prefetched nil)
  60
  61 ;;; Utility functions.
  62
  63 (defun gnus-group-asynchronous-p (group)
  64   "Say whether GROUP is fetched from a server that supports asynchronocity."
  65   (gnus-asynchronous-p (gnus-find-method-for-group group)))
  66
  67 ;;; Somewhat bogus semaphores.
  68
  69 (defun gnus-async-get-semaphore (semaphore)
  70   "Wait until SEMAPHORE is released."
  71   (while (/= (length (nconc (symbol-value semaphore) (list nil))) 2)
  72     (sleep-for 1)))
  73
  74 (defun gnus-async-release-semaphore (semaphore)
  75   "Release SEMAPHORE."
  76   (setcdr (symbol-value semaphore) nil))
  77
  78 ;;;
  79 ;;; Article prefetch
  80 ;;;
  81
  82 (gnus-add-shutdown 'gnus-async-close 'gnus)
  83 (defun gnus-async-close ()
  84   (gnus-kill-buffer gnus-async-prefetch-article-buffer)
  85   (gnus-kill-buffer gnus-async-prefetch-headers-buffer)
  86   (setq gnus-async-article-alist nil
  87         gnus-async-header-prefetched nil))
  88
  89 (defun gnus-async-set-buffer ()
  90   (nnheader-set-temp-buffer gnus-async-prefetch-article-buffer t))
  91
  92 (defun gnus-async-prefetch-next (group article summary)
  93   "Possibly prefetch several articles starting with the article after ARTICLE."
  94   (when (gnus-buffer-live-p summary)
  95     (save-excursion
  96       (set-buffer gnus-summary-buffer)
  97       (let ((next (caadr (gnus-data-find-list article))))
  98         (when next
  99           (if (not (fboundp 'run-with-idle-timer))
 100               ;; This is either an older Emacs or XEmacs, so we
 101               ;; do this, which leads to slightly slower article
 102               ;; buffer display.
 103               (gnus-async-prefetch-article group next summary)
 104             (run-with-idle-timer
 105              0.1 nil 'gnus-async-prefetch-article group next summary)))))))
 106
 107 (defun gnus-async-prefetch-article (group article summary &optional next)
 108   "Possibly prefetch several articles starting with ARTICLE."
 109   (if (not (gnus-buffer-live-p summary))
 110       (progn
 111         (gnus-async-get-semaphore 'gnus-async-article-semaphore)
 112         (setq gnus-async-fetch-list nil)
 113         (gnus-async-release-semaphore 'gnus-async-article-semaphore))
 114     (when (and gnus-asynchronous
 115                (gnus-alive-p))
 116       (when next
 117         (gnus-async-get-semaphore 'gnus-async-article-semaphore)
 118         (pop gnus-async-fetch-list)
 119         (gnus-async-release-semaphore 'gnus-async-article-semaphore))
 120       (let ((do-fetch next))
 121         (when (and (gnus-group-asynchronous-p group)
 122                    (gnus-buffer-live-p summary)
 123                    (or (not next)
 124                        gnus-async-fetch-list))
 125           (unwind-protect
 126               (progn
 127                 (gnus-async-get-semaphore 'gnus-async-article-semaphore)
 128                 (unless next
 129                   (setq do-fetch (not gnus-async-fetch-list))
 130                   ;; Nix out any outstanding requests.
 131                   (setq gnus-async-fetch-list nil)
 132                   ;; Fill in the new list.
 133                   (let ((n gnus-use-article-prefetch)
 134                         (data (gnus-data-find-list article))
 135                         d)
 136                     (while (and (setq d (pop data))
 137                                 (if (numberp n)
 138                                     (natnump (decf n))
 139                                   n))
 140                       (unless (or (gnus-async-prefetched-article-entry
 141                                    group (setq article (gnus-data-number d)))
 142                                   (not (natnump article)))
 143                         ;; Not already fetched -- so we add it to the list.
 144                         (push article gnus-async-fetch-list)))
 145                     (setq gnus-async-fetch-list
 146                           (nreverse gnus-async-fetch-list))))
 147
 148                 (when do-fetch
 149                   (setq article (car gnus-async-fetch-list))))
 150
 151             (gnus-async-release-semaphore 'gnus-async-article-semaphore))
 152
 153           (when (and do-fetch article)
 154             ;; We want to fetch some more articles.
 155             (save-excursion
 156               (set-buffer summary)
 157               (let (mark)
 158                 (gnus-async-set-buffer)
 159                 (goto-char (point-max))
 160                 (setq mark (point-marker))
 161                 (let ((nnheader-callback-function
 162                        (gnus-make-async-article-function
 163                         group article mark summary next))
 164                       (nntp-server-buffer (get-buffer
 165                                            gnus-async-prefetch-article-buffer)))
 166                   (gnus-message 7 "Prefetching article %d in group %s"
 167                                 article group)
 168                   (gnus-request-article article group))))))))))
 169
 170 (defun gnus-make-async-article-function (group article mark summary next)
 171   "Return a callback function."
 172   `(lambda (arg)
 173      (save-excursion
 174        (gnus-async-set-buffer)
 175        (gnus-async-get-semaphore 'gnus-async-article-semaphore)
 176        (push (list ',(intern (format "%s-%d" group article))
 177                    ,mark (set-marker (make-marker)
 178                                      (point-max))
 179                    ,group ,article)
 180              gnus-async-article-alist)
 181        (gnus-async-release-semaphore
 182         'gnus-async-article-semaphore)
 183        (when (gnus-buffer-live-p ,summary)
 184          (gnus-async-prefetch-article
 185           ,group ,next ,summary t)))))
 186
 187 (defun gnus-async-request-fetched-article (group article buffer)
 188   "See whether we have ARTICLE from GROUP and put it in BUFFER."
 189   (when (numberp article)
 190     (let ((entry (gnus-async-prefetched-article-entry group article)))
 191       (when entry
 192         (save-excursion
 193           (gnus-async-set-buffer)
 194           (copy-to-buffer buffer (cadr entry) (caddr entry))
 195           ;; Remove the read article from the prefetch buffer.
 196           (when (memq 'read gnus-prefetched-article-deletion-strategy)
 197             (gnus-async-delete-prefected-entry entry))
 198           t)))))
 199
 200 (defun gnus-async-delete-prefected-entry (entry)
 201   "Delete ENTRY from buffer and alist."
 202   (delete-region (cadr entry) (caddr entry))
 203   (set-marker (cadr entry) nil)
 204   (set-marker (caddr entry) nil)
 205   (gnus-async-get-semaphore 'gnus-async-article-semaphore)
 206   (setq gnus-async-article-alist
 207         (delq entry gnus-async-article-alist))
 208   (gnus-async-release-semaphore 'gnus-async-article-semaphore))
 209
 210 (defun gnus-async-prefetch-remove-group (group)
 211   "Remove all articles belonging to GROUP from the prefetch buffer."
 212   (when (and (gnus-group-asynchronous-p group)
 213              (memq 'exit gnus-prefetched-article-deletion-strategy))
 214     (let ((alist gnus-async-article-alist))
 215       (save-excursion
 216         (gnus-async-set-buffer)
 217         (while alist
 218           (when (equal group (nth 3 (car alist)))
 219             (gnus-async-delete-prefected-entry (car alist)))
 220           (pop alist))))))
 221
 222 (defun gnus-async-prefetched-article-entry (group article)
 223   "Return the entry for ARTICLE in GROUP iff it has been prefetched."
 224   (assq (intern (format "%s-%d" group article))
 225         gnus-async-article-alist))
 226
 227 ;;;
 228 ;;; Header prefetch
 229 ;;;
 230
 231 (defun gnus-async-prefetch-headers (group)
 232   "Prefetch the headers for group GROUP."
 233   (save-excursion
 234     (let (unread)
 235       (when (and gnus-use-header-prefetch
 236                  gnus-asynchronous
 237                  (gnus-group-asynchronous-p group)
 238                  (listp gnus-async-header-prefetched)
 239                  (setq unread (gnus-list-of-unread-articles group)))
 240         ;; Mark that a fetch is in progress.
 241         (setq gnus-async-header-prefetched t)
 242         (nnheader-set-temp-buffer gnus-async-prefetch-headers-buffer t)
 243         (erase-buffer)
 244         (let ((nntp-server-buffer (current-buffer))
 245               (nnheader-callback-function
 246                `(lambda (arg)
 247                   (setq gnus-async-header-prefetched
 248                         ,(cons group unread)))))
 249           (gnus-retrieve-headers unread group gnus-fetch-old-headers))))))
 250
 251 (defun gnus-async-retrieve-fetched-headers (articles group)
 252   "See whether we have prefetched headers."
 253   (when (and gnus-use-header-prefetch
 254              (gnus-group-asynchronous-p group)
 255              (listp gnus-async-header-prefetched)
 256              (equal group (car gnus-async-header-prefetched))
 257              (equal articles (cdr gnus-async-header-prefetched)))
 258     (save-excursion
 259       (nnheader-set-temp-buffer gnus-async-prefetch-headers-buffer t)
 260       (nntp-decode-text)
 261       (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 262       (erase-buffer)
 263       (setq gnus-async-header-prefetched nil)
 264       t)))
 265
 266 (provide 'gnus-async)
 267
 268 ;;; gnus-async.el ends here