cgit.sxemacs.org Git - gnus/blob - lisp/dgnushack.el

   1 ;;; dgnushack.el --- a hack to set the load path for byte-compiling
   2 ;; Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2003,
   3 ;; 2004, 2005, 2006, 2007
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Version: 4.19
   8 ;; Keywords: news, path
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (defvar dgnushack-default-load-path (copy-sequence load-path))
  32
  33 (defalias 'facep 'ignore)
  34
  35 (require 'cl)
  36
  37 (defvar srcdir (or (getenv "srcdir") "."))
  38 (defvar loaddir (and load-file-name (file-name-directory load-file-name)))
  39
  40 (defun my-getenv (str)
  41   (let ((val (getenv str)))
  42     (if (equal val "no") nil val)))
  43
  44 (if (my-getenv "lispdir")
  45     (push (my-getenv "lispdir") load-path))
  46
  47 (push (or (my-getenv "URLDIR") (expand-file-name "../../url/lisp/" loaddir))
  48       load-path)
  49
  50 (push (or (my-getenv "W3DIR") (expand-file-name "../../w3/lisp/" loaddir))
  51       load-path)
  52
  53 ;(push "/usr/share/emacs/site-lisp" load-path)
  54
  55 ;; If we are building w3 in a different directory than the source
  56 ;; directory, we must read *.el from source directory and write *.elc
  57 ;; into the building directory.  For that, we define this function
  58 ;; before loading bytecomp.  Bytecomp doesn't overwrite this function.
  59 (defun byte-compile-dest-file (filename)
  60   "Convert an Emacs Lisp source file name to a compiled file name.
  61  In addition, remove directory name part from FILENAME."
  62   (setq filename (byte-compiler-base-file-name filename))
  63   (setq filename (file-name-sans-versions filename))
  64   (setq filename (file-name-nondirectory filename))
  65   (if (memq system-type '(win32 w32 mswindows windows-nt))
  66       (setq filename (downcase filename)))
  67   (cond ((eq system-type 'vax-vms)
  68          (concat (substring filename 0 (string-match ";" filename)) "c"))
  69         ((string-match emacs-lisp-file-regexp filename)
  70          (concat (substring filename 0 (match-beginning 0)) ".elc"))
  71         (t (concat filename ".elc"))))
  72
  73 (require 'bytecomp)
  74 ;; To avoid having defsubsts and inlines happen.
  75 ;(if (featurep 'xemacs)
  76 ;    (require 'byte-optimize)
  77 ;  (require 'byte-opt))
  78 ;(defun byte-optimize-inline-handler (form)
  79 ;  "byte-optimize-handler for the `inline' special-form."
  80 ;  (cons 'progn (cdr form)))
  81 ;(defalias 'byte-compile-file-form-defsubst 'byte-compile-file-form-defun)
  82
  83 (when (and (not (featurep 'xemacs))
  84            (= emacs-major-version 21)
  85            (>= emacs-minor-version 3)
  86            (condition-case code
  87                (let ((byte-compile-error-on-warn t))
  88                  (byte-optimize-form (quote (pop x)) t)
  89                  nil)
  90              (error (string-match "called for effect"
  91                                   (error-message-string code)))))
  92   (defadvice byte-optimize-form-code-walker (around silence-warn-for-pop
  93                                                     (form for-effect)
  94                                                     activate)
  95     "Silence the warning \"...called for effect\" for the `pop' form.
  96 It is effective only when the `pop' macro is defined by cl.el rather
  97 than subr.el."
  98     (let (tmp)
  99       (if (and (eq (car-safe form) 'car)
 100                for-effect
 101                (setq tmp (get 'car 'side-effect-free))
 102                (not byte-compile-delete-errors)
 103                (not (eq tmp 'error-free))
 104                (eq (car-safe (cadr form)) 'prog1)
 105                (let ((var (cadr (cadr form)))
 106                      (last (nth 2 (cadr form))))
 107                  (and (symbolp var)
 108                       (null (nthcdr 3 (cadr form)))
 109                       (eq (car-safe last) 'setq)
 110                       (eq (cadr last) var)
 111                       (eq (car-safe (nth 2 last)) 'cdr)
 112                       (eq (cadr (nth 2 last)) var))))
 113           (progn
 114             (put 'car 'side-effect-free 'error-free)
 115             (unwind-protect
 116                 ad-do-it
 117               (put 'car 'side-effect-free tmp)))
 118         ad-do-it))))
 119
 120 (when (and (not (featurep 'xemacs))
 121            (byte-optimize-form
 122             '(and (> 0 1)
 123                   (message "This should not appear in the byte-code."))
 124             t))
 125   (defadvice byte-optimize-form-code-walker
 126     (around fix-bug-in-and/or-forms (form for-effect) activate)
 127     "Optimize the rest of the and/or forms.
 128 It has been fixed in XEmacs before releasing 21.4 and also has been
 129 fixed in Emacs 22."
 130     (if (and for-effect (memq (car-safe form) '(and or)))
 131         (let ((fn (car form))
 132               (backwards (reverse (cdr form))))
 133           (while (and backwards
 134                       (null (setcar backwards
 135                                     (byte-optimize-form (car backwards) t))))
 136             (setq backwards (cdr backwards)))
 137           (if (and (cdr form) (null backwards))
 138               (byte-compile-log
 139                "  all subforms of %s called for effect; deleted" form))
 140           (when backwards
 141             (setcdr backwards
 142                     (mapcar 'byte-optimize-form (cdr backwards))))
 143           (setq ad-return-value (cons fn (nreverse backwards))))
 144       ad-do-it)))
 145
 146 ;; Work around for an incompatibility (XEmacs 21.4 vs. 21.5), see the
 147 ;; following threads:
 148 ;;
 149 ;; http://thread.gmane.org/gmane.emacs.gnus.general/56414
 150 ;; Subject: attachment problems found but not fixed
 151 ;;
 152 ;; http://thread.gmane.org/gmane.emacs.gnus.general/56459
 153 ;; Subject: Splitting mail -- XEmacs 21.4 vs 21.5
 154 ;;
 155 ;; http://thread.gmane.org/gmane.emacs.xemacs.beta/20519
 156 ;; Subject: XEmacs 21.5 and Gnus fancy splitting.
 157 ;;
 158 ;; Should be fixed in XEmacs (March 2007).
 159 ;; http://thread.gmane.org/gmane.emacs.xemacs.patches/8124
 160 ;; When should we remove this workaround?
 161 ;;
 162 (when (and (featurep 'xemacs)
 163            (let ((table (copy-syntax-table emacs-lisp-mode-syntax-table)))
 164              (modify-syntax-entry ?= " " table)
 165              (with-temp-buffer
 166                (with-syntax-table table
 167                  (insert "foo=bar")
 168                  (goto-char (point-min))
 169                  (forward-sexp 1)
 170                  (eolp)))))
 171   ;; The original `with-syntax-table' uses `copy-syntax-table' which
 172   ;; doesn't seem to copy modified syntax entries in XEmacs 21.5.
 173   (defmacro with-syntax-table (syntab &rest body)
 174     "Evaluate BODY with the SYNTAB as the current syntax table."
 175     `(let ((stab (syntax-table)))
 176        (unwind-protect
 177            (progn
 178              ;;(set-syntax-table (copy-syntax-table ,syntab))
 179              (set-syntax-table ,syntab)
 180              ,@body)
 181          (set-syntax-table stab)))))
 182
 183 (push srcdir load-path)
 184 (push loaddir load-path)
 185 (load (expand-file-name "lpath.el" loaddir) nil t)
 186
 187 (defalias 'device-sound-enabled-p 'ignore)
 188 (defalias 'play-sound-file 'ignore)
 189 (defalias 'nndb-request-article 'ignore)
 190 (defalias 'efs-re-read-dir 'ignore)
 191 (defalias 'ange-ftp-re-read-dir 'ignore)
 192 (defalias 'define-mail-user-agent 'ignore)
 193
 194 (eval-and-compile
 195   (unless (featurep 'xemacs)
 196     (defalias 'get-popup-menu-response 'ignore)
 197     (defalias 'event-object 'ignore)
 198     (defalias 'x-defined-colors 'ignore)
 199     (defalias 'read-color 'ignore)))
 200
 201 (eval-and-compile
 202   (when (featurep 'xemacs)
 203     (unless (fboundp 'defadvice)
 204       (autoload 'defadvice "advice" nil nil 'macro))
 205     (autoload 'Info-directory "info" nil t)
 206     (autoload 'Info-menu "info" nil t)
 207     (autoload 'ad-add-advice "advice")
 208     (autoload 'annotations-at "annotations")
 209     (autoload 'apropos "apropos" nil t)
 210     (autoload 'apropos-command "apropos" nil t)
 211     (autoload 'bbdb-complete-name "bbdb-com" nil t)
 212     (autoload 'browse-url "browse-url" nil t)
 213     (autoload 'browse-url-of-file "browse-url" nil t)
 214     (autoload 'c-mode "cc-mode" nil t)
 215     (autoload 'customize-apropos "cus-edit" nil t)
 216     (autoload 'customize-group "cus-edit" nil t)
 217     (autoload 'customize-save-variable "cus-edit" nil t)
 218     (autoload 'customize-set-variable "cus-edit" nil t)
 219     (autoload 'customize-variable "cus-edit" nil t)
 220     (autoload 'delete-annotation "annotations")
 221     (autoload 'dolist "cl-macs" nil nil 'macro)
 222     (autoload 'enriched-decode "enriched")
 223     (autoload 'executable-find "executable")
 224     (autoload 'font-lock-fontify-buffer "font-lock" nil t)
 225     (autoload 'info "info" nil t)
 226     (autoload 'mail-extract-address-components "mail-extr")
 227     (autoload 'mail-fetch-field "mail-utils")
 228     (autoload 'make-annotation "annotations")
 229     (autoload 'make-display-table "disp-table")
 230     (autoload 'pp "pp")
 231     (autoload 'ps-despool "ps-print" nil t)
 232     (autoload 'ps-spool-buffer "ps-print" nil t)
 233     (autoload 'ps-spool-buffer-with-faces "ps-print" nil t)
 234     (autoload 'read-passwd "passwd")
 235     (autoload 'regexp-opt "regexp-opt")
 236     (autoload 'reporter-submit-bug-report "reporter")
 237     (if (and (emacs-version>= 21 5)
 238              (not (featurep 'sxemacs)))
 239         (autoload 'setenv "process" nil t)
 240       (autoload 'setenv "env" nil t))
 241     (autoload 'sgml-mode "psgml" nil t)
 242     (autoload 'smtpmail-send-it "smtpmail")
 243     (autoload 'sort-numeric-fields "sort" nil t)
 244     (autoload 'sort-subr "sort")
 245     (autoload 'toggle-truncate-lines "view-less" nil t)
 246     (autoload 'trace-function-background "trace" nil t)
 247     (autoload 'unmorse-region "morse" nil t)
 248     (autoload 'w3-do-setup "w3")
 249     (autoload 'w3-prepare-buffer "w3-display")
 250     (autoload 'w3-region "w3-display" nil t)
 251     (defalias 'frame-char-height 'frame-height)
 252     (defalias 'frame-char-width 'frame-width)
 253     (defalias 'frame-parameter 'frame-property)
 254     (defalias 'make-overlay 'ignore)
 255     (defalias 'overlay-end 'ignore)
 256     (defalias 'overlay-get 'ignore)
 257     (defalias 'overlay-put 'ignore)
 258     (defalias 'overlay-start 'ignore)
 259     (defalias 'overlays-in 'ignore)
 260     (defalias 'replace-dehighlight 'ignore)
 261     (defalias 'replace-highlight 'ignore)
 262     (defalias 'w3-coding-system-for-mime-charset 'ignore)))
 263
 264 (defun dgnushack-compile-verbosely ()
 265   "Call dgnushack-compile with warnings ENABLED.  If you are compiling
 266 patches to gnus, you should consider modifying make.bat to call
 267 dgnushack-compile-verbosely.  All other users should continue to use
 268 dgnushack-compile."
 269   (dgnushack-compile t))
 270
 271 (defun dgnushack-compile (&optional warn)
 272   ;;(setq byte-compile-dynamic t)
 273   (unless warn
 274     (setq byte-compile-warnings
 275           '(free-vars unresolved callargs redefine)))
 276   (let ((files (directory-files srcdir nil "^[^=].*\\.el$"))
 277         ;;(byte-compile-generate-call-tree t)
 278         file elc)
 279     ;; Avoid barfing (from gnus-xmas) because the etc directory is not yet
 280     ;; installed.
 281     (when (featurep 'xemacs)
 282       (setq gnus-xmas-glyph-directory "dummy"))
 283     (dolist (file '("dgnushack.el" "lpath.el"))
 284       (setq files (delete file files)))
 285     (when (featurep 'base64)
 286       (setq files (delete "base64.el" files)))
 287     (condition-case code
 288         (require 'w3-parse)
 289       (error
 290        (message "No w3: %s %s" (cadr code) (or (locate-library "w3-parse") ""))
 291        (dolist (file '("nnultimate.el" "webmail.el" "nnwfm.el"))
 292          (setq files (delete file files)))))
 293     (condition-case code
 294         (require 'mh-e)
 295       (error
 296        (message "No mh-e: %s %s" (cadr code) (or (locate-library "mh-e") ""))
 297        (setq files (delete "gnus-mh.el" files))))
 298     (condition-case code
 299         (require 'xml)
 300       (error
 301        (message "No xml: %s %s" (cadr code) (or (locate-library "xml") ""))
 302        (setq files (delete "nnrss.el" files))))
 303     (dolist (file
 304              (if (featurep 'xemacs)
 305                  '("md5.el")
 306                '("gnus-xmas.el" "messagexmas.el" "nnheaderxm.el")))
 307       (setq files (delete file files)))
 308
 309     (dolist (file files)
 310       (setq file (expand-file-name file srcdir))
 311       (when (and (file-exists-p
 312                   (setq elc (concat (file-name-nondirectory file) "c")))
 313                  (file-newer-than-file-p file elc))
 314         (delete-file elc)))
 315
 316     (while (setq file (pop files))
 317       (setq file (expand-file-name file srcdir))
 318       (when (or (not (file-exists-p
 319                       (setq elc (concat (file-name-nondirectory file) "c"))))
 320                 (file-newer-than-file-p file elc))
 321         (ignore-errors
 322           (byte-compile-file file))))))
 323
 324 (defun dgnushack-recompile ()
 325   (require 'gnus)
 326   (byte-recompile-directory "." 0))
 327
 328 (defvar dgnushack-gnus-load-file
 329   (if (featurep 'xemacs)
 330       (expand-file-name "auto-autoloads.el")
 331     (expand-file-name "gnus-load.el")))
 332
 333 (defvar dgnushack-cus-load-file
 334   (if (featurep 'xemacs)
 335       (expand-file-name "custom-load.el")
 336     (expand-file-name "cus-load.el")))
 337
 338 (defun dgnushack-make-cus-load ()
 339   (load "cus-dep")
 340   (let ((cusload-base-file dgnushack-cus-load-file))
 341     (if (fboundp 'custom-make-dependencies)
 342         (custom-make-dependencies)
 343       (Custom-make-dependencies))
 344     (when (featurep 'xemacs)
 345       (message "Compiling %s..." dgnushack-cus-load-file)
 346       (byte-compile-file dgnushack-cus-load-file))))
 347
 348 (defun dgnushack-make-auto-load ()
 349   (require 'autoload)
 350   (unless (make-autoload '(define-derived-mode child parent name
 351                             "docstring" body)
 352                          "file")
 353     (defadvice make-autoload (around handle-define-derived-mode activate)
 354       "Handle `define-derived-mode'."
 355       (if (eq (car-safe (ad-get-arg 0)) 'define-derived-mode)
 356           (setq ad-return-value
 357                 (list 'autoload
 358                       (list 'quote (nth 1 (ad-get-arg 0)))
 359                       (ad-get-arg 1)
 360                       (nth 4 (ad-get-arg 0))
 361                       t nil))
 362         ad-do-it))
 363     (put 'define-derived-mode 'doc-string-elt 3))
 364   (let ((generated-autoload-file dgnushack-gnus-load-file)
 365         (make-backup-files nil)
 366         (autoload-package-name "gnus"))
 367     (if (featurep 'xemacs)
 368         (if (file-exists-p generated-autoload-file)
 369             (delete-file generated-autoload-file))
 370       (with-temp-file generated-autoload-file
 371         (insert ?\014)))
 372     (batch-update-autoloads)))
 373
 374 (defun dgnushack-make-load ()
 375   (unless (featurep 'xemacs)
 376     (message "Generating %s..." dgnushack-gnus-load-file)
 377     (with-temp-file dgnushack-gnus-load-file
 378       (insert-file-contents dgnushack-cus-load-file)
 379       (delete-file dgnushack-cus-load-file)
 380       (goto-char (point-min))
 381       (search-forward ";;; Code:")
 382       (forward-line)
 383       (delete-region (point-min) (point))
 384       (insert "\
 385 ;;; gnus-load.el --- automatically extracted custom dependencies and autoload
 386 ;;
 387 ;;; Code:
 388 ")
 389       (goto-char (point-max))
 390       (if (search-backward "custom-versions-load-alist" nil t)
 391           (forward-line -1)
 392         (forward-line -1)
 393         (while (eq (char-after) ?\;)
 394           (forward-line -1))
 395         (forward-line))
 396       (delete-region (point) (point-max))
 397       (insert "\n")
 398       ;; smiley-* are duplicated. Remove them all.
 399       (let ((point (point)))
 400         (insert-file-contents dgnushack-gnus-load-file)
 401         (goto-char point)
 402         (while (search-forward "smiley-" nil t)
 403           (beginning-of-line)
 404           (if (looking-at "(autoload ")
 405               (delete-region (point) (progn (forward-sexp) (point)))
 406             (forward-line))))
 407       ;;
 408       (goto-char (point-max))
 409       (when (search-backward "\n(provide " nil t)
 410         (forward-line -1)
 411         (delete-region (point) (point-max)))
 412       (insert "\
 413
 414 \(provide 'gnus-load)
 415
 416 ;;; Local Variables:
 417 ;;; version-control: never
 418 ;;; no-byte-compile: t
 419 ;;; no-update-autoloads: t
 420 ;;; End:
 421 ;;; gnus-load.el ends here
 422 ")
 423       ))
 424   (message "Compiling %s..." dgnushack-gnus-load-file)
 425   (byte-compile-file dgnushack-gnus-load-file)
 426   (when (featurep 'xemacs)
 427     (message "Creating dummy gnus-load.el...")
 428     (with-temp-file (expand-file-name "gnus-load.el")
 429       (insert "\
 430
 431 \(provide 'gnus-load)
 432
 433 ;;; Local Variables:
 434 ;;; version-control: never
 435 ;;; no-byte-compile: t
 436 ;;; no-update-autoloads: t
 437 ;;; End:
 438 ;;; gnus-load.el ends here"))))
 439
 440 (defun dgnushack-find-lisp-shadows (&optional lispdir)
 441   "Return a list of directories in which other Gnus installations exist.
 442 This function looks for the other Gnus installations which will shadow
 443 the new Gnus Lisp modules which have been installed in LISPDIR, using
 444 the default `load-path'.  The return value will make sense only when
 445 LISPDIR is existent and is listed in the default `load-path'.  Assume
 446 LISPDIR will be prepended to `load-path' by a user if the default
 447 `load-path' does not contain it."
 448   (unless lispdir
 449     (setq lispdir (getenv "lispdir")))
 450   (when (and lispdir (file-directory-p lispdir))
 451     (setq lispdir (file-truename (directory-file-name lispdir)))
 452     (let ((indices '("gnus.elc" "gnus.el" "gnus.el.bz2" "gnus.el.gz"
 453                      "message.elc" "message.el" "message.el.bz2"
 454                      "message.el.gz"))
 455           (path (delq nil (mapcar
 456                            (lambda (p)
 457                              (condition-case nil
 458                                  (when (and p (file-directory-p p))
 459                                    (file-truename (directory-file-name p)))
 460                                (error nil)))
 461                            dgnushack-default-load-path)))
 462           rest elcs)
 463       (while path
 464         (setq rest (cons (car path) rest)
 465               path (delete (car rest) (cdr path))))
 466       (setq path (nreverse (cdr (member lispdir rest)))
 467             rest nil)
 468       (while path
 469         (setq elcs indices)
 470         (while elcs
 471           (when (file-exists-p (expand-file-name (pop elcs) (car path)))
 472             (setq rest (cons (car path) rest)
 473                   elcs nil)))
 474         (setq path (cdr path)))
 475       (prog1
 476           (setq path (nreverse rest))
 477         (when path
 478           (let (print-level print-length)
 479             (princ (concat "\n\
 480 WARNING: The other Gnus installation" (if (cdr path) "s have" " has") "\
 481  been detected in:\n\n  " (mapconcat 'identity path "\n  ") "\n\n\
 482 You will need to modify the run-time `load-path', remove them manually,
 483 or remove them using `make remove-installed-shadows'.\n\n"))))))))
 484
 485 (defun dgnushack-remove-lisp-shadows (&optional lispdir)
 486   "Remove the other Gnus installations which shadow the recent one."
 487   (let ((path (with-temp-buffer
 488                 (let ((standard-output (current-buffer)))
 489                   (dgnushack-find-lisp-shadows lispdir))))
 490         elcs files shadows file)
 491     (when path
 492       (unless (setq elcs (directory-files srcdir nil "\\.elc\\'"))
 493         (error "You should build .elc files first."))
 494       (setq files
 495             (apply
 496              'append
 497              (mapcar
 498               (lambda (el)
 499                 (list (concat el "c") el (concat el ".bz2") (concat el ".gz")))
 500               (append
 501                (list (file-name-nondirectory dgnushack-gnus-load-file)
 502                      (file-name-nondirectory dgnushack-cus-load-file))
 503                (mapcar (lambda (elc) (substring elc 0 -1)) elcs)))))
 504       (while path
 505         (setq shadows files)
 506         (while shadows
 507           (setq file (expand-file-name (pop shadows) (car path)))
 508           (when (file-exists-p file)
 509             (princ (concat "  Removing " file "..."))
 510             (condition-case nil
 511                 (progn
 512                   (delete-file file)
 513                   (princ "done\n"))
 514               (error (princ "failed\n")))))
 515         (setq path (cdr path))))))
 516
 517 ;;; dgnushack.el ends here
 518
 519 ;;; arch-tag: 579f585a-24eb-4e1c-8d34-4808e11b68f2